Нужна помощь в написании мультивалютного индикатора

[Sergey Gritsay]

При написании мультивалютного индикатора сталкнулся с такой проблемой. Постоянно выдает ошибку выход за пределы массива и рисует не понятно что.

Вроде все правильно делаю. Уже весь мозг вынес не пойму где ошибка

#property indicator_separate_window
#property indicator_buffers 4
#property indicator_plots   2
#property indicator_type1   DRAW_LINE
#property indicator_type2   DRAW_LINE
#property indicator_color1  Blue
#property indicator_color2  Red

input int                Period_MA=5;           // Период расчётной МА
input int                Bars_V=13;          // Колич.баров для расчёта скорост
input string             Symbol_1     = "EURUSD";
input string             Symbol_2     = "AUDUSD";
input ENUM_MA_METHOD     MODE_MA     = MODE_SMMA;
input ENUM_APPLIED_PRICE PriceMA     = PRICE_MEDIAN;

double Line_1[];
double Line_2[];
double CalcBuffer_1[];
double CalcBuffer_2[];

int    Handle_1=INVALID_HANDLE;
int    Handle_2=INVALID_HANDLE;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,Line_1,INDICATOR_DATA);
   SetIndexBuffer(1,Line_1,INDICATOR_DATA);
   SetIndexBuffer(2,CalcBuffer_1,INDICATOR_CALCULATIONS);
   SetIndexBuffer(3,CalcBuffer_2,INDICATOR_CALCULATIONS);

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Period_MA+Bars_V);
   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,Period_MA+Bars_V);
   Handle_1=iMA(Symbol_1,0,Period_MA,0,MODE_MA,PriceMA);
   Handle_2=iMA(Symbol_2,0,Period_MA,0,MODE_MA,PriceMA);
   ArrayInitialize(Line_1,0.0);
   ArrayInitialize(CalcBuffer_1,0.0);
   ArrayInitialize(Line_2,0.0);
   ArrayInitialize(CalcBuffer_2,0.0);

//---
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
//--- return value of prev_calculated for next call
   if(Handle_1==INVALID_HANDLE || Handle_1==0)
     {
      Handle_1=iMA(Symbol_1,0,Period_MA,0,MODE_MA,PriceMA);
      return(0);
     }
   if(Handle_2==INVALID_HANDLE || Handle_2==0)
     {
      Handle_2=iMA(Symbol_2,0,Period_MA,0,MODE_MA,PriceMA);
      return(0);
     }
   if(rates_total<Period_MA+Bars_V)return(0);

   int calculated1=BarsCalculated(Handle_1);
   int calculated2=BarsCalculated(Handle_2);

   int to_copy=MathMin(calculated1,calculated2);
   if(to_copy<0)return(0);
//---- get ma buffers
   ArraySetAsSeries(CalcBuffer_1,true);
   if(CopyBuffer(Handle_1,0,0,to_copy,CalcBuffer_1)<to_copy)
     {
      Print("Ошибка копирования данных для первого символа! Error",GetLastError());
      return(0);
     }
//---- get ma buffers
   ArraySetAsSeries(CalcBuffer_2,true);
   if(CopyBuffer(Handle_2,0,0,to_copy,CalcBuffer_2)<to_copy)
     {
      Print("Ошибка копирования данных для второго символа! Error",GetLastError());
      return(0);
     }
   ArraySetAsSeries(Line_1,true);
   ArraySetAsSeries(Line_2,true);

   int limit=to_copy-(Period_MA+Bars_V);

//--- the main loop of calculations
   for(int i=0;i<limit;i++)
     {
      Line_1[i]=CalcBuffer_1[i]-CalcBuffer_1[i+Bars_V];
      Line_2[i]=CalcBuffer_2[i]-CalcBuffer_2[i+Bars_V];
     }

   return(rates_total);
  }
//+------------------------------------------------------------------+

[Igor Makanu]

sergey1294:

При написании мультивалютного индикатора сталкнулся с такой проблемой. Постоянно выдает ошибку выход за пределы массива и рисует не понятно что.

Вроде все правильно делаю. Уже весь мозг вынес не пойму где ошибка

у меня тож такие же проблемы с мультивалютным индикатором - добился, чтобы в терминале не было ошибок, но в тестере все равно сыплет ошибками

у Вас, возможно здесь:

 int limit=to_copy-(Period_MA+Bars_V);

попробуйте повставлять в разные участки кода проверку на выход за пределы массива

int size =ArraySize(CalcBuffer_1);

for(int i=0;i<limit;i++)
  { if (size <i) continue;

....

 я у себя так нашел, а в тестере все равно ошибки

 

[Sergey Gritsay]

Косяк обнаружен вот в этих строках

   SetIndexBuffer(0,Line_1,INDICATOR_DATA);
   SetIndexBuffer(1,Line_1,INDICATOR_DATA);

проиндексировал один и тот же массив под оба буфера

[Sergey]

С аналогичной проблемой я тоже парился. Есть определенные заморочки, но решаемые (там есть ссылка на индикатор, может он поможет).  https://www.mql5.com/ru/forum/1770