Pintar o ultimo candle que fechou de amarelo

Para adicionar comentários, por favor Faça o login ou registrar
emcassio
7
emcassio  

Boa noite,


Alguem me dá uma luz, preciso que uma função que pinta o ultimo candle que acabou de fechar na cor amarela.

Tendo a função eu chamo ela dentro do meu codigo em uma condicional.

Sou iniciante e estou emperrado nessa função especifica.


Grato.

Cid Ougaske
3788
Cid Ougaske  
emcassio:

Boa noite,


Alguem me dá uma luz, preciso que uma função que pinta o ultimo candle que acabou de fechar na cor amarela.

Tendo a função eu chamo ela dentro do meu codigo em uma condicional.

Sou iniciante e estou emperrado nessa função especifica.


Grato.

Olá, seria isso que deseja?  

//--- indicator settings
#property indicator_chart_window
#property indicator_buffers 5
#property indicator_plots   1
#property indicator_label1  "Color" 
#property indicator_type1   DRAW_COLOR_CANDLES
#property indicator_color1  clrWhite,clrYellow
#property indicator_style1  STYLE_SOLID 
#property indicator_width1  1
//--- indicator buffers
double ExtColorCandlesBuffer1[],ExtColorCandlesBuffer2[],ExtColorCandlesBuffer3[],ExtColorCandlesBuffer4[],ExtColorCandlesColors[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
void OnInit()
  {
   SetIndexBuffer(0,ExtColorCandlesBuffer1,INDICATOR_DATA);
   SetIndexBuffer(1,ExtColorCandlesBuffer2,INDICATOR_DATA);
   SetIndexBuffer(2,ExtColorCandlesBuffer3,INDICATOR_DATA);
   SetIndexBuffer(3,ExtColorCandlesBuffer4,INDICATOR_DATA);
   SetIndexBuffer(4,ExtColorCandlesColors,INDICATOR_COLOR_INDEX);
   IndicatorSetString(INDICATOR_SHORTNAME,"color candles");
  }
//+------------------------------------------------------------------+
//| Main                                                             |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   int limit;
   if(prev_calculated==0)
      limit=0;
   else limit=prev_calculated-1;
   for(int i=limit;i<rates_total && !IsStopped();i++)
     {
      ExtColorCandlesBuffer1[i]=open[i];
      ExtColorCandlesBuffer2[i]=high[i];
      ExtColorCandlesBuffer3[i]=low[i];
      ExtColorCandlesBuffer4[i]=close[i];
      
      if(i==rates_total-2)
        {
            ExtColorCandlesColors[i]=1;
        }
      else
        {
            ExtColorCandlesColors[i]=0;
        }
     }
   return(rates_total);
  }
Para adicionar comentários, por favor Faça o login ou registrar