Скачать MetaTrader 5
Авторизуйтесь или зарегистрируйтесь, чтобы добавить комментарий
Не знаешь, как пользоваться виджетом? Прочитай об этом статью!
dmitriy
250
dmitriy 2013.12.30 00:01 
вот код индикатора ! я думаю многие знают что за индикатор и описание не нужно
#property copyright ""
#property link      ""

#property indicator_separate_window
#property indicator_buffers 7
#property indicator_color1 Red
#property indicator_color2 DeepSkyBlue
#property indicator_color3 Yellow
#property indicator_color4 Lime
#property indicator_color5 White
#property indicator_color6 Magenta
#property indicator_color7 Maroon

#property indicator_width1 2
#property indicator_width2 2
#property indicator_width3 2
#property indicator_width4 2
#property indicator_width5 2
#property indicator_width6 2


extern int     NumberOfBars = 500;
extern string  Note = "0 means Display all bars";
extern int     MAPeriod = 100;
extern int     LookBack = 20;


double red[],blue[],yellow[],green[],white[],magenta[],v4[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- indicators
      SetIndexBuffer(0,red);
      SetIndexStyle(0,DRAW_HISTOGRAM);
      SetIndexLabel(0,"Climax High ");
      
      SetIndexBuffer(1,blue);
      SetIndexStyle(1,DRAW_HISTOGRAM);
      SetIndexLabel(1,"Neutral");
      
      SetIndexBuffer(2,yellow);
      SetIndexStyle(2,DRAW_HISTOGRAM);
      SetIndexLabel(2,"Low ");
      
      SetIndexBuffer(3,green);
      SetIndexStyle(3,DRAW_HISTOGRAM);
      SetIndexLabel(3,"HighChurn ");
      
      SetIndexBuffer(4,white);
      SetIndexStyle(4,DRAW_HISTOGRAM);
      SetIndexLabel(4,"Climax Low ");
      
      SetIndexBuffer(5,magenta);
      SetIndexStyle(5,DRAW_HISTOGRAM);
      SetIndexLabel(5,"ClimaxChurn ");
      
      SetIndexBuffer(6,v4);
      SetIndexStyle(6,DRAW_LINE,0,2);
      SetIndexLabel(6,"Average("+MAPeriod+")");
      
      IndicatorShortName("Better Volume 1.4" );
      

//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//----
  
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
  
   double VolLowest,Range,Value2,Value3,HiValue2,HiValue3,LoValue3,tempv2,tempv3,tempv;
   int limit;
   int counted_bars=IndicatorCounted();
//---- last counted bar will be recounted
   if(counted_bars>0) counted_bars--;
   if ( NumberOfBars == 0 ) 
      NumberOfBars = Bars-counted_bars;
   limit=NumberOfBars; //Bars-counted_bars;
   
      
   for(int i=0; i<limit; i++)   
      {
         red[i] = 0; blue[i] = Volume[i]; yellow[i] = 0; green[i] = 0; white[i] = 0; magenta[i] = 0;
         Value2=0;Value3=0;HiValue2=0;HiValue3=0;LoValue3=99999999;tempv2=0;tempv3=0;tempv=0;
         
         
         VolLowest = Volume[iLowest(NULL,0,MODE_VOLUME,20,i)];
         if (Volume[i] == VolLowest)
            {
               yellow[i] = NormalizeDouble(Volume[i],0);
               blue[i]=0;
            }
               
         Range = (High[i]-Low[i]);
         Value2 = Volume[i]*Range;
         
         if (  Range != 0 )
            Value3 = Volume[i]/Range;
            
         
         for ( int n=i;n<i+MAPeriod;n++ )
            {
               tempv= Volume[n] + tempv; 
            } 
          v4[i] = NormalizeDouble(tempv/MAPeriod,0);
         
          
          for ( n=i;n<i+LookBack;n++)
            {
               tempv2 = Volume[n]*((High[n]-Low[n])); 
               if ( tempv2 >= HiValue2 )
                  HiValue2 = tempv2;
                    
               if ( Volume[n]*((High[n]-Low[n])) != 0 )
                  {           
                     tempv3 = Volume[n] / ((High[n]-Low[n]));
                     if ( tempv3 > HiValue3 ) 
                        HiValue3 = tempv3; 
                     if ( tempv3 < LoValue3 )
                        LoValue3 = tempv3;
                  } 
            }
                                      
          if ( Value2 == HiValue2  && Close[i] > (High[i] + Low[i]) / 2 )
            {
               red[i] = NormalizeDouble(Volume[i],0);
               blue[i]=0;
               yellow[i]=0;
            }   
            
          if ( Value3 == HiValue3 )
            {
               green[i] = NormalizeDouble(Volume[i],0);                
               blue[i] =0;
               yellow[i]=0;
               red[i]=0;
            }
          if ( Value2 == HiValue2 && Value3 == HiValue3 )
            {
               magenta[i] = NormalizeDouble(Volume[i],0);
               blue[i]=0;
               red[i]=0;
               green[i]=0;
               yellow[i]=0;
            } 
         if ( Value2 == HiValue2  && Close[i] <= (High[i] + Low[i]) / 2 )
            {
               white[i] = NormalizeDouble(Volume[i],0);
               magenta[i]=0;
               blue[i]=0;
               red[i]=0;
               green[i]=0;
               yellow[i]=0;
            } 
            
         
      }
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
         
как сдеать чтоб когда 1-ый бар на гистограмме был например красным цветом, на нулевом(строищимся) выполнить некое условие!!???? ..ни как не могу это написать не пойму что и с чем склеить(
и очень тормозит в тестере(( как можно ускорить??
Vitalie Postolache
11098
Vitalie Postolache 2013.12.30 00:15  
tehpp:
как сдеать чтоб когда 1-ый бар на гистограмме был например красным цветом, на нулевом(строищимся) выполнить некое условие!!???? ..ни как не могу это написать не пойму что и с чем склеить(
и очень тормозит в тестере(( как можно ускорить??

Про условие подробнее, может при условии "красное" выполнять некое действо? Так на это советник писать надо.

Ускорить можно ограничив количество считаемых баров (задать 500, например, а не NumberOfBars = Bars-counted_bars).

Alekseu Fedotov
730
Alekseu Fedotov 2013.12.30 04:46  
tehpp:

//----
   double red     = iCustom(NULL,0,"BetterVolume 1.4",0,1);
   double blue    = iCustom(NULL,0,"BetterVolume 1.4",1,1);
   double yellow  = iCustom(NULL,0,"BetterVolume 1.4",2,1);
   double green   = iCustom(NULL,0,"BetterVolume 1.4",3,1);
   double white   = iCustom(NULL,0,"BetterVolume 1.4",4,1);
   double magenta = iCustom(NULL,0,"BetterVolume 1.4",5,1); 
   
   if(red!=0 && blue==0 && yellow==0 && green==0 && white==0 && magenta==0)
      {
      // некое условие!!????
      }
//----   

Как-то так
doncilaarcadie
22
doncilaarcadie 2014.07.30 09:23  
Добрый день, помогите пожалуйста кто в программирование разбирается, нужно чтобы когда появляется красный сигнал индикатор выдал звуковой сигнал.
Спасибо.
Artyom Trishkin
69060
Artyom Trishkin 2014.07.30 10:02  
r772ra:


Как-то так

А почему бы в коде индикатора сразу после цикла, перед return(0); не проверить нулевой буфер на первом баре?

      } // конец цикла
//----
   if(red[1]>0) {
      // некое действие
      }
//----
   return(0);
  }
/
Авторизуйтесь или зарегистрируйтесь, чтобы добавить комментарий