Domande dai principianti MQL4 MT4 MetaTrader 4 - pagina 214

[Valeriy Yastremskiy]

Aleksandr Martynov:

UPS, credo di averla trovata:

Secondo la documentazione:

Se un indicatore personalizzato viene chiamato utilizzando la funzioneiCustom(), questo indicatore viene eseguito nel thread del programma chiamante. Le funzioni di libreria (importate) lavorano anche nel thread del programma chiamante.

In generale, per MQL4 non importa dove si mettono i calcoli, perché le risorse saranno allocate per il singolo thread del programma e gli indicatori utilizzati da esso.

In questo caso, è consigliabile, se possibile, trasferire il codice dell'indicatore all'Expert Advisor e ottimizzare il numero di valori calcolati per la profondità dell'array e il numero di "buffer", anche se non riguarda gli algoritmi ricorsivi - è ancora più facile leggerli nell'indicatore, perché il programma ha buffer indicizzati automaticamente solo per i dati del prezzo ...

Il problema è nella comodità di leggere e modificare il codice, e quindi mt4 è single-threaded in una finestra. Per me è più facile prendere la parte di calcolo di un indicatore in un Expert Advisor. Ma non è sempre buono. Il codice risulta lungo, mentre inlude o iQuest è lo stesso. Se vuoi accelerare, allora mt5. mt4 non è abbastanza veloce, a giudicare dai partecipanti al forum.

[Aleksandr Martynov]

Valeriy Yastremskiy:

La questione è quanto sia facile leggere e modificare il codice, e come è, mt4 è single-threaded in una finestra. Trovo più facile portare la parte di calcolo di un indicatore in un EA. Ma non è sempre buono. Il codice risulta lungo, mentre inlude o iQuest è lo stesso. Se vuoi accelerare, vai su mt5. mt4 è più lento, a giudicare dai commenti del forum.

Se vuoi accelerare, allora è mt5, ma mt4 perde, a giudicare dai commenti del forum. Quindi formule semplici come la media, lo zigzag, e non qualsiasi tipo. 5 è certamente buono, ma non tutti lo forniscono ancora e bisogna impararlo

[Valeriy Yastremskiy]

Aleksandr Martynov:

la gestione dei buffer di calcolo nell'EA sarà più costosa dell'indicatore... Quindi formule semplici come la media, lo zigzag e non tutte. Il 5 è buono, certo, ma non tutti vi hanno accesso.

Ma per farlo bisogna togliere il codice della logica dell'indicatore, il che non è sempre facile.

[Alexander Kovalev]

Quanto è sicuro dare i log dell'EA e del terminale a uno sviluppatore su sua richiesta? Può fare qualcosa al mio account o al mio computer?

[Vitaly Muzichenko]

Alexander Kovalev:

Quanto è sicuro dare i log dell'EA e del terminale allo sviluppatore su sua richiesta? Può fare qualcosa al mio account o al mio computer?

Sì, e anche portare fuori dalla casa tutti i gioielli d'oro della bara

[Alexander Korovkin]

Amici miei, per favore consigliatemi dove sto sbagliando (per favore non uccidetemi, ho lavorato in MQL4 per 3 giorni).

Sto cercando di aprire un ordine SELL dal mercato a un prezzo rientrato di Delta punti (60) dal valore precedentemente piazzato (che prendo quando apro un ordine precedente).

Tuttavia, lo script apre un nuovo ordine allo stesso tempo dell'ordine precedente, al prezzo corrente, senza aspettare la condizione appropriata (un calo di prezzo di 60 punti). So di essere arrivato da qualche parte, ma ancora non capisco dove sia.

Te ne sarei molto grato!

[Dmitrii Solovei]

Aiutatemi!!!

Non riesco a capire dove sia il mio problema. L'EA richiede volumi EMA. Ho usato iMAonArray.

Ma il calcolo non è simile a quello reale.

Ecco il codice:

***

[Наджибулло Хабибов]

Aleksandr Martynov:
Buona domanda, ho una macchina e qualcosa si muove in essa, quale bullone stringere? Avete idea di quanti consigli sono possibili e alla fine sono tutti inutili perché bisogna stringere il dado...

C'è solo un codice nello studio e nessun altro modo.

Guardate il motivo per cui non si apre per l'oro?

***

[Vladimir Karputov]

Наджибулло Хабибов:

Guardate il motivo per cui non si apre sull'oro?

***

Inserisci il codicecorrettamente: usa il pulsante o in alternativa: allega il file usando il

[Наджибулло Хабибов]

Наджибулло Хабибов:

Guardate il motivo per cui non si apre sull'oro?

***

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double KLot       = 1;        // умножение лота
extern double MaxLot     = 5;        // максимальный лот
extern double Profit     = 0;        // Профит в валюте
extern int StopLoss      = 0;        // Стоп Лось
extern int TakeProfit    = 0;        // ТейкПрофит
extern int BULevel       = 0;        // уровень БУ
extern int BUPoint       = 30;       // пункты БУ
extern int TrailingStop  = 0;        // трал
extern int StartHour     = 0;        // час начала торговли
extern int StartMin      = 30;       // минута начала торговли
extern int EndHour       = 23;       // час окончания торговли
extern int EndMin        = 30;       // минута окончания торговли
extern int Reverse       = 0;        // 1-реверс
extern int CloseSig      = 0;        // 1-закрытие по сигналу
extern int Slip          = 30;       // реквот
extern int Shift         = 1;        // на каком баре сигнал индикатора
extern int Magic         = 123;      // магик

extern string IndName    = "Aroow";
extern int SignalPeriod  = 9;

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
bool TimeSession(int aStartHour,int aStartMinute,int aStopHour,int aStopMinute,datetime aTimeCur)
  {
//--- время начала сессии
   int StartTime=3600*aStartHour+60*aStartMinute;
//--- время окончания сессии
   int StopTime=3600*aStopHour+60*aStopMinute;
//--- текущее время в секундах от начала дня
   aTimeCur=aTimeCur%86400;
   if(StopTime<StartTime)
     {
      //--- переход через полночь
      if(aTimeCur>=StartTime || aTimeCur<StopTime)
        {
         return(true);
        }
     }
   else
     {
      //--- внутри одного дня
      if(aTimeCur>=StartTime && aTimeCur<StopTime)
        {
         return(true);
        }
     }
   return(false);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)
         sl=NormalizeDouble(price+StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price-TakeProfit*_Point,_Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)
         sl=NormalizeDouble(price-StopLoss*_Point,_Digits);
      if(TakeProfit>0)
         tp=NormalizeDouble(price+TakeProfit*_Point,_Digits);
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,_Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2)
               count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   
   if(CountTrades()>0)
     {
      lot=NormalizeDouble(lot*MathPow(KLot,CountTrades()),2);
     }
   if(lot>MaxLot)
      lot=Lots;
   return(lot);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Trailing()
  {
   bool mod;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(Bid-OrderOpenPrice()>TrailingStop*_Point)
                 {
                  if(OrderStopLoss()<Bid-TrailingStop*_Point)
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-TrailingStop*_Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if((OrderOpenPrice()-Ask)>TrailingStop*_Point)
                 {
                  if((OrderStopLoss()>(Ask+TrailingStop*_Point)) || (OrderStopLoss()==0))
                    {
                     mod=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+TrailingStop*_Point,OrderTakeProfit(),0,Yellow);
                     return;
                    }
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void BU()
  {
   bool m;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(OrderOpenPrice()<=(Bid-(BULevel+BUPoint)*_Point) && OrderOpenPrice()>OrderStopLoss())
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()+BUPoint*_Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }

            if(OrderType()==OP_SELL)
              {
               if(OrderOpenPrice()>=(Ask+(BULevel+BUPoint)*_Point) && (OrderOpenPrice()<OrderStopLoss() || OrderStopLoss()==0))
                 {
                  m=OrderModify(OrderTicket(),OrderOpenPrice(),OrderOpenPrice()-BUPoint*_Point,OrderTakeProfit(),0,Yellow);
                  return;
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,_Digits),Slip,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,_Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double AllProfit(int ot=-1)
  {
   double pr=0;
   for(int i=OrdersTotal()-1; i>=0; i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }

            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               pr+=OrderProfit()+OrderCommission()+OrderSwap();
              }
           }
        }
     }
   return(pr);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   double blu = iCustom(NULL,0,IndName,SignalPeriod,4,Shift);
   double red = iCustom(NULL,0,IndName,SignalPeriod,5,Shift);
   double blu2 = iCustom(NULL,0,IndName,SignalPeriod,4,Shift+1);
   double red2 = iCustom(NULL,0,IndName,SignalPeriod,5,Shift+1);

   bool buy = blu<1000 && red2<1000;
   bool sell = red<1000 && blu2<1000;

   if(Reverse>0)
     {
      buy = red<1000 && blu2<1000;
      sell = blu<1000 && red2<1000;
     }

   if(BULevel>0)
      BU();
   if(TrailingStop>0)
      Trailing();
   if(AllProfit()>Profit && Profit>0)
      CloseAll();

   if(TimeSession(StartHour,StartMin,EndHour,EndMin,TimeCurrent()) && t!=Time[0])
     {
      if(buy)
        {
         PutOrder(0,Ask);
        }
      if(sell)
        {
         PutOrder(1,Bid);
        }
      t=Time[0];
     }

   if(CountTrades()>0 && CloseSig>0)
     {
      if(sell)
        {
         CloseAll(0);
        }
      if(buy)
        {
         CloseAll(1);
        }
     }

   Comment("\n blu: ",blu,
           "\n red: ",red,
           "\n All Profit: ",AllProfit());
  }
//+------------------------------------------------------------------+