MetaEditor build 1490

 

新的 "FileSave "功能只能以二进制形式保存一个文件?

//+------------------------------------------------------------------+
//|                                                 Scripts_Test.mq5 |
//|                                      Copyright 2012, CompanyName |
//|                                       http://www.companyname.net |
//+------------------------------------------------------------------+
//--- входные параметры
input int      rates_to_save=1000; // количество
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string  filename=_Symbol+"_ticks.csv";
   MqlRates rates[];        
//---
   int copied=CopyRates(Symbol(),Period(),0,rates_to_save,rates);
   if(copied!=-1)
     {
      PrintFormat(" CopyRates(%s) copied %d rates",Symbol(),copied);
      //---  запишем тики в файл
      if(!FileSave(filename,rates,FILE_COMMON))
         PrintFormat("FileSave() failed, error=%d",GetLastError());
     }
   else
      PrintFormat("Failed CopyRates(%s), Error=",_Symbol,GetLastError());
  }
//+------------------------------------------------------------------+

我想做的是:将文件保存为 "csv "格式,在Excel中打开。

附加的文件:
 
Vladimir Karputov:

新的 "FileSave "函数只以二进制形式保存文件?

是的。
 

对CGraphic.mqh.Category的建议。

为了能够删除一个图表对象,需要改变GraphPlot方法。

//+------------------------------------------------------------------+
//| Create graphic of one curve and return resource name             |
//+------------------------------------------------------------------+
string GraphPlot(const double &y[],ENUM_CURVE_TYPE type=CURVE_POINTS)
  {
   string   name="Graphic"+(string)(GetTickCount()+MathRand());
   ulong    width = ChartGetInteger(0,CHART_WIDTH_IN_PIXELS);
   ulong    height= ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS);
   CGraphic graphic;
//--- create graphic and add curves
   graphic.Create(0,name,0,65,45,(int)(0.6*width),(int)(0.65*height));
   graphic.CurveAdd(y,type);
//--- plot curves
   graphic.CurvePlotAll();
   graphic.Update();
//--- return resource name
   //return graphic.ResourceName();
   return graphic.ChartObjectName();
  }

例如,现在图表上有一个名为 "Graphic27489614 "的对象,graphic.ResourceName()方法返回"::Graphic2748961427502758",graphic.ChartObjectName()方法返回 "Graphic27489614"。而如果你做了改变,你可以用对象名称 调用ObjectDelete,删除图表对象。

 
Vladimir Karputov:

对CGraphic.mqh.Category的建议。

为了能够删除一个图表对象,需要改变GraphPlot方法。

例如,现在图表上有一个名为 "Graphic27489614 "的对象,graphic.ResourceName()方法返回"::Graphic2748961427502758",graphic.ChartObjectName()方法返回 "Graphic27489614"。而如果你做了改变,你可以用对象名称 调用ObjectDelete,并删除图表对象。

但这种可能性已经存在。通过调用CGraphic::ChartObjectName()方法,我们得到要删除的对象的名称。

P.S. 甚至是CGraphic::Destroy()方法。

 
Vladimir Karputov:

对CGraphic.mqh类的提议。

这是为ResourceSave 做的。
 
Anatoli Kazharski:

这个功能已经有了。只要调用CGraphic::ChartObjectName()方法,我们就可以得到要删除的对象的名称。

P.S. 甚至是CGraphic::Destroy()方法。

不,这两种方法都不起作用(CGraphic::ChartObjectName()返回 "NULL"),CGraphic::Destroy()根本就不是用来销毁图表 的。
 
Vladimir Karputov:
不,这两种方法都不起作用(CGraphic::ChartObjectName()返回 "NULL"),CGraphic::Destroy()根本不是为了删除图表

两者都对我有用。测试这个脚本并向我展示你的版本。我想知道为什么它对你不起作用。

你可以在脚本中测试两种方法。

//+------------------------------------------------------------------+
//|                                                         Test.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                              http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "http://www.mql5.com"
#property version   "1.00"
//---
#include <Math/Stat/Binomial.mqh>
#include <Graphics/Graphic.mqh>
//--- Размер массива
#define ARRAY_SIZE 50
//---
double array_values[ARRAY_SIZE];
double array_results[ARRAY_SIZE];
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart(void)
  {
   string name   ="Graphic";
   ulong  width  =::ChartGetInteger(0,CHART_WIDTH_IN_PIXELS);
   ulong  height =::ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS);
//---
   CGraphic graphic;
//--- create graphic
   graphic.Create(0,name,0,65,45,(int)(0.6*width),(int)(0.65*height));
//---
   InitArray();
   CCurve *curve1=graphic.CurveAdd(array_values,CURVE_POINTS);
//---
   graphic.CurvePlotAll();
   graphic.Update();
//---
   for(int i=0; i<10; i++)
     {
      InitArray();
      curve1.Update(array_values);
      //---
      graphic.CurvePlotAll();
      graphic.Update();
      //---
      Sleep(500);
     }
//---
   graphic.Destroy();
//---
   ::Print(__FUNCTION__," > graphic.ChartObjectName(): ",graphic.ChartObjectName());
   if(!::ObjectDelete(0,graphic.ChartObjectName()))
      Print(__FUNCTION__," > Объект уже удалён!");
  }
//+------------------------------------------------------------------+
//| Генерация значений                                               |
//+------------------------------------------------------------------+
void InitArray(void)
  {
   for(int j=0; j<ARRAY_SIZE; j++)
      array_values[j]=j;
   Shuffle(array_values);
  }
//+------------------------------------------------------------------+
//| Тасование значений массива                                       |
//+------------------------------------------------------------------+
void Shuffle(double &array[])
  {
   for(uint i=0; i<ARRAY_SIZE; i++)
      RandomSwap(array_values,i);
  }
//+------------------------------------------------------------------+
//| Случайно поменять элементы местами                               |
//+------------------------------------------------------------------+
void RandomSwap(double &array[],uint i)
  {
//--- Случайный индекс для замены
   uint j=::rand()%ARRAY_SIZE;
//--- Меняем местами
   double temp =array[i];
   array[i]    =array[j];
   array[j]    =temp;
  }
//+------------------------------------------------------------------+
 

我最初是用了这个例子(取自MetaTrader 5 build 1485:标准库中的额外测试和图表模式)。

//+------------------------------------------------------------------+
//|                                                       Test_1.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                              http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "http://www.mql5.com"
#property version   "1.00"
#include <Math/Stat/Binomial.mqh>
#include <Graphics/Graphic.mqh>
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnStart(void)
  {
   double    vars[101];
   double    results[101];
   const int N=2000;
//---  
   MathSequence(0,N,20,vars);
   MathProbabilityDensityBinomial(vars,N,M_PI/10,true,results);
   GraphPlot(results);
//---
  }
 
#include <Math\Stat\Math.mqh> // https://www.mql5.com/ru/forum/162251#comment_3885372
#include <Math\Stat\Normal.mqh>
#include <Graphics\Graphic.mqh>

void OnStart()
  {
//---
   double random_values[];
   double pdf[];
   double cdf[];
   double x[];
   if(MathRandomNormal(0,1,1000000,random_values))
     {
      if(MathProbabilityDensityEmpirical(random_values,200,x,pdf))
        {
         GraphPlot(x,pdf,CURVE_LINES);
         //---
         DebugBreak();
        }

      if(MathCumulativeDistributionEmpirical(random_values,200,x,cdf))
        {
         GraphPlot(x,cdf,CURVE_LINES);
         //---
         DebugBreak();
        }
     }
  }
 
Vladimir Karputov:

我最初是用了这个例子(取自MetaTrader 5 build 1485:标准库中的额外测试和图表模式)。

//+------------------------------------------------------------------+
//|                                                       Test_1.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                              http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "http://www.mql5.com"
#property version   "1.00"
#include <Math/Stat/Binomial.mqh>
#include <Graphics/Graphic.mqh>
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnStart(void)
  {
   double    vars[101];
   double    results[101];
   const int N=2000;
//---  
   MathSequence(0,N,20,vars);
   MathProbabilityDensityBinomial(vars,N,M_PI/10,true,results);
   GraphPlot(results);
//---
  }

在一般的拆除中,我暂时是这样做的。

      ObjectsDeleteAll(0,"Graphic",0,OBJ_BITMAP_LABEL);
      ChartRedraw();
 

我如何知道SL/TP是否在OnTradeTransaction()中被触发?

这是我所做的,没有帮助。

void  OnTradeTransaction (const MqlTradeTransaction &trans,   // структура торговой транзакции
                          const MqlTradeRequest     &request, // структура запроса
                          const MqlTradeResult      &result)  // структура ответа
{
  if(trans.type == TRADE_TRANSACTION_HISTORY_ADD)
  {
    datetime date = TimeCurrent ();
    MqlDateTime dateT;
    TimeToStruct (date, dateT);
    dateT.hour += 1;
    date = StructToTime (dateT);
    
    if(HistorySelect (TimeCurrent (), date))
    {
      int dealsTotal = HistoryDealsTotal ();
      ulong ticketD = HistoryDealGetTicket (dealsTotal - 1);
      if(HistoryDealGetString (ticketD, DEAL_SYMBOL) == Symbol ())
      {
        ENUM_DEAL_ENTRY entry = (ENUM_DEAL_ENTRY)HistoryDealGetInteger (ticketD, DEAL_ENTRY);
        if(entry == DEAL_ENTRY_OUT)
        {
          int ordersTotal = HistoryOrdersTotal ();
          ulong ticketO = HistoryOrderGetTicket (ordersTotal - 1);
          if(HistoryOrderGetString (ticketO, ORDER_SYMBOL) == Symbol ())
          {
            double orderPrice = HistoryOrderGetDouble (ticketO, ORDER_PRICE_OPEN);
            double orderSL    = HistoryOrderGetDouble (ticketO, ORDER_SL);
            double orderTP    = HistoryOrderGetDouble (ticketO, ORDER_TP);
            
            if(orderPrice == orderSL)
              Print ("Сработал SL");
            
            if(orderPrice == orderTP)
              Print ("Сработал TP");
          }  
        }
      }  
    }
  }
}

无论如何,就不能有任何更简单的方法吗!?

2016.12.04 14:33:01.854 2016.11.17 03:14:40获利 触发 #4 卖出 0.10 EURUSD 1.07103 sl: 1.07153 tp: 1.07053 [#5 在 1.07053 买入 0.10 EURUSD]
这里,事件显示在终端日志中,为什么在EA中这么容易得到这个事件(SL/TP触发)?或者说有可能吗?
原因: