[ARŞİV] Forumu kirletmemek için herhangi bir acemi sorusu. Profesyonel, kaçırmayın. Sensiz hiçbir yerde - 3. - MQL4 ve MetaTrader 4 - MQL4 programlama forumu

Vitaliy Andreischev 2011.09.27 13:58 #2171

Shniperson :

Merhaba! Çok miktarda kod ve işlem yapan Expert Advisor'ların biraz yavaşlaması.

Min'in robotta işlemleri izlemek için büyük bir bloğu var... bu blok ayrı bir danışma belgesine kaldırılırsa (ve ilkinden kaldırılırsa), o zaman benimki aynı anda 2 danışmana sahip olacak... Daha hızlı çalışacaklar mı? Bugün nasılsın? Yani, bir anlaşma üzerinde karar vermek daha hızlı olacak mı .. ve buna bağlı olarak, zararı durdurma kararları daha hızlı verilecek mi?

Bence bu, zararı durdurma kararını takip etme kararıyla ilgili değil , komisyoncu tarafından emir yürütme hızıyla ilgili. Karar vermek bir şey, onu gerçekleştirmek başka bir şey.

Vadim Zhunko 2011.09.27 14:48 #2172

Suliena :

Çok teşekkürler! Bölgesel ayarlarda liste ayırıcının ayarlanması gerektiği ortaya çıktı !!!

2 gündür kod üzerinde kafamı kaşıyorum!

Bölgesel ayarlara dokunmayın! Excel'de bir ayırıcı ayarı var.

noobys 2011.09.27 18:32 #2173

Lütfen bana söyle! MACD değişkenlerinin farkı puan cinsinden nasıl yazılır? Örneğin:

 if ( MACDCurrent-MACDSignal)> 5 * Point    // ??

Boris 2011.09.27 19:22 #2174

Söyle bana, lütfen, standart olmayan TF'ye dönüştürücü, aksi takdirde arama bir şey için çalışmaz! Teşekkür ederim!

Mikhail Dovbakh 2011.09.27 19:32 #2175

borilunad :

Söyle bana, lütfen, standart olmayan TF'ye dönüştürücü, aksi takdirde arama bir şey için çalışmaz! Teşekkür ederim!

 Period_Converter.mq4

 //|                 Copyright © 2005-2007, MetaQuotes Software Corp. |

 //|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2007, MetaQuotes Software Corp."
#property link       "http://www.metaquotes.net"
#property show_inputs
#include <WinUser32.mqh>

extern int ExtPeriodMultiplier= 5 ; // new period multiplier factor
int         ExtHandle=- 1 ;
//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
int start()
  {
   int     i, start_pos, i_time, time0, last_fpos, periodseconds;
   double d_open, d_low, d_high, d_close, d_volume, last_volume;
   int     hwnd= 0 ,cnt= 0 ;
//---- History header
   int      version = 400 ;
   string c_copyright;
   string c_symbol= Symbol ();
   int     i_period= Period ()*ExtPeriodMultiplier;
   int     i_digits= Digits ;
   int     i_unused[ 13 ];
//----  
   ExtHandle= FileOpenHistory (c_symbol+i_period+ ".hst" , FILE_BIN | FILE_WRITE );
   if (ExtHandle < 0 ) return (- 1 );
//---- write history file header
   c_copyright= "(C)opyright 2003, MetaQuotes Software Corp." ;
   FileWriteInteger (ExtHandle, version , LONG_VALUE);
   FileWriteString (ExtHandle, c_copyright, 64 );
   FileWriteString (ExtHandle, c_symbol, 12 );
   FileWriteInteger (ExtHandle, i_period, LONG_VALUE);
   FileWriteInteger (ExtHandle, i_digits, LONG_VALUE);
   FileWriteInteger (ExtHandle, 0 , LONG_VALUE);       //timesign
   FileWriteInteger (ExtHandle, 0 , LONG_VALUE);       //last_sync
   FileWriteArray (ExtHandle, i_unused, 0 , 13 );
//---- write history file
   periodseconds=i_period* 60 ;
   start_pos= Bars - 1 ;
   d_open=Open[start_pos];
   d_low=Low[start_pos];
   d_high=High[start_pos];
   d_volume=Volume[start_pos];
   //---- normalize open time
   i_time=Time[start_pos]/periodseconds;
   i_time*=periodseconds;
   for (i=start_pos- 1 ;i>= 0 ; i--)
     {
      time0=Time[i];
       //---- history may be updated
       if (i== 0 )
        {
         //---- modify index if history was updated
         if ( RefreshRates ())
            i= iBarShift ( NULL , 0 ,time0);
        }
       //----
       if (time0>=i_time+periodseconds || i== 0 )
        {
         if (i== 0 && time0<i_time+periodseconds)
           {
            d_volume+=Volume[ 0 ];
             if (Low[ 0 ]<d_low)   d_low=Low[ 0 ];
             if (High[ 0 ]>d_high) d_high=High[ 0 ];
            d_close=Close[ 0 ];
           }
         last_fpos= FileTell (ExtHandle);
         last_volume=Volume[i];
         FileWriteInteger (ExtHandle, i_time, LONG_VALUE);
         FileWriteDouble (ExtHandle, d_open, DOUBLE_VALUE);
         FileWriteDouble (ExtHandle, d_low, DOUBLE_VALUE);
         FileWriteDouble (ExtHandle, d_high, DOUBLE_VALUE);
         FileWriteDouble (ExtHandle, d_close, DOUBLE_VALUE);
         FileWriteDouble (ExtHandle, d_volume, DOUBLE_VALUE);
         FileFlush (ExtHandle);
         cnt++;
         if (time0>=i_time+periodseconds)
           {
            i_time=time0/periodseconds;
            i_time*=periodseconds;
            d_open=Open[i];
            d_low=Low[i];
            d_high=High[i];
            d_close=Close[i];
            d_volume=last_volume;
           }
        }
       else
        {
         d_volume+=Volume[i];
         if (Low[i]<d_low)   d_low=Low[i];
         if (High[i]>d_high) d_high=High[i];
         d_close=Close[i];
        }
     } 
   FileFlush (ExtHandle);
   Print (cnt, " record(s) written" );
//---- collect incoming ticks
   int last_time=LocalTime()- 5 ;
   while ( IsStopped ()==false)
     {
       int cur_time=LocalTime();
       //---- check for new rates
       if ( RefreshRates ())
        {
         time0=Time[ 0 ];
         FileSeek (ExtHandle,last_fpos, SEEK_SET );
         //---- is there current bar?
         if (time0<i_time+periodseconds)
           {
            d_volume+=Volume[ 0 ]-last_volume;
            last_volume=Volume[ 0 ]; 
             if (Low[ 0 ]<d_low) d_low=Low[ 0 ];
             if (High[ 0 ]>d_high) d_high=High[ 0 ];
            d_close=Close[ 0 ];
           }
         else
           {
             //---- no, there is new bar
            d_volume+=Volume[ 1 ]-last_volume;
             if (Low[ 1 ]<d_low) d_low=Low[ 1 ];
             if (High[ 1 ]>d_high) d_high=High[ 1 ];
             //---- write previous bar remains
             FileWriteInteger (ExtHandle, i_time, LONG_VALUE);
             FileWriteDouble (ExtHandle, d_open, DOUBLE_VALUE);
             FileWriteDouble (ExtHandle, d_low, DOUBLE_VALUE);
             FileWriteDouble (ExtHandle, d_high, DOUBLE_VALUE);
             FileWriteDouble (ExtHandle, d_close, DOUBLE_VALUE);
             FileWriteDouble (ExtHandle, d_volume, DOUBLE_VALUE);
            last_fpos= FileTell (ExtHandle);
             //----
            i_time=time0/periodseconds;
            i_time*=periodseconds;
            d_open=Open[ 0 ];
            d_low=Low[ 0 ];
            d_high=High[ 0 ];
            d_close=Close[ 0 ];
            d_volume=Volume[ 0 ];
            last_volume=d_volume;
           }
         //----
         FileWriteInteger (ExtHandle, i_time, LONG_VALUE);
         FileWriteDouble (ExtHandle, d_open, DOUBLE_VALUE);
         FileWriteDouble (ExtHandle, d_low, DOUBLE_VALUE);
         FileWriteDouble (ExtHandle, d_high, DOUBLE_VALUE);
         FileWriteDouble (ExtHandle, d_close, DOUBLE_VALUE);
         FileWriteDouble (ExtHandle, d_volume, DOUBLE_VALUE);
         FileFlush (ExtHandle);
         //----
         if (hwnd== 0 )
           {
            hwnd= WindowHandle ( Symbol (),i_period);
             if (hwnd!= 0 ) Print ( "Chart window detected" );
           }
         //---- refresh window not frequently than 1 time in 2 seconds
         if (hwnd!= 0 && cur_time-last_time>= 2 )
           {
            PostMessageA(hwnd,WM_COMMAND, 33324 , 0 );
            last_time=cur_time;
           }
        }
       Sleep ( 50 ); 
     }      
//----
   return ( 0 );
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void deinit()
  {
   if (ExtHandle>= 0 ) { FileClose (ExtHandle); ExtHandle=- 1 ; }
  }
//+------------------------------------------------------------------+

Bir TF veya bir sembol yaratırken, onu çevrimdışı bir çizelge gibi bağlarız. onlar. DOSYA -> ÇEVRİMDIŞI AÇ...

Boris 2011.09.27 20:07 #2176

avatara :
Bir TF veya bir sembol yaratırken, onu çevrimdışı bir çizelge gibi bağlarız. onlar. DOSYA -> ÇEVRİMDIŞI AÇ...

Teşekkürler! Ama bir danışman çalıştırabilecek bir dönüştürücü arıyorum!

Hatırlıyorum, bazı konularda bununla ilgili bir tartışma vardı ve CodeBase'de ne var.

26994 2011.09.27 20:23 #2177

Kaybı durdurmak ve bir kod parçası ile almak için sondaki ve başa baş nasıl bağlanır?

Bir yere bir kod parçası yapıştırmak istedim. Evet, evet, bu "stratejilerine göre"

Mikhail Dovbakh 2011.09.27 20:43 #2178

borilunad :

Teşekkürler! Ama bir danışman çalıştırabilecek bir dönüştürücü arıyorum!

Hatırlıyorum, bazı konularda bununla ilgili bir tartışma vardı ve CodeBase'de ne var.

sonrasında.

rakibin programı ile bir pencere ne zaman olacak. ve komut dosyası kaynakta düzgün bir şekilde gıcırdayacak ....

Hindileri ve baykuşları ona fırlatın (pencerede / program köründe!) - her şey çalışıyor!

;)

Shniperson 2011.09.27 21:14 #2179

Beyler, bana bir "danışman" veya bir komut dosyası söyleyebilir misiniz .. mevcut (açık) işlemin kaç puan ve zarar / kâr parası olduğunu ve bakiyenin ne olduğunu büyük sayılarla gösterecek .. yoksa bulamıyorum .. kendimden bir şey.

Boris 2011.09.27 22:19 #2180

avatara :

sonrasında.

rakibin programı ile bir pencere ne zaman olacak. ve komut dosyası kaynakta düzgün bir şekilde gıcırdayacak ....

Hindileri ve baykuşları ona fırlatın (pencerede / program köründe!) - her şey çalışıyor!

;)

Çok tınkayım!

Buldum, koda gerekli satırları ekledim ve ekledim, çevrimdışı kaldırdım ve yorumlar gitti. Yarın ticaret yapmayı deneyelim.

Test cihazındaki parametreleri kontrol edememeniz üzücü, Demo'da daha uzun oturmanız gerekecek.

İyi geceler!

Çoklu Zaman Çerçevesi Göstergeleri Dijital Filtrelere Dayalı Ticaret AltınSavaşçı02b

[ARŞİV] Forumu kirletmemek için herhangi bir acemi sorusu. Profesyonel, kaçırmayın. Sensiz hiçbir yerde - 3. - sayfa 218