MODE_TRADE на MT5?

[Marcio Andrade]

MT4 с MODE_TRADE подтвердил статус заказа как на рынке, как сделать это подтверждение в MT5?

[Rashid Umarov]

Read this article please - https://www.mql5.com/pt/articles/211

[Vladimir Karputov]

Márcio Andrade:
MT4 с MODE_TRADE подтвердил статус заказа как на рынке, как сделать это подтверждение в MT5?

В MQL5 есть позиции и отложенные ордера.

Перебор списка позиций  и списка отложенных ордеров:

//+------------------------------------------------------------------+
//|                                                       Test_1.mq5 |
//|                              Copyright © 2018, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2018, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.000"
//---
#include <Trade\PositionInfo.mqh>
#include <Trade\SymbolInfo.mqh>  
#include <Trade\OrderInfo.mqh>
CPositionInfo  m_position;                   // trade position object
CSymbolInfo    m_symbol;                     // symbol info object
COrderInfo     m_order;                      // pending orders object
//--- input parameters
input ulong   m_magic=15489;                 // magic number
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   if(!m_symbol.Name(Symbol())) // sets symbol name
      return;
   Print("All positions: ",IntegerToString(CalculateAllPositions())
         ,", all pending orders: ",IntegerToString(CalculateAllPendingOrders()));
  }
//+------------------------------------------------------------------+
//| Calculate all positions                                          |
//+------------------------------------------------------------------+
int CalculateAllPositions()
  {
   int total=0;

   for(int i=PositionsTotal()-1;i>=0;i--)
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==m_magic)
            total++;
//---
   return(total);
  }
//+------------------------------------------------------------------+
//| Calculate all pending orders                                     |
//+------------------------------------------------------------------+
int CalculateAllPendingOrders()
  {
   int total=0;

   for(int i=OrdersTotal()-1;i>=0;i--) // returns the number of current orders
      if(m_order.SelectByIndex(i))     // selects the pending order by index for further access to its properties
         if(m_order.Symbol()==m_symbol.Name() && m_order.Magic()==m_magic)
            total++;
//---
   return(total);
  }
//+------------------------------------------------------------------+

[Marcio Andrade]

Vladimir Karputov:

В MQL5 есть позиции и отложенные ордера.

Перебор списка позиций  и списка отложенных ордеров:

Благодарю! Прекрасная работа.