What leads to a cold start in the case like this? - General

kaus_bonus 2017.04.16 20:33 #351

What leads to a cold start in a case like this.

2017.04.17 00:27:51.705 Core 1  GOLD-6.17: generate 48836 ticks in 0:00:00.000, passed to tester 48984 ticks
2017.04.17 00:27:51.705 Core 1  GOLD-9.17: generate 3184 ticks in 0:00:00.000, passed to tester 35192 ticks

and that's what it's all about.

2017.04.17 00:22:16.126 Trade   2017.04.07 10:00:00   deal performed [#247  buy 1.00 GOLD-9.17 at 0.0]

now run it again

2017.04.17 00:31:51.123 Core 1  GOLD-6.17: passed to tester 48984 ticks
2017.04.17 00:31:51.123 Core 1  GOLD-9.17: passed to tester 35192 ticks

and the test result is completely different

Files:

xj2scoo-fw7j24j_2_bekd_v1.1.mq5 11 kb

fxsaber 2017.04.16 20:35 #352

@Renat Fatkhullin, provide strong evidence that the tester is accurate and ready to use.

Where are the clear criteria for verifying the validity of the tester? Where is the 100% reproducibility and match with the standard?

Where is the iron argumentation of your words?

I suggest that ALL of your tester verification experts be posted in the public domain. I propose to pay people who write EAs that fail the tester. And include them in the test base after tweaking the tester.

The tester is raw and everyone is proving it. Why, if you want to find a bug in the tester, it is found very quickly? Why 16 years of experience writing platforms can not write a tester, the results of which can be trusted? Each build one feeling from the tester - bewilderment.

A little surprised :) Errors, bugs, questions learn how to earn

Slava 2017.04.17 06:49 #353

kaus_bonus:

With the release of build 1583 we will return to the issue of mismatch of ticks in the history with the number of ticks in the tester on low-liquidity stock tickers.

Did Service Desk tell you that the problem is solved? The last reply was "we're working on it.

The problem has not been solved yet. Unfortunately, not everything depends on the developers, part of the problem depends on the quality of ticks, laid on the trading server.

Sorting it out. Wait, please.

Cannot withdraw my funds Experts: Tick Collector 'TickSave' FORTS: OnTradeTransaction() return codes

Slava 2017.04.17 07:06 #354

Here, for example, is a check script. It checks the correspondence between ticks and minute bars. It is not yet optimized. It can be accelerated by requesting ticks in a wider range. But it is more clear in this form, since it requests ticks for each minute separately

//+------------------------------------------------------------------+
//|                                                    TestTicks.mq5 |
//|                        Copyright 2017, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2017, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property script_show_inputs
//--- input parameters
input datetime InpBeginDate=D'2017.01.01 0:00:00';
input datetime InpEndDate=D'2017.12.31 0:00:00';
input bool     InpFullLogs=false;
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   MqlRates rates[];
   MqlTick  ticks[];
   datetime begin_date,end_date=(datetime)SymbolInfoInteger(_Symbol,SYMBOL_TIME);
   datetime prev_date,cur_date; 
   int      cnt_rates,cnt_ticks;
   int      i,j,book_depth=(int)SymbolInfoInteger(_Symbol,SYMBOL_TICKS_BOOKDEPTH);
   int      bars_absent=0,bars_absent_wrong=0,tickminutes_absent=0;
   int      bars_volume=0,bars_highlow=0;
   string   str_ticks=(book_depth>0)?" bid/ask":" last/volume";
//--- настроим даты
   if(InpEndDate<end_date && InpEndDate>InpBeginDate)
      end_date=InpEndDate;
   end_date/=60;
   end_date*=60;
   end_date--;
   if(InpBeginDate>=end_date)
      begin_date=end_date-24*3600;
   else
     {
      begin_date=InpBeginDate;
      begin_date/=60;
      begin_date*=60;
     }
//---
   cnt_rates=CopyRates(_Symbol,PERIOD_M1,begin_date,end_date,rates);
   Print(cnt_rates," M1 bars from ",begin_date," to ",end_date);
   for(i=0; i<cnt_rates; i++)
     {
      if(IsStopped())
        {
         Print("stopped on ",i," at ",rates[i].time);
         break;
        }
      if(i==0)
         prev_date=begin_date-60;
      else
         prev_date=rates[i-1].time;
      cur_date=rates[i].time;
      Comment(cur_date,"  ",i+1," / ",cnt_rates,"\n",tickminutes_absent,"  ",bars_volume,"  ",bars_highlow,"  ",bars_absent_wrong);
      //--- отсутствуют минутки
      if(cur_date-prev_date>60)
        {
         prev_date+=60;
         cnt_ticks=CopyTicksRange(_Symbol,ticks,COPY_TICKS_ALL,prev_date*1000,cur_date*1000-1);
         if(cnt_ticks>0)
           {
            datetime next_minute=(ticks[0].time/60+1)*60;
            int absent=1;
            int trades=0,infos=0;
            for(j=0; j<cnt_ticks; j++)
              {
               if((ticks[j].flags&(TICK_FLAG_BID|TICK_FLAG_ASK))!=0)
                  infos++;
               if((ticks[j].flags&(TICK_FLAG_LAST|TICK_FLAG_VOLUME))!=0)
                  trades++;
               //--- считаем реально отсутствующие минутки
               if(ticks[j].time>=next_minute)
                 {
                  next_minute=(ticks[j].time/60+1)*60;
                  absent++;
                 }
              }
            //--- тики не соответствуют барам
            if((book_depth<1 && infos>0) ||
               (book_depth>0 && trades>0))
              {
               Print(cnt_ticks," ticks between ",prev_date," and ",cur_date," (",absent," M1 bars absent)");
               if(InpFullLogs)
                  for(j=0; j<cnt_ticks; j++)
                    {
                     Print(ticks[j].time,".",IntegerToString(ticks[j].time_msc%1000,3,'0'),
                           " Bid=",DoubleToString(ticks[j].bid,_Digits),
                           " Ask=",DoubleToString(ticks[j].ask,_Digits),
                           " Last=",DoubleToString(ticks[j].last,_Digits),
                           " Flags=",ticks[j].flags,
                           " Volume=",ticks[j].volume);
                    }
               //--- счётчик отсутствующих баров
               bars_absent_wrong+=absent;
              }
            else
              {
               if(InpFullLogs)
                  Print(cnt_ticks,str_ticks," ticks between ",prev_date," and ",cur_date," (",absent," M1 bars)");
               //--- счётчик отсутствующих баров
               bars_absent+=absent;
              }
           }
        }
      cnt_ticks=CopyTicksRange(_Symbol,ticks,COPY_TICKS_ALL,cur_date*1000,(cur_date+60)*1000-1);
      if(cnt_ticks<=0 && !IsStopped())
        {
         if(InpFullLogs)
            Print("Ticks absent for M1 ",cur_date," last_error=",GetLastError());
         tickminutes_absent++;
        }
      //--- проверим качество тиков
      if(cnt_ticks>0)
        {
         double high_trades=0.0,low_trades=0.0;
         double high_infos=0.0,low_infos=0.0;
         int    trades=0,infos=0;
         //--- сначала соберём статистику
         for(j=0; j<cnt_ticks; j++)
           {
            if((ticks[j].flags&(TICK_FLAG_BID|TICK_FLAG_ASK))!=0)
              {
               if(ticks[j].bid>0.0)
                 {
                  if(high_infos==0.0)
                     high_infos=ticks[j].bid;
                  else
                    {
                     if(high_infos<ticks[j].bid)
                        high_infos=ticks[j].bid;
                    }
                  if(low_infos==0.0)
                     low_infos=ticks[j].bid;
                  else
                    {
                     if(low_infos>ticks[j].bid)
                        low_infos=ticks[j].bid;
                    }
                 }
               infos++;
              }
            if((ticks[j].flags&(TICK_FLAG_LAST|TICK_FLAG_VOLUME))!=0)
              {
               if(ticks[j].last>0.0)
                 {
                  if(high_trades==0.0)
                     high_trades=ticks[j].last;
                  else
                    {
                     if(high_trades<ticks[j].last)
                        high_trades=ticks[j].last;
                    }
                  if(low_trades==0.0)
                     low_trades=ticks[j].last;
                  else
                    {
                     if(low_trades>ticks[j].last)
                        low_trades=ticks[j].last;
                    }
                 }
               trades++;
              }
           }
         //--- потом сверим с минутным баром
         double point=pow(10.0,-_Digits);
         double high,low;
         int    volume;
         bool   error=false;
         //--- это биржевой инструмент?
         if(book_depth>0)
           {
            high=high_trades;
            low=low_trades;
            volume=trades;
           }
          else
           {
            high=high_infos;
            low=low_infos;
            volume=infos;
           }
         if(MathAbs(low-rates[i].low)>=point)
           {
            error=true;
            bars_highlow++;
           }
         else
           {
            if(MathAbs(high-rates[i].high)>=point)
              {
               error=true;
               bars_highlow++;
              }
            else
              {
               if(volume!=rates[i].tick_volume)
                 {
                  error=true;
                  bars_volume++;
                 }
              }
           }
         //--- надо вывести сообщение об ошибке
         if(error && InpFullLogs)
            Print(rates[i].time," ticks (",DoubleToString(high,_Digits)," ",DoubleToString(low,_Digits)," ",volume,
                  ") mismatch with M1 bar (",DoubleToString(rates[i].high,_Digits)," ",DoubleToString(rates[i].low,_Digits)," ",rates[i].tick_volume,")");
        }
     }
//---
   if(tickminutes_absent>0)
      Print("real ticks absent for ",tickminutes_absent," M1 bars");
   if(bars_volume>0)
      Print("tick volumes not matched for ",bars_volume," M1 bars");
   else
      Print("all the tick volumes matched for all M1 bars");
   if(bars_highlow>0)
      Print("tick prices not matched for ",bars_volume," M1 bars");
   else
      Print("all the tick prices matched for all M1 bars");
   if(bars_absent_wrong>0)
      Print(bars_absent_wrong," M1 bars absent in total while real ticks present");
//--- тут всё нормально, есть тики, которые не формируют бары, поэтому баров и не должно быть
   if(bars_absent>0 && InpFullLogs)
      Print(bars_absent," M1 bars absent while",str_ticks," ticks present");
//--- очистим коммент
   Comment("");
  }
//+------------------------------------------------------------------+

Files:

TestTicks.mq5 17 kb

Questions from Beginners MQL5 [ARCHIVE!] Any rookie question, Need a simple warning

fxsaber 2017.04.17 07:25 #355

Slawa:

Here, for example, is a check script. It checks the correspondence between ticks and minute bars. It is not optimized yet. It can be accelerated by requesting ticks in a wider range. But it is more clear in this form, as it requests ticks for each minute separately.

Thank you. A small remark.

book_depth=(int)SymbolInfoInteger(_Symbol,SYMBOL_TICKS_BOOKDEPTH);

This is not the way to define forex/stock market affiliation - many broadcast forex stack.

I got the following result on Metaquotes-Demo

Test2 (Si-6.17,M1)      6 M1 bars from 2017.04.17 00:00:00 to 2017.04.17 10:05:59
Test2 (Si-6.17,M1)      9 bid/ask ticks between 2017.04.17 00:00:00 and 2017.04.17 10:00:00 (9 M1 bars)
Test2 (Si-6.17,M1)      all the tick volumes matched for all M1 bars
Test2 (Si-6.17,M1)      all the tick prices matched for all M1 bars
Test2 (Si-6.17,M1)      9 M1 bars absent while bid/ask ticks present

Is it normal?

kaus_bonus 2017.04.17 07:47 #356

Slawa:

Did the service department tell you that the problem had been solved? The last answer was "we're looking into it.

The problem has not yet been solved. Unfortunately, not everything depends on the developers, part of the problem depends on the quality of ticks on the trade server.

We are figuring it out. Wait, please.

I'm not complaining.

In the SDs the application for another reason - inconsistency of ticks.

And here showed a new bug - execution in the tester at the price of 0 on the first cold run, which appeared after using all the ticks in the tester.

Any questions from newcomers MetaTrader 5 Strategy Tester: [ARCHIVE!] Any rookie question,

Slava 2017.04.17 09:10 #357

kaus_bonus:

I am not complaining.

The application in SD is about another thing - inconsistency of ticks.

and here showed a new bug - execution in the tester at 0 price on the first cold run, which appeared after using all the ticks in the tester.

This is from the same place. There is only one problem with ticks.

The case you described did not happen before? No.

Where did it come from? In the process of solving the problem of matching ticks

Slava 2017.04.17 09:11 #358

fxsaber:
Thank you. A small noteThat's no way to determine whether you belong to a forex/exchange - many are broadcasting a forex glass.

What does this have to do with the exchange - not the exchange?

If the forex market is broadcasted, it means that the bars are built by fins.

fxsaber 2017.04.17 09:39 #359

Slawa:

What does this have to do with the exchange - not the exchange?

If the stock is broadcasted, it means that the bars are built by fins.

What flippers on the forex? Open the demo here FIBOGroup-MT5 Server.

Slava 2017.04.17 10:01 #360

fxsaber:
What are the fins in forex? Open demo here FIBOGroup-MT5 Server.

If the market depth is transmitted, the bars are build by fins, otherwise by bids

I understand your question. Recently, in connection with the expansion of tick functionality, there are settings - "always build by fins", "always build by bids", "build depending on the translation of the cup".

The first two settings are not taken into account in this script. It is calculated the "old way".

New metatrader 4 compatible DAY 2 ...Purchased products Testing 'CopyTicks'

Features of the mql5 language, subtleties and tricks - page 36