Bibliotheken: HistoryLoader

Neuer Kommentar
 

HistoryLoader:

Mit diesem Modul können Sie historische Daten auf Anfrage eines den mehrwährungs Expert Advisor zu laden.

Autor: Nikolay Kositsin

 
Automated-Trading:

HistoryLoader:

Autor: Nikolay Kositsin

Syntaxfehler in Zeile 91 (fehlendes H). "SERIES_SYNCRONIZED" sollte "SERIES_SYNCHRONIZED"sein.
 
elib:
Syntaxfehler in Zeile 91 (fehlendes H). "SERIES_SYNCRONIZED" sollte "SERIES_SYNCHRONIZED"sein.

Nichts währt ewig unter dem Mond!

//+------------------------------------------------------------------+
//| Historie für das Hochladen prüfen|
//+------------------------------------------------------------------+
int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)
  {
//----+
   datetime first_date=0;
   datetime times[100];
//--- Prüfzeichen & Punkt
   if(symbol == NULL || symbol == "") symbol = Symbol();
   if(period == PERIOD_CURRENT)     period = Period();
//--- prüfen, ob das Symbol im MarketWatch ausgewählt ist
   if(!SymbolInfoInteger(symbol,SYMBOL_SELECT))
     {
      if(GetLastError()==ERR_MARKET_UNKNOWN_SYMBOL) return(-1);
      if(!SymbolSelect(symbol,true)) Print(__FUNCTION__,"(): Failed to add character ",symbol," im MarketWatch-Fenster!!!");
     }
//--- prüfen, ob Daten vorhanden sind
   SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date);
   if(first_date>0 && first_date<=start_date) return(1);
//--- nicht nach dem Laden der eigenen Daten fragen, wenn es sich um einen Indikator handelt
   if(MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR && Period()==period && Symbol()==symbol)
      return(-4);
//--- zweiter Versuch
   if(SeriesInfoInteger(symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,first_date))
     {
      //--- es sind Daten geladen, um Zeitreihen zu erstellen
      if(first_date>0)
        {
         //--- Zeitreihenbildung erzwingen
         CopyTime(symbol,period,first_date+PeriodSeconds(period),1,times);
         //--- Datum prüfen
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(2);
        }
     }
//--- Maximale Balken im Diagramm aus Terminal-Optionen
   int max_bars=TerminalInfoInteger(TERMINAL_MAXBARS);
//--- Informationen über den Symbolverlauf laden
   datetime first_server_date=0;
   while(!SeriesInfoInteger(symbol,PERIOD_M1,SERIES_SERVER_FIRSTDATE,first_server_date) && !IsStopped())
      Sleep(5);
//--- Startdatum für das Laden festlegen
   if(first_server_date>start_date) start_date=first_server_date;
   if(first_date>0 && first_date<first_server_date)
      Print(__FUNCTION__,"(): Warning: first server date ",first_server_date," for ",symbol,
            " does not match to first series date ",first_date);
//--- Daten Schritt für Schritt laden
   int fail_cnt=0;
   while(!IsStopped())
     {
      //--- Warten auf Zeitreihenbildung
      while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
         Sleep(5);
      //--- Bitte um gebaute Stäbe
      int bars=Bars(symbol,period);
      if(bars>0)
        {
         if(bars>=max_bars) return(-2);
         //--- um ein erstes Date bitten
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(0);
        }
      //--- Kopieren des nächsten Teils erzwingt das Laden von Daten
      int copied=CopyTime(symbol,period,bars,100,times);
      if(copied>0)
        {
         //--- Prüfung auf Daten
         if(times[0]<=start_date) return(0);
         if(bars+copied>=max_bars) return(-2);
         fail_cnt=0;
        }
      else
        {
         //--- nicht mehr als 100 Fehlversuche
         fail_cnt++;
         if(fail_cnt>=100) return(-5);
         Sleep(10);
        }
     }
//----+stopped
   return(-3);
  }
//+------------------------------------------------------------------+
 

Es funktioniert nicht, es stirbt beim ersten Zeichen....

Hier ist der Code

//+------------------------------------------------------------------+ 
//|TestLoadHistory.mq5 | 
//| Copyright 2009, MetaQuotes Software Corp. | | 
//| https://www.mql5.com | 
//+------------------------------------------------------------------+ 
#property copyright "2009, MetaQuotes Software Corp." 
#property link      "https://www.mql5.com" 
#property version   "1.02" 
#property script_show_inputs 

//--- Eingabeparameter 

//+------------------------------------------------------------------+ 
//| Skript-Programmstartfunktion| 
//+------------------------------------------------------------------+ 
void OnStart()
  {


   int      all_symbols=SymbolsTotal(false);   string  sym_name="";
   Print("Load symbols ",all_symbols);

   for(int k=0;k<all_symbols;k++)
      if((sym_name=SymbolName(k,false))!="")
        {
         SymbolSelect(sym_name,true);

         Print(k," Symbol name ",sym_name);

datetime time= (TimeCurrent()-60*60*24*5);


         int res=CheckLoadHistory(sym_name,PERIOD_M1,time);

         switch(res)
           {
            case -1 : Print("Unknown symbol ",sym_name);             break;
            case -2 : Print("Requested bars more than max bars in chart ",sym_name); break;
            case -3 : Print("Program was stopped ",sym_name);                        break;
            case -4 : Print("Indicator shouldn't load its own data ",sym_name);      break;
            case -5 : Print("Load failed ",sym_name);                                break;
            case  0 : Print("Loaded OK ",sym_name);                                  break;
            case  1 : Print("Loaded previously ",sym_name);                          break;
            case  2 : Print("Loaded previously and built ",sym_name);                break;
            default : Print("Unknown result ",sym_name);
           }

         datetime first_date;
         SeriesInfoInteger(sym_name,PERIOD_M1,SERIES_FIRSTDATE,first_date);
         int bars=Bars(sym_name,PERIOD_M1);
         Print("First date ",first_date," - ",bars," bars");
       }
//--- 

//--- 
  }
//+------------------------------------------------------------------+
//| Historie für das Hochladen prüfen|
//+------------------------------------------------------------------+
int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)
  {
//----+
   datetime first_date=0;
   datetime times[100];
//--- Prüfzeichen & Punkt
   if(symbol == NULL || symbol == "") symbol = Symbol();
   if(period == PERIOD_CURRENT)     period = Period();
//--- prüfen, ob das Symbol im MarketWatch ausgewählt ist
   if(!SymbolInfoInteger(symbol,SYMBOL_SELECT))
     {
      if(GetLastError()==ERR_MARKET_UNKNOWN_SYMBOL) return(-1);
      if(!SymbolSelect(symbol,true)) Print(__FUNCTION__,"(): Failed to add character ",symbol," im MarketWatch-Fenster!!!");
     }
//--- prüfen, ob Daten vorhanden sind
   SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date);
   if(first_date>0 && first_date<=start_date) return(1);
//--- nicht nach dem Laden der eigenen Daten fragen, wenn es sich um einen Indikator handelt
   if(MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR && Period()==period && Symbol()==symbol)
      return(-4);
//--- zweiter Versuch
   if(SeriesInfoInteger(symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,first_date))
     {
      //--- es sind Daten geladen, um Zeitreihen zu erstellen
      if(first_date>0)
        {
         //--- Zeitreihenbildung erzwingen
         CopyTime(symbol,period,first_date+PeriodSeconds(period),1,times);
         //--- Datum prüfen
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(2);
        }
     }
//--- Maximale Balken im Diagramm aus Terminal-Optionen
   int max_bars=TerminalInfoInteger(TERMINAL_MAXBARS);
//--- Informationen über den Symbolverlauf laden
   datetime first_server_date=0;
   while(!SeriesInfoInteger(symbol,PERIOD_M1,SERIES_SERVER_FIRSTDATE,first_server_date) && !IsStopped())
      Sleep(5);
//--- Startdatum für das Laden festlegen
   if(first_server_date>start_date) start_date=first_server_date;
   if(first_date>0 && first_date<first_server_date)
      Print(__FUNCTION__,"(): Warning: first server date ",first_server_date," for ",symbol,
            " does not match to first series date ",first_date);
//--- Daten Schritt für Schritt laden
   int fail_cnt=0;
   while(!IsStopped())
     {
      //--- Warten auf Zeitreihenbildung
      while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
         Sleep(5);
      //--- Frage nach eingebauten Stäben
      int bars=Bars(symbol,period);
      if(bars>0)
        {
         if(bars>=max_bars) return(-2);
         //--- um ein erstes Date bitten
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(0);
        }
      //--- Kopieren des nächsten Teils erzwingt das Laden von Daten
      int copied=CopyTime(symbol,period,bars,100,times);
      if(copied>0)
        {
         //--- Prüfung auf Daten
         if(times[0]<=start_date) return(0);
         if(bars+copied>=max_bars) return(-2);
         fail_cnt=0;
        }
      else
        {
         //--- nicht mehr als 100 Fehlversuche
         fail_cnt++;
         if(fail_cnt>=100) return(-5);
         Sleep(10);
        }
     }
//----+stopped
   return(-3);
  }
//+------------------------------------------------------------------+

und er stirbt hier

while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
 

Hallo Nikolaj

Historyloader.mqh hat nur eine Funktion von

int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)

es hat keine Funktion Loadhistory() wie erwähnt.
 
Nikolay Kositsin:

Unter dem Mond dauert nichts ewig!

Vielen Dank, es funktioniert für mich!

Neuer Kommentar