MQL5 向导 - 基于 牛市孕育/ 熊市孕育形态的交易信号 + CCI - MetaTrader 5EA

MQL5 向导 可创建现成的交易程序，此程序基于客户端附带的 标准类库 (参见 在 MQL5 向导中创建现成交易程序 具体内容)。它可以快速验证您的交易想法，所有您需要做的就是创建您自己的交易信号类。这个类的结构及用例可参阅文章 MQL5 向导：如何创建交易信号模块。

通常做法如下：交易信号子类由 CExpertSignal衍生出来，之后，必须用您自己的方法重写类中的 LongCondition() 和 ShortCondition() 虚方法。

有本书 "Strategies of best traders（交易者最佳策略）" （俄语版），书中论述了许多交易策略，我们将注意力集中在反转 K 线形态上，并用 Stochastic, CCI, MFI 和 RSI 振荡指标来确认。

最佳途径是创建分离的子类，此类由 CExpertSignal 中衍生，用于检查 K 线的形态结构。用于验证 K 线形态生成的交易信号，写一个 CCandlePattern 的衍生子类就足够了，并加入必要的特性（如，振荡指标确认）。

此处我们讨论的信号，基于 "牛市孕育 / 熊市孕育" 反转 K 线形态，确认则依赖 CCI 指标。这个交易信号模块基于 CCandlePattern 类，这是一个利用 K 线形态创建交易信号的简单例子。

1. "牛市孕育" 和 "熊市孕育" 反转形态

1.1. 牛市孕育

牛市孕育 反转形态形成于下跌趋势，当一根大阴线之后紧跟一条小阳线，且整根小阳线全部包含在大阴线的实体内。这个形态指出下跌趋势 (下降趋势) 也许将会反转，这个信号表明现在是一个好的多单入场的时间。第二根线的开盘价有一个向上跳空缺口。则第二根小阳线，看来有可能反转。

图例. 1. "牛市孕育" 形态

识别 "牛市孕育" 形态已经在 CCandlePattern 类的 CheckPatternBullishHarami() 方法中实现：

//+------------------------------------------------------------------+
//| Checks formation of "Bullish Harami" candlestick pattern         |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishHarami()
  {
//--- 牛市孕育
   if((Close(1)>Open(1))              && // 最后的完整柱线为阳线
     ((Open(2)-Close(2))>AvgBody(1))  && // 前一根为阴线，实体大于平均值 (长阴)
     ((Close(1)<Open(2))              && // 阳线收盘价低于阴线开盘价 
      (Open(1)>Close(2)))             && // 阳线开盘价大于阴线收盘价
      (MidPoint(2)<CloseAvg(2)))         // 下跌趋势
      return(true);
//---
   return(false);
  }

1.2. 熊市孕育

"熊市孕育" 反转形态形成于上升趋势，当一根大阳线之后紧跟一条小阴线，且整根小阴线完全包含在大阳线的实体内。这个形态指出上涨趋势 (上升趋势) 也许将会反转，这个信号表明现在是一个好的空单入场的时间。第二根线的开盘价有一个向下跳空缺口。

第二根小阴线，看来有可能反转。

图例. 2. "熊市孕育" 形态

识别 "熊市孕育" 形态已经在 CCandlePattern 类的 CheckPatternBearishHarami() 方法中实现：

//+------------------------------------------------------------------+
//| Checks formation of "Bearish Harami" candlestick pattern         |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishHarami()
  {
//--- 熊市孕育
   if((Close(1)<Open(1))              && // 最后的完整柱线为阴线
     ((Close(2)-Open(2))>AvgBody(1))  && // 前一根为阳线，实体大于平均值 (长阳)
     ((Close(1)>Open(2))              && // 阴线收盘价高于阳线开盘价 
      (Open(1)<Close(2)))             && // 阴线开盘价低于阳线收盘价
      (MidPoint(2)>CloseAvg(2)))         // 上升趋势
      return(true);
//---
   return(false);
  }

2. CCI 指标确认交易信号

采用交易信号来开多单或空单，必须用 CCI 指标来确认。CCI 指标的数值必须高于/ 低于临界水平 (-50 为多单，以及 50 为空单)。

已建仓位的平仓同样依靠 CCI 指标。可分 2 种情况完成：

1. 如果 CCI 已经到达反向临界水平 (80 为多单 ，以及 -80 为空单)
2. 如果反转信号未被确认 (当 CCI 指标到达如下水平：-80 为多单，以及 80 为空单)

图例. 3. "牛市孕育" 形态，由 CCI 指标确认

• int CBH_BH_CCI::LongCondition() - 检测开多单条件 (返回 80) 以及平空仓 (返回 40);
  
• int CBE_BE_CCI::ShortCondition() - 检测开空单条件 (返回 80) 以及平多仓 (返回 40)。

2.1. 开多单/平空仓

1. 这个 "牛市孕育" 形态的形状必须由 CCI 指标确认： CCI(1)<-50 (最后完整的 CCI 指标数值必须小于 -50)。

2. 空单必须被平仓如果 CCI 指标上穿临界水平 -80 或 下穿 80。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CBH_BH_CCI::LongCondition()
  {
   int result=0;
//--- idx 可用于检测交易程序工作模式
//--- idx=0 - EA 在每个即时价格都检查交易条件
//--- idx=1 - EA 仅在每个新柱线建立时检查交易条件
   int idx   =StartIndex();
//--- 检查开多单条件
//--- 牛市孕育形态形状及 CCI<-50
   if(CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_HARAMI) && (CCI(1)<-50))
     result=80;
//--- 检查平空仓条件
//--- 信号线交叉超买/超卖 (上穿 -80, 下穿 80)
   if(((CCI(1)>-80) && (CCI(2)<-80)) || ((CCI(1)<80) && (CCI(2)>80)))
     result=40;
//--- 返回结果
   return(result);
  }

2.2. 开空单/平多仓

1. 这个 "熊市孕育" 形态的形状必须由 CCI 指标确认： CCI(1)>50 (最后完整的 CCI 指标数值必须大于 50)。

2. 多单必须被平仓如果 CCI 指标已经向下穿越临界水平 -80 或 80。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CBH_BH_CCI::ShortCondition()
  {
   int result=0;
//--- idx 可用于检测交易程序工作模式
//--- idx=0 - EA 在每个即时价格都检查交易条件
//--- idx=1 - EA 仅在每个新柱线建立时检查交易条件
   int idx   =StartIndex();
//--- 检查开空单条件
//--- 熊市孕育形态形状及 CCI>50
   if(CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_HARAMI) && (CCI(1)>50))
     result=80;
//--- 检查平多仓条件
//--- 信号线交叉超买/超卖 (下穿 -80, 下穿 80)
   if(((CCI(1)<80) && (CCI(2)>80)) || ((CCI(1)<-80) && (CCI(2)>-80)))
     result=40;
//--- 返回结果
   return(result);
  }

2.3. 使用 MQL5 向导创建交易程序

为创建交易程序，启动 MQL5 向导：

图例. 4. 使用 MQL5 向导创建交易程序

为交易程序起个特别名称：

图例. 5. 交易程序的一般属性

之后我们要选择交易信号将会使用的模块。

图例. 6. 交易程序的信号属性

在我们的案例中，我们仅使用交易信号的一个模块。

加入 "基于 牛市孕育 / 熊市孕育 信号，由 CCI 指标确认" 信号模块:

图例. 7. 交易程序的信号属性

交易信号模块被加入：

图例. 8. 交易程序的信号属性

您可以选择任何移动属性，但是我们选择 "不使用移动止损"：

图例. 9. 交易程序的移动属性

关注资金管理属性，我们将使用 "固定手数交易"：

图例. 10. 交易程序的资金管理属性

通过点击 "完成" 按钮，我们将会得到生成的交易程序代码，名为 Expert_ABH_BH_CCI.mq5，它会被保存在 客户端目录\MQL5\Experts\。

交易程序生成的省缺输入参数：

//--- 主信号线输入参数
input int            Signal_ThresholdOpen   =10;     // 开单信号阀值 [0...100]
input int            Signal_ThresholdClose  =10;     // 平单信号阀值 [0...100]
input double         Signal_PriceLevel      =0.0;    // 执行订单价位
input double         Signal_StopLevel       =50.0;   // 止损位 (点数)
input double         Signal_TakeLevel       =50.0;   // 止盈位 (点数)

必须替换为：

//--- 主信号线输入参数
input int            Signal_ThresholdOpen   =40;     // 开单信号阀值 [0...100]
input int            Signal_ThresholdClose  =20;     // 平单信号阀值 [0...100]
input double         Signal_PriceLevel      =0.0;    // 执行订单价位
input double         Signal_StopLevel       =0.0;    // 止损位 (点数)
input double         Signal_TakeLevel       =0.0;    // 止盈位 (点数)

这个 Signal_ThresholdOpen/Signal_ThresholdClose 输入参数允许设置特殊的开、平单阀值。

在交易信号类 LongCondition() 和 ShortCondition() 方法的代码中，我们有固定的阀值：

• 开单: 80;
• 平仓: 40。
  

Signal_StopLevel 和 Signal_TakeLevel 输入参数的值设为 0，它意味着无需止盈、止损，仅当平仓条件为真时才会平仓。

2.4. 历史回测结果

我们来讨论交易程序基于历史数据的回测 (EURUSD H1, 测试周期: 2010.01.01-2011.03.16, PeriodCCI=11, MA_period=5)。

创建交易程序时我们采用固定手数 (固定交易手数, 0.1), 移动止损算法未采用 (不使用移动止损)。

图例. 11. 交易程序的测试结果，基于 牛市孕育 / 熊市孕育 + CCI

最佳输入参数集合可借助 MetaTrader 5 客户端的 策略测试员 发现。

由 MQL5 向导创建的交易程序代码，附加在 expert_abh_bh_cci.mq5。