新人对MQL4和MQL5的任何问题，对算法和代码的帮助和讨论 - 页 232

[Vitalie Postolache]

Rustam Bikbulatov:
第二。打开一个订单的命令

这没有任何意义。这与市场订单有什么关系？也许是指标调用 的问题？然后修改指标，用iCustom而不是iMACD来调用它。

也许，根本不需要修改什么，kodobase里有很多好东西。

[Rustam Bikbulatov]

Vitalie Postolache:

这没有任何意义。这与市场订单有什么关系？也许是指标调用 的问题？然后修改指标，用iCustom而不是iMACD来调用它。

也许我不需要修改什么，kodobase里有很多好东西。

我试着通过iCustom来做，但效果很慢。我试着通过iMAOnArray来做，但在数组方面遇到了问题。我无法设法将所有的人捆绑在一起。制作 iMACD更容易，但这是个问题

[Vitalie Postolache]

Rustam Bikbulatov:

我试过iCustom，但它工作得很慢。试过iMAOnArray，但对数组有问题。几天来无法将所有东西捆绑在一起。制作iMACD 更容易，但这是个问题。

你不能这样做，标准的iMACD使用SMA公式计算信号线，只有自定义才有帮助。

[Rustam Bikbulatov]

Vitalie Postolache:

不可能，标准的iMACD使用SMA公式计算信号线，只有自定义才有帮助。

好吧，我想明白了，这是不可能的。 非常感谢你的信息。

[Vitalie Postolache]

Rustam Bikbulatov:

我已经意识到这是不可能的，非常感谢您提供的信息。

没有什么是不可能的，我们只是需要把范围扩大一点))))。

[Artyom Trishkin]

Rustam Bikbulatov:

就是这样，我意识到这是不可能的，非常感谢你的信息。

以下是标准MACD的代码

//+------------------------------------------------------------------+
//|                                                  Custom MACD.mq4 |
//|                   Copyright 2005-2014, MetaQuotes Software Corp. |
//|                                              http://www.mql4.com |
//+------------------------------------------------------------------+
#property copyright   "2005-2014, MetaQuotes Software Corp."
#property link        "http://www.mql4.com"
#property description "Moving Averages Convergence/Divergence"
#property strict

#include <MovingAverages.mqh>

//--- indicator settings
#property  indicator_separate_window
#property  indicator_buffers 2
#property   indicator_color1  Silver
#property   indicator_color2  Red
#property   indicator_width1  2
//--- indicator parameters
input int InpFastEMA=12;   // Fast EMA Period
input int InpSlowEMA=26;   // Slow EMA Period
input int InpSignalSMA=9;  // Signal SMA Period
//--- indicator buffers
double    ExtMacdBuffer[];
double    ExtSignalBuffer[];
//--- right input parameters flag
bool      ExtParameters=false;

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit(void)
  {
   IndicatorDigits(Digits+1);
//--- drawing settings
   SetIndexStyle(0,DRAW_HISTOGRAM);
   SetIndexStyle(1,DRAW_LINE);
   SetIndexDrawBegin(1,InpSignalSMA);
//--- indicator buffers mapping
   SetIndexBuffer(0,ExtMacdBuffer);
   SetIndexBuffer(1,ExtSignalBuffer);
//--- name for DataWindow and indicator subwindow label
   IndicatorShortName("MACD("+IntegerToString(InpFastEMA)+","+IntegerToString(InpSlowEMA)+","+IntegerToString(InpSignalSMA)+")");
   SetIndexLabel(0,"MACD");
   SetIndexLabel(1,"Signal");
//--- check for input parameters
   if(InpFastEMA<=1 || InpSlowEMA<=1 || InpSignalSMA<=1 || InpFastEMA>=InpSlowEMA)
     {
      Print("Wrong input parameters");
      ExtParameters=false;
      return(INIT_FAILED);
     }
   else
      ExtParameters=true;
//--- initialization done
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Moving Averages Convergence/Divergence                           |
//+------------------------------------------------------------------+
int OnCalculate (const int rates_total,
                 const int prev_calculated,
                 const datetime& time[],
                 const double& open[],
                 const double& high[],
                 const double& low[],
                 const double& close[],
                 const long& tick_volume[],
                 const long& volume[],
                 const int& spread[])
  {
   int i,limit;
//---
   if(rates_total<=InpSignalSMA || !ExtParameters)
      return(0);
//--- last counted bar will be recounted
   limit=rates_total-prev_calculated;
   if(prev_calculated>0)
      limit++;
//--- macd counted in the 1-st buffer
   for(i=0; i<limit; i++)
      ExtMacdBuffer[i]=iMA(NULL,0,InpFastEMA,0,MODE_EMA,PRICE_CLOSE,i)-
                    iMA(NULL,0,InpSlowEMA,0,MODE_EMA,PRICE_CLOSE,i);
//--- signal line counted in the 2-nd buffer
   SimpleMAOnBuffer(rates_total,prev_calculated,0,InpSignalSMA,ExtMacdBuffer,ExtSignalBuffer);
   //ExponentialMAOnBuffer(rates_total,prev_calculated,0,InpSignalSMA,ExtMacdBuffer,ExtSignalBuffer);
//--- done
   return(rates_total);
  }
//+------------------------------------------------------------------+

标记为粉红色 的那一行是我加的。

如果我取消粉红色标记的线条，并注释掉绿色标记的线条，MACD应该使用所有指数 型MACD来计算。

[Rustam Bikbulatov]

Artyom Trishkin:

以下是标准MACD的代码

标记为粉红色 的那条线是我加的。

如果我取消注释标有粉红色的线，并注释掉标有绿色的线，MACD应该使用所有指数型MACD来计算。

问题是如何在EA中做到这一点。EA自动使用SMA公式 进行计算

[Artyom Trishkin]

Rustam Bikbulatov:

问题是如何在EA中做到这一点。EA使用公式自动计算SMA

我向你展示了如何制作一个自定义的MACD。

这就是你应该通过iCustom()在你的专家顾问中使用的内容。

[Rustam Bikbulatov]

Artyom Trishkin:

我向你展示了如何制作一个自定义的MACD。

这就是你应该通过iCustom()在你的专家顾问中使用的内容。

我有大量的数据，而灌木丛的速度正在减慢。我已经试过了。它正在影响结果。还是谢谢你。

[[删除]]

Rustam Bikbulatov:

我有大量的数据，而灌木丛的速度正在减慢。我已经试过了。它正在影响结果。同样感谢。

检查你的设置，也许你有太多的条形显示，因此出现滞后。