В чём может быть проблема неправильного открытия ордеров?

[Удален] 2014.07.24 12:01

Здравствуйте. Я хотел написать советник, но уже мучаюсь неделю. У меня не получается привязать советник к цвету индикатора, эксперт должен открывать ордер на переключении цвета. Как бы я не писал условие, советник открывает ордера неправильно. Помогите, пожалуйста.

Код эксперта:

//+------------------------------------------------------------------+
//|                                                 FirstRenkoEA.mq4 |
//|                        Copyright 2014, MetaQuotes Software Corp. |
//|                                        https://www.metaquotes.net |
//+------------------------------------------------------------------+
#property copyright "Copyright 2014, MetaQuotes Software Corp."
#property link      "https://www.metaquotes.net"

extern int Stop = 20;
extern double multipler = 2;
extern double FixLot = 0.1;
extern double PercentRisk = 2;
extern bool Revers = true;
// extern int StartTrade = 10;   
// extern int StopTrade = 17;
extern int period1 = 9;
extern int period2 = 14;   

#include <stdlib.mqh>   

bool   gbDisabled    = False;          // Флаг блокировки советника
color  clOpenBuy     = LightBlue;      // Цвет значка открытия покупки
color  clOpenSell    = LightCoral;     // Цвет значка открытия продажи
color  clModifyBuy   = Aqua;           // Цвет значка модификации покупки
color  clModifySell  = Tomato;         // Цвет значка модификации продажи
int    Slippage      = 3;              // Проскальзывание цены
int    NumberOfTry   = 5;              // Количество торговых попыток
bool   UseSound      = True;           // Использовать звуковой сигнал
string NameFileSound = "expert.wav";   // Наименование звукового файла  





//+------------------------------------------------------------------+
//| expert initialization function                                   |
//+------------------------------------------------------------------+
int init()
  {
   if (Digits == 3 || Digits == 5)
   {
   Stop*=10;   
   } 
   return(0);
  }
//+------------------------------------------------------------------+
//| expert deinitialization function                                 |
//+------------------------------------------------------------------+
int deinit()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert start function                                            |
//+------------------------------------------------------------------+
int start()
  {
  int ticket;
  int Take = Stop*multipler;
  double SL, TP;
  
  
    //  Проверяем, нет ли активных ордеров по паре на которой работает советник. 
  int b=0,s=0;
  for(int f=OrdersTotal()-1; f>=0; f--)
    if(OrderSelect(f,SELECT_BY_POS)==true)
      if(OrderSymbol()==Symbol())
           {
            if(OrderType()==0)b++; // Колличество бай ордеров по символу на который установлен советник.
            if(OrderType()==1)s++; // Колличество сел ордеров по символу на который установлен советник.
           }
  
   double MAR1 = iCustom(Symbol(), 0, "4321", 0, 1);
   double MAL1 = iCustom(Symbol(), 0, "4321", 1, 1);
   
   double MAR2 = iCustom(Symbol(), 0, "4321", 0, 2);
   double MAL2 = iCustom(Symbol(), 0, "4321", 1, 2);
       
   
   double Lot;
   if (FixLot>0)
   {
   Lot = FixLot;
   }
   else if (FixLot==0)
   {
   Lot = LotsByRisk(PercentRisk, Stop);
   }
  
    //  Проверяем условия и проводим операции с ордерами.
  if (MAL1 > 0 && MAR2 > 0 && b==0 && s==0)
  { 
  ticket = OpenPosition(NULL, OP_BUY, Lot);
  
     if (OrderSelect(ticket, SELECT_BY_TICKET))
     {
     SL = NormalizeDouble(Ask - Stop*Point, Digits);
     TP = NormalizeDouble(Ask + Take*Point, Digits);
     ModifyOrder(0, SL, TP);
     }     
  }  
   
  if (MAR1 > 0 && MAL2 > 0 && b==0 && s==0)
  { 
  ticket = OpenPosition(NULL, OP_SELL, Lot);
  
     if (OrderSelect(ticket, SELECT_BY_TICKET))
     {
     SL = NormalizeDouble(Bid + Stop*Point, Digits);
     TP = NormalizeDouble(Bid - Take*Point, Digits);
     ModifyOrder(0, SL, TP);
     }     
  }  
  
    // Revers.
  if (Revers == true)
  {
    
   if (MAL1 > 0 && MAR2 > 0 && s==1)
   {
   CloseAllPos();
   }
  
   if (MAR1 > 0 && MAL2 > 0 && b==1)
   {
   CloseAllPos();
   }
  
  }   
    
  

   return(0);
  }
//+------------------------------------------------------------------+
// Функции.
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 06.03.2008                                                     |
//|  Описание : Возвращает флаг существования позиций                          |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//|    ot - время открытия             ( 0   - любое время открытия)           |
//+----------------------------------------------------------------------------+
bool ExistPositions(string sy="", int op=-1, int mn=-1, datetime ot=0) {
  int i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (ot<=OrderOpenTime()) return(True);
            }
          }
        }
      }
    }
  }
  return(False);
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 01.09.2005                                                     |
//|  Описание : Возвращает наименование торговой операции                      |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    op - идентификатор торговой операции                                    |
//+----------------------------------------------------------------------------+
string GetNameOP(int op) {
  switch (op) {
    case OP_BUY      : return("Buy");
    case OP_SELL     : return("Sell");
    case OP_BUYLIMIT : return("Buy Limit");
    case OP_SELLLIMIT: return("Sell Limit");
    case OP_BUYSTOP  : return("Buy Stop");
    case OP_SELLSTOP : return("Sell Stop");
    default          : return("Unknown Operation");
  }
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 01.09.2005                                                     |
//|  Описание : Возвращает наименование таймфрейма                             |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    TimeFrame - таймфрейм (количество секунд)      (0 - текущий ТФ)         |
//+----------------------------------------------------------------------------+
string GetNameTF(int TimeFrame=0) {
  if (TimeFrame==0) TimeFrame=Period();
  switch (TimeFrame) {
    case PERIOD_M1:  return("M1");
    case PERIOD_M5:  return("M5");
    case PERIOD_M15: return("M15");
    case PERIOD_M30: return("M30");
    case PERIOD_H1:  return("H1");
    case PERIOD_H4:  return("H4");
    case PERIOD_D1:  return("Daily");
    case PERIOD_W1:  return("Weekly");
    case PERIOD_MN1: return("Monthly");
    default:                 return("UnknownPeriod");
  }
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 01.09.2005                                                     |
//|  Описание : Вывод сообщения в коммент и в журнал                           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    m - текст сообщения                                                     |
//+----------------------------------------------------------------------------+
void Message(string m) {
  Comment(m);
  if (StringLen(m)>0) Print(m);
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 28.11.2006                                                     |
//|  Описание : Модификация одного предварительно выбранного ордера.           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    pp - цена установки ордера                                              |
//|    sl - ценовой уровень стопа                                              |
//|    tp - ценовой уровень тейка                                              |
//|    cl - цвет значка модификации                                            |
//+----------------------------------------------------------------------------+
void ModifyOrder(double pp=-1, double sl=0, double tp=0, color cl=CLR_NONE) {
  bool   fm;
  double op, pa, pb, os, ot;
  int    dg=MarketInfo(OrderSymbol(), MODE_DIGITS), er, it;

  if (pp<=0) pp=OrderOpenPrice();
  if (sl<0 ) sl=OrderStopLoss();
  if (tp<0 ) tp=OrderTakeProfit();
  
  pp=NormalizeDouble(pp, dg);
  sl=NormalizeDouble(sl, dg);
  tp=NormalizeDouble(tp, dg);
  op=NormalizeDouble(OrderOpenPrice() , dg);
  os=NormalizeDouble(OrderStopLoss()  , dg);
  ot=NormalizeDouble(OrderTakeProfit(), dg);

  if (pp!=op || sl!=os || tp!=ot) {
    for (it=1; it<=NumberOfTry; it++) {
      if (!IsTesting() && (!IsExpertEnabled() || IsStopped())) break;
      while (!IsTradeAllowed()) Sleep(5000);
      RefreshRates();
      fm=OrderModify(OrderTicket(), pp, sl, tp, 0, cl);
      if (fm) {
        if (UseSound) PlaySound(NameFileSound); break;
      } else {
        er=GetLastError();
        pa=MarketInfo(OrderSymbol(), MODE_ASK);
        pb=MarketInfo(OrderSymbol(), MODE_BID);
        Print("Error(",er,") modifying order: ",ErrorDescription(er),", try ",it);
        Print("Ask=",pa,"  Bid=",pb,"  sy=",OrderSymbol(),
              "  op="+GetNameOP(OrderType()),"  pp=",pp,"  sl=",sl,"  tp=",tp);
        Sleep(1000*10);
      }
    }
  }
}

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 21.03.2008                                                     |
//|  Описание : Открывает позицию и возвращает её тикет.                       |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (NULL или "" - текущий символ)          |
//|    op - операция                                                           |
//|    ll - лот                                                                |
//|    sl - уровень стоп                                                       |
//|    tp - уровень тейк                                                       |
//|    mn - MagicNumber                                                        |
//+----------------------------------------------------------------------------+
int OpenPosition(string sy, int op, double ll, double sl=0, double tp=0, int mn=0) {
  color    clOpen;
  datetime ot;
  double   pp, pa, pb;
  int      dg, err, it, ticket=0;
  string   lsComm=WindowExpertName()+" "+GetNameTF(Period());

  if (sy=="" || sy=="0") sy=Symbol();
  if (op==OP_BUY) clOpen=clOpenBuy; else clOpen=clOpenSell;
  for (it=1; it<=NumberOfTry; it++) {
    if (!IsTesting() && (!IsExpertEnabled() || IsStopped())) {
      Print("OpenPosition(): Остановка работы функции");
      break;
    }
    while (!IsTradeAllowed()) Sleep(5000);
    RefreshRates();
    dg=MarketInfo(sy, MODE_DIGITS);
    pa=MarketInfo(sy, MODE_ASK);
    pb=MarketInfo(sy, MODE_BID);
    if (op==OP_BUY) pp=pa; else pp=pb;
    pp=NormalizeDouble(pp, dg);
    ot=TimeCurrent();
    ticket=OrderSend(sy, op, ll, pp, Slippage, sl, tp, lsComm, mn, 0, clOpen);
    if (ticket>0) {
      if (UseSound) PlaySound(NameFileSound); break;
    } else {
      err=GetLastError();
      if (pa==0 && pb==0) Message("Проверьте в Обзоре рынка наличие символа "+sy);
      // Вывод сообщения об ошибке
      Print("Error(",err,") opening position: ",ErrorDescription(err),", try ",it);
      Print("Ask=",pa," Bid=",pb," sy=",sy," ll=",ll," op=",GetNameOP(op),
            " pp=",pp," sl=",sl," tp=",tp," mn=",mn);
      // Блокировка работы советника
      if (err==2 || err==64 || err==65 || err==133) {
        gbDisabled=True; break;
      }
      // Длительная пауза
      if (err==4 || err==131 || err==132) {
        Sleep(1000*300); break;
      }
      if (err==128 || err==142 || err==143) {
        Sleep(1000*66.666);
        if (ExistPositions(sy, op, mn, ot)) {
          if (UseSound) PlaySound(NameFileSound); break;
        }
      }
      if (err==140 || err==148 || err==4110 || err==4111) break;
      if (err==141) Sleep(1000*100);
      if (err==145) Sleep(1000*17);
      if (err==146) while (IsTradeContextBusy()) Sleep(1000*11);
      if (err!=135) Sleep(1000*7.7);
    }
  }
  return(ticket);
}
//+----------------------------------------------------------------------------+
double LotsByRisk (double risk, double sl)
{
 double lot_min = MarketInfo(Symbol(), MODE_MINLOT);
 double lot_max = MarketInfo(Symbol(), MODE_MAXLOT);
 double lot_step = MarketInfo(Symbol(), MODE_LOTSTEP);
 double lotcoast = MarketInfo(Symbol(), MODE_TICKVALUE);
 
 
 double lot = AccountBalance() * risk/100;
 double UsdPerPip = lot/sl;
 
 lot = NormalizeDouble(UsdPerPip/lotcoast, 2);
 lot = NormalizeDouble(lot/lot_step, 0) * lot_step;
 
 if (lot < lot_min) lot = lot_min;
 if (lot > lot_max) lot = lot_max;
 
  return(lot);
}
//+----------------------------------------------------------------------------+
int CloseAllPos()
{
for(int i=0;i<OrdersTotal();i++){
if(true==OrderSelect(i, SELECT_BY_POS, MODE_TRADES))
{if(OrderSymbol()==Symbol())
{ if(OrderType()==OP_BUY){OrderClose(OrderTicket(),OrderLots(),Bid,Yellow);i--;}
  if(OrderType()==OP_SELL){OrderClose(OrderTicket(),OrderLots(),Ask,Yellow);i--;}
}}
}// end for
//=====
return(0);
}

Функции Игоря Кима можно не проверять, они работают исправно в других моих советниках.

Заранее благодарен, с уважением.

Vladimir Paukas 2014.07.24 15:34 #1

А в чем заключается неправильность?

[Удален] 2014.07.24 18:50 #2

paukas:
А в чем заключается неправильность?

[quote]Как бы я не писал условие, советник открывает ордера неправильно.[/quote]

Советник должен открывать один ордер на смене цвета, а он открывает множество ордеров, тип которых вообще не зависит от цвета индикатора. Т.е. индикатор зеленый, а советник открывает продажу, и наоборот. Вопрос заключается в том, чтобы правильно составить условие для открытия ордера. С другими индикаторами такого типа у меня небыло проблем. Я просто присваивал переменной буфер индикатора, который отвечал за определенный цвет, и если значение этой переменной становилось больше нуля, то это означало что индикатор принял определенный цвет. На основании этих данных я и писал условия. Но с этим индикатором этот принцип не работает по неизвестным мне причинам, вот я и обратился за помощью.

[ВНИМАНИЕ, ТЕМА ЗАКРЫТА!] Любой Любой вопрос новичка, чтоб [Архив!] Любой вопрос новичка,

Artyom Trishkin 2014.07.24 21:13 #3

Hurricanas:

[quote]Как бы я не писал условие, советник открывает ордера неправильно.[/quote]

Уже раннее утро, а я ещё не ложился, так что глядеть индикатор нет сил. Посему сделаю просто подсказку: повесьте его на график, нажмите Ctrl+D - откроется окно данных. Водите мышкой по барам и глядите что содержится в буферах индикатора в окне данных. Побарно. И не забывайте что есть ещё, кроме нулевых значений буфера, пустое значение EMPTY_VALUE, которое в числовом представлении больше ноля, так что с ним ещё сравнивайте.

Закрытый код Как привязать подобный индикатор Скользящая средняя(SMA) в количестве

Vitalie Postolache 2014.07.25 05:40 #4

тема - близнец этой, https://www.mql5.com/ru/forum/152499

[Удален] 2014.07.25 07:09 #5

artmedia70:
Уже раннее утро, а я ещё не ложился, так что глядеть индикатор нет сил. Посему сделаю просто подсказку: повесьте его на график, нажмите Ctrl+D - откроется окно данных. Водите мышкой по барам и глядите что содержится в буферах индикатора в окне данных. Побарно. И не забывайте что есть ещё, кроме нулевых значений буфера, пустое значение EMPTY_VALUE, которое в числовом представлении больше ноля, так что с ним ещё сравнивайте.

Спасибо, разобрался!

if (MAL1 != EMPTY_VALUE && MAR2 != EMPTY_VALUE && b==0 && s==0)
{
// Open buy.
}

Новый комментарий