Советник не работает на сервере Форекс

Новый комментарий
 
Не пойму в чём дело, не открывает сделки на реальном счёте, пишет что неверные стопы, хотя на демо счёте работает замечательно 
#include <Trade\PositionInfo.mqh>
#include <Trade\Trade.mqh>
#include <Trade\SymbolInfo.mqh>  
CPositionInfo  m_position;                   // trade position object
CTrade         m_trade;                      // trading object
CSymbolInfo    m_symbol;                     // symbol info object
//--- input parameters
input ushort   InpStopLoss    = 1;          // Stop Loss (in pips)
input ushort   InpTakeProfit  = 1;          // Take Profit (in pips)
input double   InpLots   = 0.05;      // Lots
//---
ulong          m_magic=15489;                // magic number
ulong          m_slippage=30;                // slippage

double         ExtLot=0.0;
double         ExtStopLoss=0.0;
double         ExtTakeProfit=0.0;
double         m_adjusted_point;             // point value adjusted for 3 or 5 points
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   m_symbol.Name(Symbol());                  // sets symbol name
   RefreshRates();
   m_symbol.Refresh();
//---
   m_trade.SetExpertMagicNumber(m_magic);
//---
   if(IsFillingTypeAllowed(Symbol(),SYMBOL_FILLING_FOK))
      m_trade.SetTypeFilling(ORDER_FILLING_FOK);
   else if(IsFillingTypeAllowed(Symbol(),SYMBOL_FILLING_IOC))
      m_trade.SetTypeFilling(ORDER_FILLING_IOC);
   else
      m_trade.SetTypeFilling(ORDER_FILLING_RETURN);
//---
   m_trade.SetDeviationInPoints(m_slippage);
//--- tuning for 3 or 5 digits
   int digits_adjust=1;
   if(m_symbol.Digits()==3 || m_symbol.Digits()==5)
      digits_adjust=5;
   m_adjusted_point=m_symbol.Point()*digits_adjust;

   ExtLot         = m_symbol.LotsMin();
   ExtStopLoss    = InpStopLoss     * m_adjusted_point;
   ExtTakeProfit  = InpTakeProfit   * m_adjusted_point;
//--- Initialize the generator of random numbers 
   MathSrand(GetTickCount());
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   if(CalculateAllPositions()==0)
     {
      if(!RefreshRates())
         return;
      //--- odd (1) - "BUY", even (2) - "SELL"
      int math_rand=MathRand();
      Print(__FUNCTION__,", ",TimeToString(TimeCurrent(),TIME_SECONDS),"; ExtLot=",DoubleToString(ExtLot,2));
      if(math_rand%1==0 && math_rand%2==0)
        {
         double sl=(InpStopLoss==0)?0.0:m_symbol.Bid()+ExtStopLoss;
         double tp=(InpTakeProfit==0)?0.0:m_symbol.Bid()-ExtTakeProfit;
         OpenSell(ExtLot,sl,tp);
        }
      else
        {
         double sl=(InpStopLoss==0)?0.0:m_symbol.Ask()-ExtStopLoss;
         double tp=(InpTakeProfit==0)?0.0:m_symbol.Ask()+ExtTakeProfit;
         OpenBuy(ExtLot,sl,tp);
        }
     }
//---
  }
//+------------------------------------------------------------------+
//| Refreshes the symbol quotes data                                 |
//+------------------------------------------------------------------+
bool RefreshRates()
  {
//--- refresh rates
   if(!m_symbol.RefreshRates())
      return(false);
//--- protection against the return value of "zero"
   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)
      return(false);
//---
   return(true);
  }
//+------------------------------------------------------------------+ 
//| Checks if the specified filling mode is allowed                  | 
//+------------------------------------------------------------------+ 
bool IsFillingTypeAllowed(string symbol,int fill_type)
  {
//--- Obtain the value of the property that describes allowed filling modes 
   int filling=(int)SymbolInfoInteger(symbol,SYMBOL_FILLING_MODE);
//--- Return true, if mode fill_type is allowed 
   return((filling & fill_type)==fill_type);
  }
//+------------------------------------------------------------------+
//| Calculate all positions Buy and Sell                             |
//+------------------------------------------------------------------+
int CalculateAllPositions()
  {
   int totlal=0;

   for(int i=PositionsTotal()-1;i>=0;i--)
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==m_magic)
            totlal++;
//---
   return(totlal);
  }
//+------------------------------------------------------------------+
//| Open Buy position                                                |
//+------------------------------------------------------------------+
void OpenBuy(double lot,double sl,double tp)
  {
   sl=m_symbol.NormalizePrice(sl);
   tp=m_symbol.NormalizePrice(tp);

   double volume=LotCheck(lot);
   if(volume==0.0)
      return;
//--- check volume before OrderSend to avoid "not enough money" error (CTrade)
   double check_volume_lot=m_trade.CheckVolume(m_symbol.Name(),volume,m_symbol.Ask(),ORDER_TYPE_BUY);

   if(check_volume_lot!=0.0)
      if(check_volume_lot>=volume)
        {
         if(m_trade.Buy(volume,NULL,m_symbol.Ask(),sl,tp))
           {
            if(m_trade.ResultDeal()==0)
              {
               Print("Buy -> false. Result Retcode: ",m_trade.ResultRetcode(),
                     ", description of result: ",m_trade.ResultRetcodeDescription());
              }
            else
              {
               Print("Buy -> true. Result Retcode: ",m_trade.ResultRetcode(),
                     ", description of result: ",m_trade.ResultRetcodeDescription());
              }
           }
         else
           {
            Print("Buy -> false. Result Retcode: ",m_trade.ResultRetcode(),
                  ", description of result: ",m_trade.ResultRetcodeDescription());
           }
        }
//---
  }
//+------------------------------------------------------------------+
//| Open Sell position                                               |
//+------------------------------------------------------------------+
void OpenSell(double lot,double sl,double tp)
  {
   sl=m_symbol.NormalizePrice(sl);
   tp=m_symbol.NormalizePrice(tp);

   double volume=LotCheck(lot);
   if(volume==0.0)
      return;
//--- check volume before OrderSend to avoid "not enough money" error (CTrade)
   double check_volume_lot=m_trade.CheckVolume(m_symbol.Name(),volume,m_symbol.Bid(),ORDER_TYPE_SELL);

   if(check_volume_lot!=0.0)
      if(check_volume_lot>=volume)
        {
         if(m_trade.Sell(volume,NULL,m_symbol.Bid(),sl,tp))
           {
            if(m_trade.ResultDeal()==0)
              {
               Print("Sell -> false. Result Retcode: ",m_trade.ResultRetcode(),
                     ", description of result: ",m_trade.ResultRetcodeDescription());
              }
            else
              {
               Print("Sell -> true. Result Retcode: ",m_trade.ResultRetcode(),
                     ", description of result: ",m_trade.ResultRetcodeDescription());
              }
           }
         else
           {
            Print("Sell -> false. Result Retcode: ",m_trade.ResultRetcode(),
                  ", description of result: ",m_trade.ResultRetcodeDescription());
           }
        }
//---
  }
//+------------------------------------------------------------------+
//| Lot Check                                                        |
//+------------------------------------------------------------------+
double LotCheck(double lots)
  {
//--- calculate maximum volume
   double volume=NormalizeDouble(lots,2);
   double stepvol=m_symbol.LotsStep();
   if(stepvol>0.0)
      volume=stepvol*MathFloor(volume/stepvol);
//---
   double minvol=m_symbol.LotsMin();
   if(volume<minvol)
      volume=0.0;
//---
   double maxvol=m_symbol.LotsMax();
   if(volume>maxvol)
      volume=maxvol;
   return(volume);
  }
//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value 
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      long     deal_entry        =0;
      double   deal_profit       =0.0;
      double   deal_volume       =0.0;
      string   deal_symbol       ="";
      long     deal_magic        =0;
      long     deal_reason       =-1;
      if(HistoryDealSelect(trans.deal))
        {
         deal_entry=HistoryDealGetInteger(trans.deal,DEAL_ENTRY);
         deal_profit=HistoryDealGetDouble(trans.deal,DEAL_PROFIT);
         deal_volume=HistoryDealGetDouble(trans.deal,DEAL_VOLUME);
         deal_symbol=HistoryDealGetString(trans.deal,DEAL_SYMBOL);
         deal_magic=HistoryDealGetInteger(trans.deal,DEAL_MAGIC);
         deal_reason=HistoryDealGetInteger(trans.deal,DEAL_REASON);
        }
      else
         return;

      if(deal_symbol==m_symbol.Name() && deal_magic==m_magic)
         if(deal_entry==DEAL_ENTRY_OUT)
           {
            if(deal_reason==DEAL_REASON_SL)
               ExtLot*=2.0;
            else if(deal_reason==DEAL_REASON_TP)
               ExtLot=InpLots;
           }
     }
  }
//+------------------------------------------------------------------+
в чём причина может быть?
 
Андрей Пелевин:
Не пойму в чём дело, не открывает сделки на реальном счёте, пишет что неверные стопы, хотя на демо счёте работает замечательно в чём причина может быть?

Бывает что нельзя ставить стопы при открытии позиции. Т.е. сначала нужно открыть позицию с нулевыми стопами, и потом модифицировать.

Плюс, есть ограничения на дистанцию от стопов до текущих цен. Они зависят от брокера.

 

Сервер Форекс — это в анналы Юмора ))

А по существу  Andrey Barinov все правильно написал. Узнать минимальную дистанцию SL и TP, а также некоторые другие параметры можно моим индикатором ShowImportantParams. 

И еще распечатайте sl и tp вот так. Вот измененная функция

Print("sl=", sl, "   tp=", tp); 
void OnTick()
  {
//---
   if(CalculateAllPositions()==0)
     {
      if(!RefreshRates())
         return;
      //--- odd (1) - "BUY", even (2) - "SELL"
      int math_rand=MathRand();
      Print(__FUNCTION__,", ",TimeToString(TimeCurrent(),TIME_SECONDS),"; ExtLot=",DoubleToString(ExtLot,2));
      if(math_rand%1==0 && math_rand%2==0)
        {
         double sl=(InpStopLoss==0)?0.0:m_symbol.Bid()+ExtStopLoss;
         double tp=(InpTakeProfit==0)?0.0:m_symbol.Bid()-ExtTakeProfit;
         OpenSell(ExtLot,sl,tp);
        }
      else
        {
         double sl=(InpStopLoss==0)?0.0:m_symbol.Ask()-ExtStopLoss;
         double tp=(InpTakeProfit==0)?0.0:m_symbol.Ask()+ExtTakeProfit;
         Print("sl=", sl, "   tp=", tp); 
         OpenBuy(ExtLot,sl,tp);
        }
     }
//---
  }
Andrey Barinov
Andrey Barinov
  • 2023.02.07
  • www.mql5.com
Профиль трейдера
 
Alexey Volchanskiy #:

Сервер Форекс — это в анналы Юмора ))

А по существу  Andrey Barinov все правильно написал. Узнать минимальную дистанцию SL и TP, а также некоторые другие параметры можно моим индикатором ShowImportantParams. 

И еще распечатайте sl и tp вот так. Вот измененная функция

Алексей! Спасибо за индикатор. А поясните пожалуйста что это у Вас за два типа спреда? Они что по одному и тому же инструменту могут быть одновременно разными?

 
Vitaly Murlenko #:

Алексей! Спасибо за индикатор. А поясните пожалуйста что это у Вас за два типа спреда? Они что по одному и тому же инструменту могут быть одновременно разными?

Почему только два? Их там три ))

Причем каждый тип, хоть и лаконично, но достаточно понятно описан:

  • SpreadSmooth — текущий спред, усредненный на SpreadSmoothTicks тиках.
  • RealSpread — текущий спред без усреднения.
  • SpreadPrice — цена усредненного спреда в валюте депозита.
 
Ihor Herasko #:

Почему только два? Их там три ))

Причем каждый тип, хоть и лаконично, но достаточно понятно описан:

Спасибо за помощь. К сожалению, на форуме так и не сделали возможность посмотреть список ответов на свои посты. Надо ручками записывать, что где писал, это напрягает и пропускаешь вопросы ((.

Дополню, что

  • SpreadPrice — цена усредненного спреда в валюте депозита на один лот. 

В кодебазе валяется еще мой вариант для МТ5. Но, на время написания, в индикаторах на MQL5 был отключен доступ к большинству торговых функций. В МТ4 такого нет, советники и индикаторы равноправны в этом плане. Так что вариант для МТ5 получился урезанный. В частности, в индикаторе закрыта даже функция получения плеча на счете! Вот зачем было так гадить программистам на MQL5, мне так и не объяснили. Тогда еще полноценно работала тех. поддержка, они ответили, что разработчики MQL5 решили, что в индикаторах это лишнее!!! Очевидно, Рената рядом не было в момент принятия этого идиотического решения!

Надо еще разок проверить, может разрабы все же одумались, перестали курить запрещенные вещества? Просто думаю обновить эти 2 индикатора, но для МТ5 придется писать советник, который будет доставать инфу, недоступную индикатору и класть ее в глобальные переменные. Причем, для экономии, пусть грузит инфу для всех инструментов в открытых окнах. А индикатор будет тупо отображать «запрещенку». Как идея?

ShowImportantParams
ShowImportantParams
  • www.mql5.com
Показывает важные параметры инструмента и счета.
 
Alexey Volchanskiy #:

Спасибо за помощь. К сожалению, на форуме так и не сделали возможность посмотреть список ответов на свои посты. Надо ручками записывать, что где писал, это напрягает и пропускаешь вопросы ((.

Дополню, что

  • SpreadPrice — цена усредненного спреда в валюте депозита на один лот. 

В кодебазе валяется еще мой вариант для МТ5. Но, на время написания, в индикаторах на MQL5 был отключен доступ к большинству торговых функций. В МТ4 такого нет, советники и индикаторы равноправны в этом плане. Так что вариант для МТ5 получился урезанный. В частности, в индикаторе закрыта даже функция получения плеча на счете! Вот зачем было так гадить программистам на MQL5, мне так и не объяснили. Тогда еще полноценно работала тех. поддержка, они ответили, что разработчики MQL5 решили, что в индикаторах это лишнее!!! Очевидно, Рената рядом не было в момент принятия этого идиотического решения!

Надо еще разок проверить, может разрабы все же одумались, перестали курить запрещенные вещества? Просто думаю обновить эти 2 индикатора, но для МТ5 придется писать советник, который будет доставать инфу, недоступную индикатору и класть ее в глобальные переменные. Причем, для экономии, пусть грузит инфу для всех инструментов в открытых окнах. А индикатор будет тупо отображать «запрещенку». Как идея?

Просто надо почаще бывать на форуме. Уже давно всё что не связано с открытием ордеров\позиций в индикаторах доступно.

Новый комментарий
Причина обращения: