Индикаторы: Reversal

Otto Pauser 2019.12.10 22:04 #11

Christian:

Здесь царит разведение и порядок! :-)

...это было мягкое масло с предрождественским очарованием... по крайней мере, мне так показалось.

;)

Otto Pauser 2019.12.11 01:55 #12

Я взял этот Indi и перепрограммировал его.

Из 286 запутанных линий он превратился в 151 четкую линию, а также может делать больше.

Теперь это очень простой индикатор, который имеет потенциал в сочетании, например, с EMA 50 (линия покупки/продажи Стивена Примо) и подходящим выходом.

//+------------------------------------------------------------------+
//|Reversal_V2.0.mq5 |
//| Copyright © 2019, Ing. Отто Паузер |
//| https://www.mql5.com/ru/users/kronenchakra |
//| найдено на https://www.mql5.com/ru/code/19605 |
//+------------------------------------------------------------------+
#property copyright     "Copyright © 2019, Ing. Otto Pauser"
#property link          "https://www.mql5.com/ru/users/kronenchakra"
#property version       "2.00"

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2

//+------------------------------------------------------------------+
//| входные параметры|
//+------------------------------------------------------------------+
input int   inp_PeriodBack    =      10;  // Периоды обратного просмотра
input int   inp_ArrowCodeDN   =     242;  // ArrowCode sell
input int   inp_ArrowCodeUP   =     241;  // ArrowCode buy
input color inp_ArrowColorDN  =  clrRed;  // ArrowColor sell
input color inp_ArrowColorUP  = clrLime;  // ArrowColor buy
input int   inp_ArrowSize     =       3;  // ArrowSize
input int   inp_ArrowOffs     =      30;  // ArrowOffset
input bool  inp_DrawRange     =    true;  // Нарисуйте проверенный диапазон
input bool  inp_SendMail      =   false;  // Отправка почты по сигналу

//+------------------------------------------------------------------+
//| индикаторные буферы|
//+------------------------------------------------------------------+
double buDN[];    // буфер Стрелки вниз
double buUP[];    // буфер Стрелки вверх

//+------------------------------------------------------------------+
//| Пользовательская функция инициализации индикатора |
//+------------------------------------------------------------------+
int OnInit()
{
   InitArrows(buDN,inp_ArrowCodeDN,inp_ArrowColorDN,inp_ArrowSize,-inp_ArrowOffs,"Sell");
   InitArrows(buUP,inp_ArrowCodeUP,inp_ArrowColorUP,inp_ArrowSize,+inp_ArrowOffs,"Buy" );
   return(INIT_SUCCEEDED);
}

//+------------------------------------------------------------------+
//| Пользовательская функция итерации индикатора |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
   ArraySetAsSeries(high ,true);
   ArraySetAsSeries(close,true);
   ArraySetAsSeries(open ,true);
   ArraySetAsSeries(low  ,true);
   ArraySetAsSeries(time ,true);

   int limit=(prev_calculated==0)?0:rates_total-prev_calculated-1;

   for(int i=limit; i>=0; i--)
      {
         buDN[i]=NULL;
         buUP[i]=NULL;
         
         if(i>=MathMin(5000-1,rates_total-1-50)) continue; //с некоторыми старыми тарифами, чтобы предотвратить "Array out of range" или медленное вычисление

                                                      //Стрелки вниз
         if(high[1+i]==HH(high,inp_PeriodBack))       //Candlestick High равен Resistance
            if(close[1+i]<open[1+i])                  //Candlestick Close < Candlestick Open (медвежий бар)
               {
                  buDN[i]=high[i];                    //Установка значения индикатора по максимуму свечи
                  if(i==1) 
                     myAlert(time[1],"Sell");         //Оповещение о следующем открытии бара
               }
                                                      //Стрелки вверх
         if(low[1+i]==LL(low,inp_PeriodBack))         //Candlestick Low равен поддержке
            if(close[1+i]>open[1+i])                  //Candlestick Close > Candlestick Open (бычий бар)
               {
                  buUP[i]=low[i];                     //Установка значения индикатора на нижней границе свечи
                  if(i==1) 
                     myAlert(time[1],"Buy");          //Оповещение о следующем открытии бара
               }
      }

   if(inp_DrawRange)
      DrawRange("Range",time[inp_PeriodBack],HH(high,inp_PeriodBack),time[0],LL(low,inp_PeriodBack));

   return(rates_total);
}

//+------------------------------------------------------------------+
void myAlert(datetime aTime, string aMsg)    // Функция оповещения
{
   static datetime lastTime=NULL;
   if(aTime!=lastTime)
      {
         aMsg="Reversal_V2.9 @ "+_Symbol+","+PeriodShortStr(_Period)+" -> "+aMsg;
         Print(aMsg);
         if(inp_SendMail) 
            SendMail("Reversal_V2.9", aMsg);
         lastTime=aTime;
      }
}

string PeriodShortStr(ENUM_TIMEFRAMES _tf)            // отсечение ведущих 'PERIOD_' / возвращает 'M1', 'M10', .... 
{
   return(StringSubstr(EnumToString(_tf),7));
}

//+------------------------------------------------------------------+
double HH(const double &aBuffer[], int aPeriBack)     // самый высокий максимум периода в обратном направлении
{
   return(aBuffer[ArrayMaximum(aBuffer,0,aPeriBack)]);
}

double LL(const double &aBuffer[], int aPeriBack)     // самый низкий минимум периода в обратном направлении
{
   return(aBuffer[ArrayMinimum(aBuffer,0,aPeriBack)]);
}

void DrawRange(string aName, datetime aBegin, double aHigh, datetime aEnd, double aLow)
{
   if(ObjectFind   (0,aName)==0) 
      ObjectDelete (0,aName);
   ObjectCreate    (0,aName,OBJ_RECTANGLE,0,aBegin,aHigh,aEnd,aLow);
   ObjectSetInteger(0,aName,OBJPROP_STYLE,STYLE_DASHDOT);
}
//+------------------------------------------------------------------+
//| инициируйте индикаторный буфер со стрелками|
//+------------------------------------------------------------------+
void InitArrows(double &aBuffer[], int aArrowCode, color aArrowColor, int aArrowSize, int aArrowOffs, string aPlotLabel)
{
   static int idx=0;
   SetIndexBuffer(idx,aBuffer,INDICATOR_DATA);
   PlotIndexSetInteger(idx,PLOT_DRAW_TYPE  ,DRAW_ARROW);
   PlotIndexSetInteger(idx,PLOT_ARROW      ,aArrowCode);
   PlotIndexSetInteger(idx,PLOT_LINE_COLOR ,aArrowColor);
   PlotIndexSetInteger(idx,PLOT_LINE_WIDTH ,aArrowSize);
   PlotIndexSetInteger(idx,PLOT_ARROW_SHIFT,aArrowOffs);
   PlotIndexSetString (idx,PLOT_LABEL      ,aPlotLabel);
   PlotIndexSetDouble (idx,PLOT_EMPTY_VALUE,NULL);
   ArrayInitialize    (aBuffer,NULL);
   ArraySetAsSeries   (aBuffer,true);
   idx++;
}

Этот индикатор - хороший кандидат для моей домашней страницы, которая появится в Интернете в начале следующего года.

Файлы:

Reversal_V2.0.mq5 14 kb

Функция ICustom Помощь в кодировании Конверт 2.11

Nibelungen 2019.12.11 23:36 #13

Otto Pauser:

Я взял этот Indi и перепрограммировал его.

С 286 запутанных линий я сократил до 151 четкой линии и могу делать больше.

Теперь это очень простой индикатор, который в сочетании с EMA 50 (линия покупки/продажи Стивена Примо) и подходящим выходом, например, определенно имеет потенциал.

Этот индикатор - хороший кандидат для моей домашней страницы, которая появится в Интернете в начале следующего года.

Очень мило с вашей стороны! Я сразу же опробовал его, и он отлично работает. Большое спасибо!

CDBCM170270 2020.08.05 02:01 #14

не работает

Juan David Paternina Hernandez 2023.03.17 19:15 #15

не работает

Joseph Kisakye 2024.01.23 02:32 #16

есть ошибки при компиляции в мета-редакторе. пожалуйста, исправьте, если это возможно. спасибо за бесплатное предложение такой потенциально отличной концепции индикатора

bitcoin razak 2024.09.10 13:43 #17

Joseph Kisakye #:
есть ошибки при компиляции в мета-редакторе. пожалуйста, исправьте, если возможно. спасибо за бесплатное предложение такой потенциально отличной концепции индикатора

это код, измененный для отсутствия ошибок.

//+------------------------------------------------------------------+
//|Индикатор: разворот.mq5 |
//||
//||
//+------------------------------------------------------------------+
#property copyright "Sergey Vradiy"
#property version   "1.00"
#property description ""

//--- настройки индикатора
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots 2

#property indicator_type1 DRAW_ARROW
#property indicator_width1 3
#property indicator_color1 0x0000FF
#property indicator_label1 "Sell"

#property indicator_type2 DRAW_ARROW
#property indicator_width2 3
#property indicator_color2 0xFFAA00
#property indicator_label2 "Buy"

//--- индикаторные буферы
double Buffer1[];
double Buffer2[];

input int Interval=10;
datetime time_alert;     //используется при отправке оповещения
input bool Send_Email=true;
double myPoint; //инициализируется в OnInit

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
void myAlert(string type,string message)
{
   if(type=="print")
      Print(message);
   else if(type=="error")
   {
      Print(type+" | reversal @ "+Symbol()+","+(string)Period()+" | "+message);
   }
   else if(type=="indicator")
   {
      if(Send_Email)
         SendMail("reversal",type+" | reversal @ "+Symbol()+","+(string)Period()+" | "+message);
   }
}
//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
void DrawLine(string objname,double price,int count,int start_index) //создает или изменяет существующий объект, если это необходимо
{
   if((price<0) && ObjectFind(0,objname)>=0)
   {
      ObjectDelete(0,objname);
   }
   else if(ObjectFind(0,objname)>=0 && ObjectGetInteger(0,objname,OBJPROP_TYPE)==OBJ_TREND)
   {
      datetime Time[];
      ArraySetAsSeries(Time,true);
      CopyTime(Symbol(),Period(),0,start_index+count,Time);
      ObjectSetInteger(0,objname,OBJPROP_TIME,Time[start_index]);
      ObjectSetDouble(0,objname,OBJPROP_PRICE,price);
      ObjectSetInteger(0,objname,OBJPROP_TIME,1,Time[start_index+count-1]);
      ObjectSetDouble(0,objname,OBJPROP_PRICE,1,price);
   }
   else
   {
      datetime Time[];
      ArraySetAsSeries(Time,true);
      CopyTime(Symbol(),Period(),0,start_index+count,Time);
      ObjectCreate(0,objname,OBJ_TREND,0,Time[start_index],price,Time[start_index+count-1],price);
      ObjectSetInteger(0,objname,OBJPROP_RAY_LEFT,0);
      ObjectSetInteger(0,objname,OBJPROP_RAY_RIGHT,0);
      ObjectSetInteger(0,objname,OBJPROP_COLOR,C'0x00,0x00,0xFF');
      ObjectSetInteger(0,objname,OBJPROP_STYLE,STYLE_SOLID);
      ObjectSetInteger(0,objname,OBJPROP_WIDTH,2);
   }
}
//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
double Support(int time_interval,bool fixed_tod,int hh,int mm,bool draw,int shift)
{
   int start_index=shift;
   int count=time_interval/PeriodSeconds();
   if(fixed_tod)
   {
      datetime start_time;
      datetime Time[];
      ArraySetAsSeries(Time,true);
      CopyTime(Symbol(),Period(),0,Bars(Symbol(),Period())-count,Time);
      if(shift==0)
         start_time=TimeCurrent();
      else
         start_time=Time[shift-1];
      datetime dt=StringToTime(TimeToString(start_time,TIME_DATE)+" "+(string)hh+":"+(string)mm); //ближайшее время чч:мм
      if(dt>start_time)
         dt-=86400; //вернуться на 24 часа назад
      int dt_index = iBarShift(Symbol(), Period(), dt, true);
      datetime dt2 = dt;
      while(dt_index<0 && dt>Time[Bars(Symbol(),Period())-1-count]) //бар не найден => смотреть несколько дней назад
      {
         dt-=86400; //вернуться на 24 часа назад
         dt_index=iBarShift(Symbol(),Period(),dt,true);
      }
      if(dt_index<0) //По-прежнему не найдено => найдите ближайший бар
         dt_index =iBarShift(Symbol(), Period(), dt2, false);
      start_index=dt_index+1; //бар после открытия S/R в dt
   }
   double _Low[];
   ArraySetAsSeries(_Low,true);
   CopyLow(Symbol(),Period(),start_index,count,_Low);
   double ret=_Low[ArrayMinimum(_Low,0,count)];
   if(draw) DrawLine("Support",ret,count,start_index);
   return(ret);
}
//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
double Resistance(int time_interval,bool fixed_tod,int hh,int mm,bool draw,int shift)
{
   int start_index=shift;
   int count=time_interval/PeriodSeconds();
   if(fixed_tod)
   {
      datetime start_time;
      datetime Time[];
      ArraySetAsSeries(Time,true);
      CopyTime(Symbol(),Period(),0,Bars(Symbol(),Period())-count,Time);
      if(shift==0)
         start_time=TimeCurrent();
      else
         start_time=Time[shift-1];
      datetime dt=StringToTime(TimeToString(start_time,TIME_DATE)+" "+(string)hh+":"+(string)mm); //ближайшее время чч:мм
      if(dt>start_time)
         dt-=86400; //вернуться на 24 часа назад
      int dt_index = iBarShift(Symbol(), Period(), dt, true);
      datetime dt2 = dt;
      while(dt_index<0 && dt>Time[Bars(Symbol(),Period())-1-count]) //бар не найден => смотреть несколько дней назад
      {
         dt-=86400; //вернуться на 24 часа назад
         dt_index=iBarShift(Symbol(),Period(),dt,true);
      }
      if(dt_index<0) //По-прежнему не найдено => найдите ближайший бар
         dt_index =iBarShift(Symbol(), Period(), dt2, false);
      start_index=dt_index+1; //бар после открытия S/R в dt
   }
   double _High[];
   ArraySetAsSeries(_High,true);
   CopyHigh(Symbol(),Period(),start_index,count,_High);
   double ret=_High[ArrayMaximum(_High,0,count)];
   if(draw) DrawLine("Resistance",ret,count,start_index);
   return(ret);
}
//+------------------------------------------------------------------+
//| Пользовательская функция инициализации индикатора |
//+------------------------------------------------------------------+
int OnInit()
{
   SetIndexBuffer(0,Buffer1);
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
   PlotIndexSetInteger(0,PLOT_ARROW,242);
   SetIndexBuffer(1,Buffer2);
   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0);
   PlotIndexSetInteger(1,PLOT_ARROW,241);

   //инициализация myPoint
   myPoint=Point();
   if(Digits()==5 || Digits()==3)
   {
      myPoint*=10;
   }
   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Пользовательская функция итерации индикатора|
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
   int limit=rates_total-prev_calculated;
   if(limit<=0) return(rates_total);

//--- подсчет от 0 до rates_total
   ArraySetAsSeries(Buffer1,true);
   ArraySetAsSeries(Buffer2,true);

   //--- начальный ноль
   if(prev_calculated<1)
   {
      ArrayInitialize(Buffer1,0);
      ArrayInitialize(Buffer2,0);
   }
   else
      limit++;

   //--- главный цикл
   for(int i=limit-1; i>=0; i--)
   {
      if(i>=MathMin(5000-1,rates_total-1-50)) continue; //удалить старые тарифы

      //Индикаторный буфер 1 (продажа)
      if(high[i]==Resistance(Interval*PeriodSeconds(),false,00,00,false,i)
         && close[i]<open[i]) //Состояние для продажи
      {
         Buffer1[i]=high[i]; //Установка значения индикатора по максимуму свечи
         if(i==1 && time[1]!=time_alert)
            myAlert("indicator","Sell"); //Оповещение о следующем открытии бара
         time_alert=time[1];
      }
      else
      {
         Buffer1[i]=0;
      }

      //Индикаторный буфер 2 (Купить)
      if(low[i]==Support(Interval*PeriodSeconds(),false,00,00,false,i)
         && close[i]>open[i]) //Условия для покупки
      {
         Buffer2[i]=low[i]; //Установка значения индикатора на нижней границе свечи
         if(i==1 && time[1]!=time_alert)
            myAlert("indicator","Buy"); //Оповещение о следующем открытии бара
         time_alert=time[1];
      }
      else
      {
         Buffer2[i]=0;
      }
   }
   return(rates_total);
}
//+------------------------------------------------------------------+

Joseph Kisakye 2025.01.30 16:32 #18

bitcoin razak #:

Это код, измененный для отсутствия ошибки.

Спасибо, Разак, обновленный код успешно скомпилировался. Позвольте мне протестировать его и посмотреть, работает ли он так, как объясняется в вашем вступлении.

Я протестировал индикатор, используя настройки по умолчанию, но не вижу стрелок покупки и продажи на графике. Пожалуйста, пересмотрите код, если эта ошибка подтвердится. Спасибо

Советники: Ravi AO Когда будет запущен рынок Индикаторы: Keltner Channel

Индикаторы: Reversal - страница 2