Discussão do artigo "Como criar bots para Telegram em MQL5"

Marco vd Heijden 2020.06.26 21:34 #301

SendPhoto

A classe implementou a oportunidade de enviar fotos com duas formas de aplicação.

int SendPhoto(const long chat_id, const string local_path, string &photo_id, const string caption=NULL, const bool common_flag=false, const int timeout=10000)
chat_id	número do chat
local_path	caminho local para a pasta em <pasta de dados>\MQL5\Files
photo_id	identificador da foto carregada no servidor
caption	texto da assinatura abaixo da foto
common_flag	sinalizador de local do arquivo na pasta comum de todos os terminais do cliente \Terminal\Common\Files
tempo limite	tempo limite da operação em milissegundos

Há várias maneiras de enviar uma foto.

CCustomBot bot;

string token = "208375865:AAFnuOjlZ3Wsdan6PAjeqqUtBybe0Di1or8";

bot.Token(token);

string photo_id;
int result=bot.SendPhoto(198289825,"EURUSD1.gif",photo_id,"screenshot");
if(result==0)
   Print("Photo ID: ",photo_id);
else
   Print("Error: ",GetErrorDescription(result));

Estou vendo que você tem um sinal de menos.

Você pode dar uma olhada no arquivo Telegram.mqh.

//+------------------------------------------------------------------+
   int SendPhoto(const long   _chat_id,
                 const string _photo_id,
                 const string _caption=NULL)
     {
      if(m_token==NULL)
         return(ERR_TOKEN_ISEMPTY);

      string out;
      string url=StringFormat("%s/bot%s/sendPhoto",TELEGRAM_BASE_URL,m_token);
      string params=StringFormat("chat_id=%lld&photo=%s",_chat_id,_photo_id);
      if(_caption!=NULL)
         params+="&caption="+UrlEncode(_caption);

      int res=PostRequest(out,url,params,WEB_TIMEOUT);
      if(res!=0)
        {
         //--- resultado da análise
         CJAVal js(NULL,jtUNDEF);
         bool done=js.Deserialize(out);
         if(!done)
            return(ERR_JSON_PARSING);

         //--- obter descrição do erro
         bool ok=js["ok"].ToBool();
         long err_code=js["error_code"].ToInt();
         string err_desc=js["description"].ToStr();
        }
      //--- feito
      return(res);
     }

   //+------------------------------------------------------------------+
   int SendPhoto(string &_photo_id,
                 const string _channel_name,
                 const string _local_path,
                 const string _caption=NULL,
                 const bool _common_flag=false,
                 const int _timeout=10000)
     {
      if(m_token==NULL)
         return(ERR_TOKEN_ISEMPTY);

      string name=StringTrim(_channel_name);
      if(StringGetCharacter(name,0)!='@')
         name="@"+name;

      if(m_token==NULL)
         return(ERR_TOKEN_ISEMPTY);

      ResetLastError();
      //--- copiar o arquivo para o buffer de memória
      if(!FileIsExist(_local_path,_common_flag))
         return(ERR_FILE_NOT_EXIST);

      //---
      int flags=FILE_READ|FILE_BIN|FILE_SHARE_WRITE|FILE_SHARE_READ;
      if(_common_flag)
         flags|=FILE_COMMON;

      //---
      int file=FileOpen(_local_path,flags);
      if(file<0)
         return(_LastError);

      //---
      int file_size=(int)FileSize(file);
      uchar photo[];
      ArrayResize(photo,file_size);
      FileReadArray(file,photo,0,file_size);
      FileClose(file);

      //--- create boundary: (data -> base64 -> 1024 bytes -> md5)
      uchar base64[];
      uchar key[];
      CryptEncode(CRYPT_BASE64,photo,key,base64);
      //---
      uchar temp[1024]={0};
      ArrayCopy(temp,base64,0,0,1024);
      //---
      uchar md5[];
      CryptEncode(CRYPT_HASH_MD5,temp,key,md5);
      //---
      string hash=NULL;
      int total=ArraySize(md5);
      for(int i=0;i<total;i++)
         hash+=StringFormat("%02X",md5[i]);
      hash=StringSubstr(hash,0,16);

      //--- WebRequest
      uchar result[];
      string result_headers;

      string url=StringFormat("%s/bot%s/sendPhoto",TELEGRAM_BASE_URL,m_token);

      //--- 1
      uchar data[];

      //--- adicionar chart_id
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,"--"+hash+"\r\n");
      ArrayAdd(data,"Content-Disposition: form-data; name=\"chat_id\"\r\n");
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,name);
      ArrayAdd(data,"\r\n");

      if(StringLen(_caption)>0)
        {
         ArrayAdd(data,"--"+hash+"\r\n");
         ArrayAdd(data,"Content-Disposition: form-data; name=\"caption\"\r\n");
         ArrayAdd(data,"\r\n");
         ArrayAdd(data,_caption);
         ArrayAdd(data,"\r\n");
        }

      ArrayAdd(data,"--"+hash+"\r\n");
      ArrayAdd(data,"Content-Disposition: form-data; name=\"photo\"; filename=\"lampash.gif\"\r\n");
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,photo);
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,"--"+hash+"--\r\n");

      // SaveToFile("debug.txt",data);

      //---
      string headers="Content-Type: multipart/form-data; boundary="+hash+"\r\n";
      int res=WebRequest("POST",url,headers,_timeout,data,result,result_headers);
      if(res==200)//OK
        {
         //--- excluir lista técnica
         int start_index=0;
         int size=ArraySize(result);
         for(int i=0; i<fmin(size,8); i++)
           {
            if(result[i]==0xef || result[i]==0xbb || result[i]==0xbf)
               start_index=i+1;
            else
               break;
           }

         //---
         string out=CharArrayToString(result,start_index,WHOLE_ARRAY,CP_UTF8);

         //--- resultado da análise
         CJAVal js(NULL,jtUNDEF);
         bool done=js.Deserialize(out);
         if(!done)
            return(ERR_JSON_PARSING);

         //--- obter descrição do erro
         bool ok=js["ok"].ToBool();
         if(!ok)
            return(ERR_JSON_NOT_OK);

         total=ArraySize(js["result"]["photo"].m_e);
         for(int i=0; i<total; i++)
           {
            CJAVal image=js["result"]["photo"].m_e[i];

            long image_size=image["file_size"].ToInt();
            if(image_size<=file_size)
               _photo_id=image["file_id"].ToStr();
           }

         return(0);
        }
      else
        {
         if(res==-1)
           {
            string out=CharArrayToString(result,0,WHOLE_ARRAY,CP_UTF8);
            //Print(out);
            return(_LastError);
           }
         else
           {
            if(res>=100 && res<=511)
              {
               string out=CharArrayToString(result,0,WHOLE_ARRAY,CP_UTF8);
               //Print(out);
               return(ERR_HTTP_ERROR_FIRST+res);
              }
            return(res);
           }
        }
      //--- 
      return(0);
     }

   //+------------------------------------------------------------------+
   int SendPhoto(string &_photo_id,
                 const long _chat_id,
                 const string _local_path,
                 const string _caption=NULL,
                 const bool _common_flag=false,
                 const int _timeout=10000)
     {
      if(m_token==NULL)
         return(ERR_TOKEN_ISEMPTY);

      ResetLastError();
      //--- copiar o arquivo para o buffer de memória
      if(!FileIsExist(_local_path,_common_flag))
         return(ERR_FILE_NOT_EXIST);

      //---
      int flags=FILE_READ|FILE_BIN|FILE_SHARE_WRITE|FILE_SHARE_READ;
      if(_common_flag)
         flags|=FILE_COMMON;

      //---
      int file=FileOpen(_local_path,flags);
      if(file<0)
         return(_LastError);

      //---
      int file_size=(int)FileSize(file);
      uchar photo[];
      ArrayResize(photo,file_size);
      FileReadArray(file,photo,0,file_size);
      FileClose(file);

      //--- create boundary: (data -> base64 -> 1024 bytes -> md5)
      uchar base64[];
      uchar key[];
      CryptEncode(CRYPT_BASE64,photo,key,base64);
      //---
      uchar temp[1024]={0};
      ArrayCopy(temp,base64,0,0,1024);
      //---
      uchar md5[];
      CryptEncode(CRYPT_HASH_MD5,temp,key,md5);
      //---
      string hash=NULL;
      int total=ArraySize(md5);
      for(int i=0;i<total;i++)
         hash+=StringFormat("%02X",md5[i]);
      hash=StringSubstr(hash,0,16);

      //--- WebRequest
      uchar result[];
      string result_headers;

      string url=StringFormat("%s/bot%s/sendPhoto",TELEGRAM_BASE_URL,m_token);

      //--- 1
      uchar data[];

      //--- adicionar chart_id
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,"--"+hash+"\r\n");
      ArrayAdd(data,"Content-Disposition: form-data; name=\"chat_id\"\r\n");
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,IntegerToString(_chat_id));
      ArrayAdd(data,"\r\n");

      if(StringLen(_caption)>0)
        {
         ArrayAdd(data,"--"+hash+"\r\n");
         ArrayAdd(data,"Content-Disposition: form-data; name=\"caption\"\r\n");
         ArrayAdd(data,"\r\n");
         ArrayAdd(data,_caption);
         ArrayAdd(data,"\r\n");
        }

      ArrayAdd(data,"--"+hash+"\r\n");
      ArrayAdd(data,"Content-Disposition: form-data; name=\"photo\"; filename=\"lampash.gif\"\r\n");
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,photo);
      ArrayAdd(data,"\r\n");
      ArrayAdd(data,"--"+hash+"--\r\n");

      // SaveToFile("debug.txt",data);

      //---
      string headers="Content-Type: multipart/form-data; boundary="+hash+"\r\n";
      int res=WebRequest("POST",url,headers,_timeout,data,result,result_headers);
      if(res==200)//OK
        {
         //--- excluir lista técnica
         int start_index=0;
         int size=ArraySize(result);
         for(int i=0; i<fmin(size,8); i++)
           {
            if(result[i]==0xef || result[i]==0xbb || result[i]==0xbf)
               start_index=i+1;
            else
               break;
           }

         //---
         string out=CharArrayToString(result,start_index,WHOLE_ARRAY,CP_UTF8);

         //--- resultado da análise
         CJAVal js(NULL,jtUNDEF);
         bool done=js.Deserialize(out);
         if(!done)
            return(ERR_JSON_PARSING);

         //--- obter descrição do erro
         bool ok=js["ok"].ToBool();
         if(!ok)
            return(ERR_JSON_NOT_OK);

         total=ArraySize(js["result"]["photo"].m_e);
         for(int i=0; i<total; i++)
           {
            CJAVal image=js["result"]["photo"].m_e[i];

            long image_size=image["file_size"].ToInt();
            if(image_size<=file_size)
               _photo_id=image["file_id"].ToStr();
           }

         return(0);
        }
      else
        {
         if(res==-1)
           {
            string out=CharArrayToString(result,0,WHOLE_ARRAY,CP_UTF8);
            //Print(out);
            return(_LastError);
           }
         else
           {
            if(res>=100 && res<=511)
              {
               string out=CharArrayToString(result,0,WHOLE_ARRAY,CP_UTF8);
               //Print(out);
               return(ERR_HTTP_ERROR_FIRST+res);
              }
            return(res);
           }
        }
      //--- 
      return(0);
     }
   //+------------------------------------------------------------------+

Se você olhar o arquivo mqh, verá

      string name=StringTrim(_channel_name);
      if(StringGetCharacter(name,0)!='@')
         name="@"+name;

Portanto, no seu caso, você pode tentar uma modificação como esta

      string name = _channel_name;
      //se(StringGetCharacter(name,0)!='@')
      // name="@"+name;

Keith Watford 2020.06.26 23:35 #302

tdbguy:

Não faça postagens duplicadas!

Excluirei seu tópico e moverei as respostas para cá.

RedProviders 2020.06.29 13:18 #303

John Progton:

Andrey Voytenko Basicamente, adicionei os arquivos que você usa e depois modifiquei o script que tenho para enviar para o telegrama em vez de e-mail ao executar uma ação de negociação. Isso funciona, exceto pelo fato de que, ao abrir uma negociação, ele enviará a mensagem várias vezes

Os mesmos problemas

huwa 2020.07.07 21:03 #304

Confirmo que, com uma pequena modificação da postagem nº 46, o código está funcionando bem no MT5 para enviar alertas aos canais.

Confirmo também que as solicitações de envio ao bot para controle do EA estão funcionando.

Mas alguém conseguiu bloquear essas solicitações do bot para o EA em apenas um "from_id"? Assim, o bot só ouve solicitações de um ID específico.

Discussão do artigo "Metaquotes Qualquer pergunta de novato, Ferramentas para Long &

huwa 2020.07.11 19:14 #305

huwa:

Confirmo que, com uma pequena modificação da postagem nº 46, o código está funcionando bem no MT5 para enviar alertas aos canais.

Confirmo também que as solicitações de envio ao bot para controle do EA estão funcionando.

Mas alguém conseguiu bloquear essas solicitações do bot para o EA em apenas um "from_id"? Assim, o bot só ouve solicitações de um ID específico.

Para aqueles que desejam bloquear a solicitação do bot para o ID da conta do Telegram, encontre esta linha em Telegram.mqh :

//--- filtro
   //if(m_users_filter.Total()==0 || (m_users_filter.Total()>0 && m_users_filter.SearchLinear(msg.from_username)>=0)) //Remover essa linha do código
   if(msg.from_id==??????????)   /Adicione esta linha ao código em que ?????????? é seu ID de conta do Telegram

ade kurniawan 2020.07.21 15:32 #306

Uau, obrigado Andrey Voytenko por compartilhar seu conhecimento, é muito útil para iniciantes como eu

Telegram_Bot_EA e Telegram_Search_EA estão funcionando muito bem, mas não com o último ( Telegram_signal_EA ).

Não recebi sinal em meu canal.

O que eu fiz foi o seguinte:

- Criar um bot, adicionar ao meu canal e definir como administrador

- Alterar seu código com meu indicador

- Alterar o Telegram.mqh para criar um canal privado

Depois de executar o Telegram_singal_EA, consigo ver o nome do meu bot, mas ainda não recebi nenhum sinal.

A cada tick, recebo um erro:

Telegram_Signal_EA GBPUSD,M1: Error:Bad Request

Telegram_Signal_EA GBPUSD,M1: {"ok":false, "error_code":400, "description": "Bad Request: chat not found"}

Você tem alguma sugestão?

Indicadores de múltiplos períodos Qualquer pergunta de novato, Discussão do artigo "Visualização

Andriy Voitenko 2020.07.21 16:10 #307

@ade kurniawan, você deve trabalhar com canais privados usando o ID do bate-papo (e não o nome do canal).

Ade Kurniawan 2020.07.21 16:12 #308

Andrey Voytenko:

@ade kurniawan, você deve trabalhar com canais privados usando o ID do gráfico (e não o nome do canal).

Sim, eu já o alterei. Continua com o mesmo erro. Mesmo que eu mude tudo para o canal público

Herman Makmur 2020.08.01 06:25 #309

Alguém já tentou usar as fontes BOLD ou ITALIC com essa biblioteca?
Tentei usar **bold** __italic__ com markdown na mensagem da seguinte forma, mas não consegui...

"n**boldtext** __italictext__ Balance: $%s parse_mode=MARKDOWN"

O resultado é:

**boldtext** __italictext__ Saldo: $10056.21 parse_mode=MARKDOWN

Discussion of article "How Discussão do artigo "Sistema Como usar indicadores fora

Herman Makmur 2020.08.01 06:44 #310

Não importa....

Encontrei a resposta definindo o sinalizador AsHTML como true...

bot.SendMessage(InpTelegramId,"<b>Balance: $10056.21</b>",true);

Desculpe...

spottypegasus:

Alguém tentou usar as fontes BOLD ou ITALIC com essa biblioteca?
Tentei usar **bold** __italic__ com markdown na mensagem da seguinte forma, mas não consegui...

"n**boldtext** __italictext__ Balance: $%s parse_mode=MARKDOWN"

O resultado é:

**boldtext** __italictext__ Saldo: $10056.21 parse_mode=MARKDOWN

Discussão do artigo "Como criar bots para Telegram em MQL5" - página 31

SendPhoto