Errori, bug, domande

Alexey Navoykov 2016.07.30 05:42 #16211

fxsaber:
Sembra riguardare le finestre a volte non chiuse dei test visivi. Non riesco però a riprodurlo. Ora funziona.

Hai fatto dei test o hai ottimizzato? In quest'ultimo caso, ci sono effettivamente dei problemi.

[Eliminato] 2016.07.30 06:25 #16212

Karputov Vladimir:

Ecco lo script che richiama il menu "File" - voce "Connect to trading account" - cliccate sul pulsante "OK" - così il terminale si collegherà all'ultimo conto di trading che è stato autenticato:

#ifndef  _IsX64
#define  HWND long
#define  HMENU long
#define  HBITMAP long
#define  ULONG_PTR long
#else
#define  HWND int
#define  HMENU int
#define  HBITMAP int
#define  ULONG_PTR int
#endif

_IsX64 non può essere usato in questo modo. È rilevante solo in fase di esecuzione.

fxsaber 2016.07.30 09:26 #16213

Alexey Navoykov:

Hai fatto dei test o hai ottimizzato? In quest'ultimo caso, ci sono effettivamente dei problemi.

Esecuzione singola, non ho incluso l'ottimizzazione.

Vladimir Karputov 2016.07.30 10:14 #16214

Koldun Zloy:

_IsX64 non può essere usato in questo modo. Ha importanza solo in fase di esecuzione.

Grazie per il suggerimento. L'ho corretto e l'ho reso un file include:

//+------------------------------------------------------------------+
//|                                          LoginToTradeAccount.mqh |
//|                              Copyright © 2016, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.00"
#property description "Library for clicks on the MetaTrader 5 menu \"File\" item \"Login to trading account\""
#property description "Библиотека для кликов по меню MetaTrader 5 \"Файл\" пункт \"Подключиться к торговому счёту\""

int number_menu=1;   //menu "File"; меню "Файл"
int item_menu=14;    //item "Login to trading account"; пункт "Подключиться к торговому счёту"

#define  GA_ROOT            0x00000002  // Retrieves the root window by walking the chain of parent windows
#define  WM_COMMAND         0x00000111
#define  BM_CLICK           0x000000F5

#import "user32.dll"
int  GetLastError();
//+------------------------------------------------------------------+
//| GetAncestor. Retrieves the handle to the ancestor of the         |
//| specified window. Возвращает хендл предка заданного окна         |
//+------------------------------------------------------------------+
//--- x64
long  GetAncestor(long hwnd,int gaFlags);
//--- x86
int  GetAncestor(int hwnd,int gaFlags);
//+------------------------------------------------------------------+
//| GetMenu. Retrieves a handle to the menu assigned to the          |
//| specified window. Возвращает хендл меню,                         |
//| назначенного указанному окну.                                    |
//+------------------------------------------------------------------+
//--- x64
long GetMenu(long hWnd);
//--- x86
int GetMenu(int hWnd);
//+------------------------------------------------------------------+
//| GetSubMenu. Retrieves a handle to the drop-down menu or submenu  |
//| activated by the specified menu item. Возвращает хендл           |
//| выпадающего меню или подменю указанного пункта меню.             |
//+------------------------------------------------------------------+
//--- x64
long GetSubMenu(long hMenu,int nPos);
//--- x86
int GetSubMenu(int hMenu,int nPos);
//+------------------------------------------------------------------+
//| GetMenuItemID. Retrieves the menu item identifier of a menu item |
//| located at the specified position in a menu. Возвращает          |
//| идентификатор пункта меню, расположенного в                      |
//| указанной позиции в меню.                                        |
//+------------------------------------------------------------------+
//--- x64
int   GetMenuItemID(long hMenu,int nPos);
//--- x86
int   GetMenuItemID(int hMenu,int nPos);
//+------------------------------------------------------------------+
//| PostMessageW. Places (posts) a message in the message queue      |
//| associated with the thread that created the specified window     |
//| and returns without waiting for the thread to process the        |
//| message. Размещает (публикует) сообщение в очереди сообщений,    |
//| связанной с потоком, который создал указанное окно и             |
//| возвращается, не дожидаясь потока, чтобы обработать сообщение.   |
//+------------------------------------------------------------------+
//--- x64
bool  PostMessageW(long hWnd,int Msg,int wParam,int lParam);
//--- x86
bool  PostMessageW(int hWnd,int Msg,int wParam,int lParam);
//+------------------------------------------------------------------+
//| GetLastActivePopup. Determines which pop-up window owned by the  |
//| specified window was most recently active. Определяет, какое     |
//| всплывающее окно, принадлежащие указанному окну, совсем недавно  |
//| было активным.                                                   |
//+------------------------------------------------------------------+
//--- x64
long  GetLastActivePopup(long hWnd);
//--- x86
int  GetLastActivePopup(int hWnd);
//+------------------------------------------------------------------+
//| GetDlgItem. Retrieves a handle to a control in the specified     |
//| dialog box. Возвращает хэндл элемента управления в               |
//| указанном диалоговом окне.                                       |
//+------------------------------------------------------------------+
//--- x64
long  GetDlgItem(long hDlg,int nIDDlgItem);
//--- x86
int  GetDlgItem(int hDlg,int nIDDlgItem);
#import
//+------------------------------------------------------------------+
//| Click on the item "Login to trading account"                     |
//| Клик на пункте "Подключиться к торговому счёту"                  |
//+------------------------------------------------------------------+
void LoginToTradeAccount()
  {
   long mainChartID=ChartID(); //returns the ID of the current chart; возвращает идентификатор текущего графика
   int hdlmainChartID=ChartWindowsHandle(mainChartID); //returns the Chart window handle (HWND); получает хэндл графика 

   if(_IsX64)
     {
      long hdlRoot=GetAncestor((long)hdlmainChartID,GA_ROOT);
      long hmenu=GetMenu(hdlRoot);
      long hsubmenu=GetSubMenu(hmenu,number_menu);
      int hpos=GetMenuItemID(hsubmenu,item_menu);
      PostMessageW(hdlRoot,WM_COMMAND,hpos,0);
      Sleep(2000);
      long hlastPopup=GetLastActivePopup(hdlRoot);
      long hOK=GetDlgItem(hlastPopup,0x00000001);
      PostMessageW(hOK,BM_CLICK,0,0);
     }
   else
     {
      int hdlRoot=GetAncestor(hdlmainChartID,GA_ROOT);
      int hmenu=GetMenu(hdlRoot);
      int hsubmenu=GetSubMenu(hmenu,number_menu);
      int hpos=GetMenuItemID(hsubmenu,item_menu);
      PostMessageW(hdlRoot,WM_COMMAND,hpos,0);
      Sleep(2000);
      int hlastPopup=GetLastActivePopup(hdlRoot);
      int hOK=GetDlgItem(hlastPopup,0x00000001);
      PostMessageW(hOK,BM_CLICK,0,0);
     }
  }
//+------------------------------------------------------------------+
//| The function gets the handle graphics                            |
//| Функция получает хэндл графика                                   |
//+------------------------------------------------------------------+
int ChartWindowsHandle(long chart_ID)
  {
//--- prepare the variable to get the property value
//--- подготовим переменную для получения значения свойства
   long result=-1;
//--- reset the error value
//--- сбросим значение ошибки
   ResetLastError();
//--- receive the property value
//--- получим значение свойства
   if(!ChartGetInteger(chart_ID,CHART_WINDOW_HANDLE,0,result))
     {
      //--- display the error message in Experts journal
      //--- выведем сообщение об ошибке в журнал "Эксперты"
      Print(__FUNCTION__+", Error Code = ",GetLastError());
     }
//--- return the value of the chart property
//--- вернем значение свойства графика
   return((int)result);
  }
//+------------------------------------------------------------------+

File:

LoginToTradeAccount.mqh 7 kb

Vladimir Karputov 2016.07.30 16:23 #16215

Dmitri Custurov:
Purtroppo, non sempre. Se non c'è connessione per un lungo periodo di tempo, il terminale mostra "Account disable" e poi si deve accedere manualmente. Questo accade ad esempio in un fondo dove i server sono solitamente spenti di notte.

Ecco la soluzione: EA controlla periodicamente lo stato di connessione al server commerciale(TERMINAL_CONNECTED) e se il valore restituito è "0", chiama (usando WIn API) il menu "File", voce "Connect to trade account". Il file include in cui è implementata la funzione di clic del menu può essere trovato qui. Esempio di un EA:

//+------------------------------------------------------------------+
//|                                           TestAccountDisable.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"

#include <LoginToTradeAccount.mqh>
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- create timer
   EventSetTimer(12);

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- destroy timer
   EventKillTimer();

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---

  }
//+------------------------------------------------------------------+
//| Timer function                                                   |
//+------------------------------------------------------------------+
void OnTimer()
  {
//---
   static bool cleaner=false;
   if(!cleaner)
     {
      long rezult=TerminalInfoInteger(TERMINAL_CONNECTED);
      Comment("TERMINAL_CONNECTED: ",IntegerToString(rezult));
      if(rezult==0)
         LoginToTradeAccount();
     }
   else
      Comment("");
   cleaner=!cleaner;
  }
//+------------------------------------------------------------------+

EA controlla lo stato della connessione ogni 12 secondi e cancella i commenti ogni tanto.

Discussione sull articolo "Ordini, Domande dai principianti MQL5 Errors, bugs, questions

TheXpert 2016.07.30 17:48 #16216

Davvero non c'è una definizione?

Aliaksandr Yemialyanau 2016.07.31 07:40 #16217

Come faccio a collegare un file array al mio EA?

Per prima cosa, lo script scrive un array:

string filename="mas.dat";
int handle=FileOpen(filename,FILE_BIN|FILE_WRITE);
FileWriteArray(handle,hol,0,4608);
FileClose(handle);

Collego il file nell'EA:

#include <mas.dat>

Durante la compilazione, errori:

'??????????????????????????t????...' - l'identificatore è troppo lungo mas.dat 1 1

'' - simbolo sconosciuto mas.dat 1 3015

Errors, bugs, questions [ARCHIVIO] Qualsiasi domanda da GUI in crowdsourcing. Open

Aleksey Vyazmikin 2016.07.31 11:04 #16218

Aliaksandr Yemialyanau:

Come faccio a collegare un file array al mio EA?

Per prima cosa, lo script scrive un array:

Collego il file nell'EA:

Durante la compilazione, errori:

'??????????????????????????t????...' - l'identificatore è troppo lungo mas.dat 1 1

'' - simbolo sconosciuto mas.dat 1 3015

È molto più veloce leggere l'intero file array in memoria e poi lavorarci - sarà molto più veloce.

Dmitri Custurov 2016.07.31 12:17 #16219

Karputov Vladimir:

Ecco la soluzione: EA controlla periodicamente lo stato di connessione al server commerciale(TERMINAL_CONNECTED) e se il valore restituito è "0", chiama (usando WIn API) il menu "File", voce "Connect to trade account". Il file include in cui è implementata la funzione di clic del menu può essere trovato qui. Esempio di un EA:

Il consulente controlla lo stato della connessione ogni 12 secondi e cancella i commenti ogni tanto.

Grazie mille per la soluzione fornita. Tutto funziona.

fxsaber 2016.07.31 12:18 #16220

Debugging

#define  i ii

void OnTick()
{
  for (int i = 0; i < 5; i++)
    Print(i); // отладчик по Shift+F9 показывает не ii, а i, выдавая Unknown identifier
}

Errori, bug, domande - pagina 1622