インディケータ: サポートとレジスタンス

新しいコメント
 

サポートとレジスタンス:

「サポートとレジスタンス」インディケータはビルウィリアムズのフラクタルインディケータを使ってサポートとレジスタンスレベルを表示します。

サポートとレジスタンスレベルインディケータ

作者: Nikolay Kositsin

 

インジケータが正しく動作しない。レベルが正しく反映されるのは履歴のみで、新しいバーが 表示されると、そのレベルは追跡されません。

図の赤い線は、インジケータがチャートに取り付けられた瞬間です。その左側はすべて正しく、右側は間違っています。

正解と不正解

 
gdtt:

インジケータが正しく動作しない。レベルが正しく反映されるのはヒストリのみで、新しいバーが 表示されると、それらは追跡されません。

図の赤い線は、インジケータがチャートに取り付けられた瞬間です。その左側はすべて正しく、右側は間違っています。

そうそう、フラクタルが七面鳥の逆算だってこと、すっかり忘れてた！直そう！
 

テクニカル指標

 

MT5の最後のアップデート以降、このインジケータは壊れています。すべてのローソク足の高値と安値に点が表示されるだけです。

何が悪いのでしょうか？

 
yohmm:

MT5の最後のアップデート以降、このインジケータは壊れています。すべてのローソク足の高値と安値に点が表示されるだけです。

何が悪いのでしょうか？

このインジケータは正常に動作しています。ビルド1016
 

はい、Build 1016です。再度インジケータをダウンロードし、再コンパイルしました。ただ、高値と安値に点が表示されるだけです。

でも大丈夫です。今は代わりにフィボ・リトレースメントを使ったり、自分でS/Rレベルを描いたりしています。

 
yohmm:

はい、Build 1016です。再度インジケータをダウンロードし、再コンパイルしました。ただ、高値と安値に点が表示されるだけです。

でも大丈夫です。今は代わりにフィボ・リトレースメントを使ったり、自分でS/Rレベルを描いたりしています。

チャートをアップロードできますか？
 
belido:
チャートをアップロードできますか？

もちろんです：

メタトレーダー取引プラットフォームのスクリーンショット

EURUSD, M5, 2014.11.28

MetaQuotes Software Corp.、メタトレーダー5、デモ

temp_file_screenshot_27398.png

EURUSD, M5, 2014.11.28, MetaQuotes Software Corp.


 
メタトレーダーを再インストールしても解決しない。
ファイル:
sup.png  36 kb
 

これを試してみよう


//+------------------------------------------------------------------+
//|サポートとレジスタンスmq5｜｜サポートとレジスタンス
//|著作権 © 2005, ドミトリー
//|2014年12月更新
//+------------------------------------------------------------------+
#property copyright "Copyright © 2006, MetaQuotes Software Corp."
#property link      "http://www.metaquotes.net/"
//---- バージョン
#property version   "1.01"
//---- チャート・ウィンドウのインジケーター
#property indicator_chart_window 
//---- 2つのインジケーター・バッファを使用
#property indicator_buffers 2
//---- 2つのグラフィック・プロットを使用
#property indicator_plots   2
//+----------------------------------------------+
//｜弱気インジケーターのオプション
//+----------------------------------------------+
//---- 描画タイプを矢印にする
#property indicator_type1   DRAW_ARROW
//---- マゼンタ色
#property indicator_color1  Magenta
//---- 線幅
#property indicator_width1  1
//---- サポートラベル
#property indicator_label1  "Support"
//+----------------------------------------------+
//| 強気インジケーターのオプション
//+----------------------------------------------+
//---- 描画タイプを矢印にする
#property indicator_type2   DRAW_ARROW
//---- ライム色
#property indicator_color2  Lime
//---- 線幅
#property indicator_width2  1
//---- 抵抗ラベル
#property indicator_label2 "Resistance"

//+----------------------------------------------+
//| インジケータ入力パラメータ
//+----------------------------------------------+
// 入力 int iPeriod=70; // ATR期間
//+----------------------------------------------+

//---- インジケータ・バッファとして使用される動的配列の宣言
double SellBuffer[];
double BuyBuffer[];
//---
int StartBars;
int FRA_Handle;
//+------------------------------------------------------------------+
//| カスタムインジケータ初期化関数
//+------------------------------------------------------------------+
void OnInit()
  {
//---- グローバル変数の初期化
   StartBars=6;
//---- iFractals インジケータのハンドルを取得する。
   FRA_Handle=iFractals(NULL,0);
   if(FRA_Handle==INVALID_HANDLE)Print(" INVALID_HANDLE FRA");

//---- SellBuffer をインジケータ・バッファとして設定する。
   SetIndexBuffer(0,SellBuffer,INDICATOR_DATA);
//---- プロットする開始バーのインデックスを設定する
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,StartBars);
//---- サポート用のラベルを設定する
   PlotIndexSetString(0,PLOT_LABEL,"Support");
//---- 矢印の文字コードを設定する
   PlotIndexSetInteger(0,PLOT_ARROW,159);
//---- インデックスを時系列に設定する
   ArraySetAsSeries(SellBuffer,true);

//---- BuyBuffer をインジケータ・バッファとして設定する。
   SetIndexBuffer(1,BuyBuffer,INDICATOR_DATA);
//---- プロットする開始バーのインデックスを設定する
   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,StartBars);
//--- 抵抗のラベルを設定する
   PlotIndexSetString(1,PLOT_LABEL,"Resistance");
//---- 矢印の文字コードを設定する
   PlotIndexSetInteger(1,PLOT_ARROW,159);
//---- インデックスを時系列に設定する
   ArraySetAsSeries(BuyBuffer,true);

//---- 精度の設定
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//---- インジケーターの略称
   string short_name="Support & Resistance";
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//---- 
  }
//+------------------------------------------------------------------+
//| カスタム・インジケータ反復関数|
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[]
                )
  {
//---- バーのチェック
   if(BarsCalculated(FRA_Handle)<rates_total
      || rates_total<StartBars)
      return(0);

//---- ローカル変数の宣言
   int to_copy,limit,bar;
   double FRAUp[],FRALo[];

//---- コピーするバーの計算
//---- 小節数再計算ループの開始インデックス(リミット)
   if(prev_calculated>rates_total || prev_calculated<=0)// 最初の呼び出しをチェックする
     {
      to_copy=rates_total;           // コピーするバー
      limit=rates_total-StartBars-1; // 開始インデックス
     }
   else
     {
      to_copy=rates_total-prev_calculated+3; // コピーするバー
      limit=rates_total-prev_calculated+2;   // 開始インデックス
     }

//---- インデックスを時系列に設定する
   ArraySetAsSeries(FRAUp,true);
   ArraySetAsSeries(FRALo,true);
   ArraySetAsSeries(high,true);
   ArraySetAsSeries(low,true);

//---- インジケータのデータを配列にコピーする
   if(CopyBuffer(FRA_Handle,0,0,to_copy,FRAUp)<=0) return(0);
   if(CopyBuffer(FRA_Handle,1,0,to_copy,FRALo)<=0) return(0);
 
//---- メインループ
   for(bar=limit; bar>=0; bar--)
     {
       BuyBuffer[bar] = 0.0;
       SellBuffer[bar] = 0.0;
       
     
       if(FRAUp[bar] != DBL_MAX) BuyBuffer[bar] = high[bar]; else BuyBuffer[bar] = BuyBuffer[bar+1];
       
       
       if(FRALo[bar] != DBL_MAX) SellBuffer[bar] = low[bar]; else SellBuffer[bar] = SellBuffer[bar+1];
     }
//---- 
   return(rates_total);
  }
//+------------------------------------------------------------------+
123
新しいコメント