Discusión sobre el artículo "Interfaces gráficas VII: Control "Pestañas" (Capítulo 2)" - página 3

Nuevo comentario
 

Como puedo añadir CLabel a las pestañas, cuando creo un elemento CLabel y quiero añadirlo a las pestañas el compilador me da este error:


CLabel m_overview_titlte_label;

bool CMainPanel::CreateOverviewTitleLabel(const string text)
  {

//--- Pasar el objeto panel
   m_overview_title_label.WindowPointer(m_window);
//--- Adjuntar a la cuarta pestaña del primer grupo de pestañas
   m_main_panel_tabs.AddToElementsArray(0,m_overview_title_label);  
   m_main_panel_tabs.AddToElementsArray( 
//--- Coordenadas
   int x=m_window.X()+OVERVIE_TITLE_LABEL_GAP_X;
   int y=m_window.Y()+OVERVIE_TITLE_LABEL_GAP_Y;
//--- Establecer propiedades antes de la creación
   m_overview_title_label.XSize(140);
   m_overview_title_label.YSize(18);
   //m_overview_title_label.
//--- Crear control
   if(!m_overview_title_label.Create(m_chart_id,text,m_subwin,x,y))
      return(false);
//--- Añade el objeto al array común de grupos de objetos
   //CWndContainer::AddToElementsArray(0,m_overview_title_label);
   return(true);
  }


Compiler Error:

'WindowPointer' - función no definida MainPanel.mqh 233 27

m_overview_title_label' - parámetro de conversión no permitido MainPanel.mqh 235 43

m_overview_title_label' - variable del mismo tipo esperada MainPanel.mqh 235 43

 
Martin Fischer función como WindowPointer().
Puedo crear estos objetos, pero no puedo adjuntarlos a la ventana.

El
no funciona en este caso...

2.)
¿Es el CComboBox un objeto estático. ¿Es posible modificar la lista de elementos en el

ComboBox-Listview después de la creación del ComboBox?

Muchas gracias.

Yo tenia el mismo problema, lo solucione creando un archivo include y escribiendo mi clase label y usandola. Debes crear este archivo en Include\EasyAndFastGUI\Controls\MyLabel.mqh

Ese código es:

//+------------------------------------------------------------------+
//|MyLabel.mqh ||
//|Copyright 2023, Sassiz.Raíz
//|https://t.me/R00T_S4SS12 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2023, Sassiz.Root"
#property link      "https://t.me/R00T_S4SS12"
#property strict

#include "Element.mqh"
#include "Window.mqh"
//+------------------------------------------------------------------+
//| Clase para crear una casilla de verificación|
//+------------------------------------------------------------------+
class MyLabel : public CElement
  {
private:
   //--- Puntero al formulario al que se adjunta el elemento
   CWindow          *m_wnd;
   //--- Objetos para crear una casilla de verificación

   CLabel            m_label;

   //--- Texto de la casilla de verificación
   string            m_label_text;
   //--- Márgenes de la etiqueta de texto
   int               m_label_x_gap;
   int               m_label_y_gap;
   //--- Colores de la etiqueta de texto en diferentes estados
   color             m_label_color;
   color             m_label_color_off;
   color             m_label_color_hover;
   color             m_label_color_locked;
   color             m_label_color_array[];
   //--- Prioridades de la pulsación del botón izquierdo del ratón
   int               m_zorder;
   int               m_area_zorder;

   //---
public:
                     MyLabel(void);
                    ~MyLabel(void);
   //--- Métodos para crear una casilla de verificación
   bool              CreateLabel(const long chart_id,const int subwin,const string text,const int x,const int y);
   //---
private:
   bool              CreateLabel2(void);
   //---
public:
   //--- (1) Almacena el puntero del formulario, (2) devuelve/establece el estado del checkbox
   void              WindowPointer(CWindow &object)                 { m_wnd=::GetPointer(object);            }

   //--- (1) Color de fondo, (2) márgenes para la etiqueta de texto

   void              LabelXGap(const int x_gap)                     { m_label_x_gap=x_gap;                   }
   void              LabelYGap(const int y_gap)                     { m_label_y_gap=y_gap;                   }
   //--- Color del texto en diferentes estados
   void              LabelColor(const color clr)                    { m_label_color=clr;                     }

   //--- (1) Descripción de la casilla de verificación, (2) devolver/establecer el estado del botón de casilla de verificación
   string            LabelText(void)                          const { return(m_label.Description());         }

   //--- Cambiar el color
   void              ChangeObjectsColor(void);
   //---
public:
   //--- Manejador del evento Chart
   virtual void      OnEvent(const int id,const long &lparam,const double &dparam,const string &sparam);
   //--- Temporizador
   virtual void      OnEventTimer(void);
   //--- Mover el elemento
   virtual void      Moving(const int x,const int y);
   //--- (1) Mostrar, (2) ocultar, (3) restablecer, (4) eliminar
   virtual void      Show(void);
   virtual void      Hide(void);
   virtual void      Reset(void);
   virtual void      Delete(void);
   //--- (1) Establecer, (2) restablecer las prioridades de la pulsación del botón izquierdo del ratón
   virtual void      SetZorders(void);
   virtual void      ResetZorders(void);
   //--- Restablecer el color
   virtual void      ResetColors(void);
   virtual void      SetText(string text);
   virtual void      SetFontSize(int fontSize);
   //---
private:
   //--- Manejo de la prensa en el elemento
   bool              OnClickLabel(const string clicked_object);
  };
//+------------------------------------------------------------------+
//| Constructor|
//+------------------------------------------------------------------+
MyLabel::MyLabel(void) :      
                             m_label_x_gap(20),
                             m_label_y_gap(2),
                             m_label_color(clrBlack)
                             
  {
//--- Almacenar el nombre de la clase del elemento en la clase base
   CElement::ClassName(CLASS_NAME);
//--- Establece las prioridades del click del botón izquierdo del ratón
   m_zorder      =0;
   m_area_zorder =1;
  }
//+------------------------------------------------------------------+
//| Destructor|
//+------------------------------------------------------------------+
MyLabel::~MyLabel(void)
  {
  }
//+------------------------------------------------------------------+
//| Manejo de eventos|
//+------------------------------------------------------------------+
void MyLabel::OnEvent(const int id,const long &lparam,const double &dparam,const string &sparam)
  {
//--- Manejo del evento de movimiento del cursor
   if(id==CHARTEVENT_MOUSE_MOVE)
     {
      //--- Dejar, si el elemento está oculto
      if(!CElement::IsVisible())
         return;
      //--- Dejar, si los números de las subventanas no coinciden
      if(CElement::m_subwin!=CElement::m_mouse.SubWindowNumber())
         return;
      //--- Comprobación del foco sobre el elemento
      CElement::MouseFocus(m_mouse.X()>X() && m_mouse.X()<X2() && m_mouse.Y()>Y() && m_mouse.Y()<Y2());
      return;
     }
//--- Manejo del click del botón izquierdo del ratón sobre el objeto
   if(id==CHARTEVENT_OBJECT_CLICK)
     {
      //--- Pulsando sobre la casilla
      if(OnClickLabel(sparam))
         return;
     }
  }
//+------------------------------------------------------------------+
//| Temporizador|
//+------------------------------------------------------------------+
void MyLabel::OnEventTimer(void)
  {
//--- Si el formulario no está bloqueado
   if(!m_wnd.IsLocked())
      //--- Cambiar el color de los objetos elemento
      ChangeObjectsColor();
  }
//+------------------------------------------------------------------+
//| Crea un grupo de los objetos checkbox|
//+------------------------------------------------------------------+
bool MyLabel::CreateLabel(const long chart_id,const int subwin,const string text,const int x,const int y)
  {
//--- Dejar, si no hay puntero de formulario
   if(!CElement::CheckWindowPointer(::CheckPointer(m_wnd)))
      return(false);
//--- Inicialización de variables
   m_id         =m_wnd.LastId()+1;
   m_chart_id   =chart_id;
   m_subwin     =subwin;
   m_x          =x;
   m_y          =y;
   m_label_text =text;
//--- Márgenes desde el borde
   CElement::XGap(CElement::X()-m_wnd.X());
   CElement::YGap(CElement::Y()-m_wnd.Y());
//--- Creación de un elemento

   if(!CreateLabel2())
      return(false);
//--- Ocultar el elemento si la ventana es de diálogo o está minimizada
   if(m_wnd.WindowType()==W_DIALOG || m_wnd.IsMinimized())
      Hide();
//---
   return(true);
  }


//+------------------------------------------------------------------+
//| Crea la etiqueta de la casilla de verificación|
//+------------------------------------------------------------------+
bool MyLabel::CreateLabel2(void)
  {
//--- Formación del nombre del objeto
   string name=CElement::ProgramName()+"_lable_"+(string)CElement::Id();
//--- Coordenadas
   int x =CElement::X()+m_label_x_gap;
   int y =CElement::Y()+m_label_y_gap;
//--- Color del texto según el estado
   color label_color=clrBlack;//(m_check_button_state) ? m_label_color : m_label_color_off;
//--- Establecer el objeto
   if(!m_label.Create(m_chart_id,name,m_subwin,x,y))
      return(false);
//--- establecer propiedades
   m_label.Description(m_label_text);
   m_label.Font(FONT);
   m_label.FontSize(FONT_SIZE);
   m_label.Color(label_color);
   m_label.Corner(m_corner);
   m_label.Anchor(m_anchor);
   m_label.Selectable(false);
   m_label.Z_Order(m_zorder);
   m_label.Tooltip("\n");
//--- Márgenes desde el borde
   m_label.XGap(x-m_wnd.X());
   m_label.YGap(y-m_wnd.Y());
//--- Inicializando la matriz de gradientes
   CElement::InitColorArray(label_color,m_label_color_hover,m_label_color_array);
//--- Almacenar el puntero del objeto
   CElement::AddToArray(m_label);
   return(true);
  }
//+------------------------------------------------------------------+
//| Elementos móviles|
//+------------------------------------------------------------------+
void MyLabel::Moving(const int x,const int y)
  {
//--- Dejar, si el elemento está oculto
   if(!CElement::IsVisible())
      return;
//--- Almacenamiento de sangrías en los campos de los elementos
   CElement::X(x+XGap());
   CElement::Y(y+YGap());
//--- Almacenamiento de coordenadas en los campos de los objetos
   m_label.X(x+m_label.XGap());
   m_label.Y(y+m_label.YGap());
//--- Actualización de coordenadas de objetos gráficos
   m_label.X_Distance(m_label.X());
   m_label.Y_Distance(m_label.Y());
  }
//+------------------------------------------------------------------+
//| Cambiar el color del objeto cuando el cursor pasa por encima.
//+------------------------------------------------------------------+
void MyLabel::ChangeObjectsColor(void)
  {
//--- Dejar, si el elemento está bloqueado

//---
   color label_color=clrBlack;//(m_check_button_state) ? m_label_color : m_label_color_off;
   CElement::ChangeObjectColor(m_label.Name(),CElement::MouseFocus(),OBJPROP_COLOR,label_color,m_label_color_hover,m_label_color_array);
  }
//+------------------------------------------------------------------+
//| Muestra combobox|
//+------------------------------------------------------------------+
void MyLabel::Show(void)
  {
//--- Dejar, si el elemento ya es visible
   if(CElement::IsVisible())
      return;
//--- Hacer visibles todos los objetos
   for(int i=0; i<CElement::ObjectsElementTotal(); i++)
      CElement::Object(i).Timeframes(OBJ_ALL_PERIODS);
//--- Estado de visibilidad
   CElement::IsVisible(true);
  }
//+------------------------------------------------------------------+
//| Oculta combobox|
//+------------------------------------------------------------------+
void MyLabel::Hide(void)
  {
//--- Dejar, si el elemento ya es visible
   if(!CElement::IsVisible())
      return;
//--- Ocultar todos los objetos
   for(int i=0; i<CElement::ObjectsElementTotal(); i++)
      CElement::Object(i).Timeframes(OBJ_NO_PERIODS);
//--- Estado de visibilidad
   CElement::IsVisible(false);
  }
//+------------------------------------------------------------------+
//| Redibujando|
//+------------------------------------------------------------------+
void MyLabel::Reset(void)
  {
//--- Dejar, si se trata de un elemento desplegable
   if(CElement::IsDropdown())
      return;
//--- Ocultar y mostrar
   Hide();
   Show();
  }
//+------------------------------------------------------------------+
//| Supresión|
//+------------------------------------------------------------------+
void MyLabel::Delete(void)
  {
//--- Eliminar objetos
   m_label.Delete();
//--- Vaciar el array de los objetos
   CElement::FreeObjectsArray();
//--- Inicialización de variables por valores por defecto
   CElement::MouseFocus(false);
   CElement::IsVisible(true);
  }
//+------------------------------------------------------------------+
//| Seth las prioridades|
//+------------------------------------------------------------------+
void MyLabel::SetZorders(void)
  {
   m_label.Z_Order(m_zorder);
  }
//+------------------------------------------------------------------+
//| Restablecer las prioridades|
//+------------------------------------------------------------------+
void MyLabel::ResetZorders(void)
  {
   m_label.Z_Order(0);
  }
//+------------------------------------------------------------------+
//| Restablecer el color de los objetos del elemento|
//+------------------------------------------------------------------+
void MyLabel::ResetColors(void)
  {

//--- Restablecer el color
   m_label.Color(clrBlack);
//--- Poner a cero el foco
   CElement::MouseFocus(false);
  }

//+------------------------------------------------------------------+
//| Haciendo clic en la cabecera del elemento|
//+------------------------------------------------------------------+
bool MyLabel::OnClickLabel(const string clicked_object)
  {

//--- El cursor del ratón está actualmente sobre el elemento
   m_label.Color(m_label_color_hover);
//--- Enviar un mensaje al respecto
   ::EventChartCustom(m_chart_id,ON_CLICK_LABEL,CElement::Id(),0,m_label.Description());
   return(true);
  }
//+------------------------------------------------------------------+


void MyLabel::SetText(string text){
   m_label.Description(text);
}

void MyLabel::SetFontSize(int fontSize){
   m_label.FontSize(fontSize);
}

A continuación, crear objeto de la clase MyLabel así y utilizarlo:

   //---Etiqueta
   MyLabel           m_overview_title_label;

Entonces:

//+------------------------------------------------------------------+
//| Crea OverviewTitleLabel|
//+------------------------------------------------------------------+
bool CMainPanel::CreateOverviewTitleLabel(const string text)
  {

//--- Pasar el objeto panel
   m_overview_title_label.WindowPointer(m_window);
//--- Adjuntar a la cuarta pestaña del primer grupo de pestañas
   m_main_panel_tabs.AddToElementsArray(0,m_overview_title_label);  
//--- Coordenadas
   int x=m_window.X()+OVERVIE_TITLE_LABEL_GAP_X;
   int y=m_window.Y()+OVERVIE_TITLE_LABEL_GAP_Y;
//--- Establecer propiedades antes de la creación
   m_overview_title_label.XSize(140);
   m_overview_title_label.YSize(18);
   m_overview_title_label.SetText(text);
   m_overview_title_label.SetFontSize(18);
   //m_overview_title_label.
//--- Crear control
   if(!m_overview_title_label.CreateLabel(m_chart_id,m_subwin,text,x,y))
      return(false);
//--- Añade el objeto al array común de grupos de objetos
   CWndContainer::AddToElementsArray(0,m_overview_title_label);
   return(true);
  }
 
Si aumentamos el número de pestañas, ya sea vertical u horizontalmente, no habrá capacidad de desplazamiento, lo que hará que la ventana se extienda más allá de sus límites y reducirá su eficacia.
123
Nuevo comentario