Как правильно получить доступ к массиву(буферу)?

[Григорий]

Пытаюсь переделать под себя стандартный Average True Range (ATR.mq5), чтоб текущее значение просто выводилось на график. При попытке вывести  

ObjectSetString(0,obj_name,OBJPROP_TEXT,"S = "+DoubleToString(ExtATRBuffer,0));

 редактор матерится
'ExtATRBuffer' - invalid array access 

А как правильно получить доступ к массиву(буферу)? 

[Дмитрий Александрович]

griha:
Пытаюсь переделать под себя стандартный Average True Range (ATR.mq5), чтоб текущее значение просто выводилось на график. При попытке вывести  

ObjectSetString(0,obj_name,OBJPROP_TEXT,"S = "+DoubleToString(ExtATRBuffer,0));

 редактор матерится
'ExtATRBuffer' - invalid array access 

А как правильно получить доступ к массиву(буферу)? 

ExtATRBuffer - у вас это массив, следовательно, в зависимости от контекста, нужно употреблять ExtATRBuffer[0] или ExtATRBuffer[i] и т.п.

[Григорий]

Спасибо за подсказку, на ExtATRBuffer[0] или ExtATRBuffer[i] редактор действительно не матерится, но на график при ExtATRBuffer[i] выводится вместо чисел надпись Label, а при ExtATRBuffer[0]  - 0. Пытался ставит значение периода - выводит совсем левые числа.

[Sergey Gritsay]

griha:
Спасибо за подсказку, на ExtATRBuffer[0] или ExtATRBuffer[i] редактор действительно не матерится, но на график при ExtATRBuffer[i] выводится вместо чисел надпись Label, а при ExtATRBuffer[0]  - 0. Пытался ставит значение периода - выводит совсем левые числа.

а вы буфер перевернуть не забыли?

[Дмитрий Александрович]

griha:
Спасибо за подсказку, на ExtATRBuffer[0] или ExtATRBuffer[i] редактор действительно не матерится, но на график при ExtATRBuffer[i] выводится вместо чисел надпись Label, а при ExtATRBuffer[0]  - 0. Пытался ставит значение периода - выводит совсем левые числа.

Для полного счастья нам нужен исходный код, только так сможем помочь :)
Объясним что к чему и почему :)

[Григорий]

Это мои первые потуги в програмировании, поэтому вообще не знаю что такое "перевернуть буфер". :)
Стандартный индикатор "Average True Range". Вот код

//+------------------------------------------------------------------+
//| ATR.mq5 |
//| Copyright 2009, MetaQuotes Software Corp. |
//| http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "2009, MetaQuotes Software Corp."
#property link "http://www.mql5.com"
#property description "Average True Range"
//--- indicator settings
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots 1
#property indicator_type1 DRAW_LINE
#property indicator_color1 DodgerBlue
#property indicator_label1 "ATR"
//--- input parameters
input int InpAtrPeriod=14; // ATR period

input int FontSize=16;  // моя константа
input color FontColor=White; // моя константа


//--- indicator buffers
double ExtATRBuffer[];
double ExtTRBuffer[];
//--- global variable
int ExtPeriodATR;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
void OnInit()
{
//--- check for input value
if(InpAtrPeriod<=0)
{
ExtPeriodATR=14;
printf("Incorrect input parameter InpAtrPeriod = %d. Indicator will use value %d for calculations.",InpAtrPeriod,ExtPeriodATR);
}
else ExtPeriodATR=InpAtrPeriod;
//--- indicator buffers mapping
SetIndexBuffer(0,ExtATRBuffer,INDICATOR_DATA);
SetIndexBuffer(1,ExtTRBuffer,INDICATOR_CALCULATIONS);
//---
IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//--- sets first bar from what index will be drawn
PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,InpAtrPeriod);
//--- name for DataWindow and indicator subwindow label
string short_name="ATR("+string(ExtPeriodATR)+")";
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
PlotIndexSetString(0,PLOT_LABEL,short_name);
//--- initialization done
}
//+------------------------------------------------------------------+
//| Average True Range |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &Time[],
const double &Open[],
const double &High[],
const double &Low[],
const double &Close[],
const long &TickVolume[],
const long &Volume[],
const int &Spread[])
{
int i,limit;
//--- check for bars count
if(rates_total<=ExtPeriodATR)
return(0); // not enough bars for calculation
//--- preliminary calculations
if(prev_calculated==0)
{
ExtTRBuffer[0]=0.0;
ExtATRBuffer[0]=0.0;
//--- filling out the array of True Range values for each period
for(i=1;i<rates_total;i++)
ExtTRBuffer[i]=MathMax(High[i],Close[i-1])-MathMin(Low[i],Close[i-1]);
//--- first AtrPeriod values of the indicator are not calculated
double firstValue=0.0;
for(i=1;i<=ExtPeriodATR;i++)
{
ExtATRBuffer[i]=0.0;
firstValue+=ExtTRBuffer[i];
}
//--- calculating the first value of the indicator
firstValue/=ExtPeriodATR;
ExtATRBuffer[ExtPeriodATR]=firstValue;
limit=ExtPeriodATR+1;
}
else limit=prev_calculated-1;
//--- the main loop of calculations
for(i=limit;i<rates_total;i++)
{
ExtTRBuffer[i]=MathMax(High[i],Close[i-1])-MathMin(Low[i],Close[i-1]);
ExtATRBuffer[i]=ExtATRBuffer[i-1]+(ExtTRBuffer[i]-ExtTRBuffer[i-ExtPeriodATR])/ExtPeriodATR;
}

//------------мое дополнение----------

string obj_name="my_OBJ_TEXT_object";

if(ObjectFind(0,obj_name)==-1)
{ObjectCreate(0,obj_name,OBJ_LABEL,0,0,0);}
   
ObjectSetInteger(0,obj_name,OBJPROP_XDISTANCE,50); //x координата надписи "S="
ObjectSetInteger(0,obj_name,OBJPROP_YDISTANCE,int(MathCeil(1.5*Font2Size)));
ObjectSetInteger(0,obj_name,OBJPROP_COLOR,FontColor); //--- зададим цвет текста
  ObjectSetInteger(0,obj_name,OBJPROP_FONTSIZE,FontSize);//размер шрифта надписи "S="
ObjectSetString(0,obj_name,OBJPROP_FONT,"Arial");
  ObjectSetString(0,obj_name,OBJPROP_TEXT,"S = "+DoubleToString(ExtATRBuffer[i],1)); 
 

//------------мое дополнение end----------

//--- return value of prev_calculated for next call
return(rates_total);
}
//+------------------------------------------------------------------+

 

[[Удален]]

griha:

Это мои первые потуги в програмировании, поэтому вообще не знаю что такое "перевернуть буфер". :)
Стандартный индикатор "Average True Range". Вот код

скорей всего речь шла о серийности массива. Подробней можно тут посмотреть ArrayIsSeries и тут ArraySetAsSeries.

[Aleksey Lebedev]

mrProF:

Для полного счастья нам нужен исходный код, только так сможем помочь :)

С исходным кодом эт любой может.. :)

Последний(текущий) бар имеет индекс [rates_total-1].

Перевод в строку DoubleToString - одной цифры после запятой маловато будет.

Как-то так должно быть:

DoubleToString(ExtATRBuffer[rates_total-1],5)

и ChartRedraw() после установки свойств лабела желательно вставить.

зы: _Digits вместо 5, будет как в индюке.

[Дмитрий Александрович]

Swan:

С исходным кодом эт любой может.. :)

Да просто времени попрактиковаться в телепатии не хватает :)

[Григорий]

Спасибо,

DoubleToString(ExtATRBuffer[rates_total-1],5)

работает. А зачем ChartRedraw()? И без него все работает

[Дмитрий Александрович]

griha:
Спасибо,

DoubleToString(ExtATRBuffer[rates_total-1],5)

работает. А зачем ChartRedraw()? И без него все работает

Без перерисовки чарта, объект может не отображаться, например в выходные когда нет тиков.

Тогда придется либо сдвинуть чарт или сделать другие действия, которые вызовут перерисовку чарта.