Обсуждение статьи "Графические интерфейсы VII: Элементы "Вкладки" (Глава 2)" - страница 3

Новый комментарий
 

Как мне добавить CLabel на вкладки, когда я создаю элемент CLabel и хочу добавить его на вкладки, компилятор выдает такую ошибку:


CLabel m_overview_titlte_label;

bool CMainPanel::CreateOverviewTitleLabel(const string text)
  {

//--- Передайте объект панели
   m_overview_title_label.WindowPointer(m_window);
//--- Прикрепите к четвертой вкладке первой группы вкладок
   m_main_panel_tabs.AddToElementsArray(0,m_overview_title_label);  
   m_main_panel_tabs.AddToElementsArray( 
//--- Координаты
   int x=m_window.X()+OVERVIE_TITLE_LABEL_GAP_X;
   int y=m_window.Y()+OVERVIE_TITLE_LABEL_GAP_Y;
//--- Установите свойства перед созданием
   m_overview_title_label.XSize(140);
   m_overview_title_label.YSize(18);
   //m_overview_title_label.
//--- Создайте элемент управления
   if(!m_overview_title_label.Create(m_chart_id,text,m_subwin,x,y))
      return(false);
//--- Добавьте объект в общий массив групп объектов
   //CWndContainer::AddToElementsArray(0,m_overview_title_label);
   return(true);
  }


Compiler Error:

'WindowPointer' - функция не определена MainPanel.mqh 233 27

'm_overview_title_label' - преобразование параметров недопустимо MainPanel.mqh 235 43

'm_overview_title_label' - ожидается переменная того же типа MainPanel.mqh 235 43

 
Martin Fischer функции типа WindowPointer().
Я могу создать эти объекты, но не могу прикрепить их к окну.


не работает в этом случае...

2.)
Является ли CComboBox статическим объектом. Можно ли изменить список элементов в

ComboBox-Listview после создания ComboBox?

Спасибо!

У меня была такая же проблема, я решил ее созданием файла include и написанием своего класса лейбла и использованием его. Вы должны создать этот файл в Include\EasyAndFastGUI\Controls\MyLabel.mqh

Вот этот код:

//+------------------------------------------------------------------+
//|MyLabel.mqh |
//|Copyright 2023, Sassiz.Root |
//|https://t.me/R00T_S4SS12 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2023, Sassiz.Root"
#property link      "https://t.me/R00T_S4SS12"
#property strict

#include "Element.mqh"
#include "Window.mqh"
//+------------------------------------------------------------------+
//| Класс для создания флажка|
//+------------------------------------------------------------------+
class MyLabel : public CElement
  {
private:
   //--- Указатель на форму, к которой прикреплен элемент
   CWindow          *m_wnd;
   //--- Объекты для создания флажка

   CLabel            m_label;

   //--- Текст флажка
   string            m_label_text;
   //--- Поля для текстовых надписей
   int               m_label_x_gap;
   int               m_label_y_gap;
   //--- Цвета текстовой метки в разных состояниях
   color             m_label_color;
   color             m_label_color_off;
   color             m_label_color_hover;
   color             m_label_color_locked;
   color             m_label_color_array[];
   //--- Приоритеты нажатия левой кнопки мыши
   int               m_zorder;
   int               m_area_zorder;

   //---
public:
                     MyLabel(void);
                    ~MyLabel(void);
   //--- Методы создания флажка
   bool              CreateLabel(const long chart_id,const int subwin,const string text,const int x,const int y);
   //---
private:
   bool              CreateLabel2(void);
   //---
public:
   //--- (1) Сохраняет указатель формы, (2) возвращает/устанавливает состояние флажка
   void              WindowPointer(CWindow &object)                 { m_wnd=::GetPointer(object);            }

   //--- (1) Цвет фона, (2) Поля для текстовой метки

   void              LabelXGap(const int x_gap)                     { m_label_x_gap=x_gap;                   }
   void              LabelYGap(const int y_gap)                     { m_label_y_gap=y_gap;                   }
   //--- Цвет текста в разных состояниях
   void              LabelColor(const color clr)                    { m_label_color=clr;                     }

   //--- (1) Описание флажка, (2) возврат/установка состояния кнопки флажка
   string            LabelText(void)                          const { return(m_label.Description());         }

   //--- Изменение цвета
   void              ChangeObjectsColor(void);
   //---
public:
   //--- Обработчик событий графика
   virtual void      OnEvent(const int id,const long &lparam,const double &dparam,const string &sparam);
   //--- Таймер
   virtual void      OnEventTimer(void);
   //--- Перемещение элемента
   virtual void      Moving(const int x,const int y);
   //--- (1) показать, (2) скрыть, (3) сбросить, (4) удалить
   virtual void      Show(void);
   virtual void      Hide(void);
   virtual void      Reset(void);
   virtual void      Delete(void);
   //--- (1) Установка, (2) сброс приоритетов нажатия левой кнопки мыши
   virtual void      SetZorders(void);
   virtual void      ResetZorders(void);
   //--- Сбросьте цвет
   virtual void      ResetColors(void);
   virtual void      SetText(string text);
   virtual void      SetFontSize(int fontSize);
   //---
private:
   //--- Обработка нажатия на элемент
   bool              OnClickLabel(const string clicked_object);
  };
//+------------------------------------------------------------------+
//| Конструктор|
//+------------------------------------------------------------------+
MyLabel::MyLabel(void) :      
                             m_label_x_gap(20),
                             m_label_y_gap(2),
                             m_label_color(clrBlack)
                             
  {
//--- Храните имя класса элемента в базовом классе
   CElement::ClassName(CLASS_NAME);
//--- Установите приоритеты нажатия левой кнопки мыши
   m_zorder      =0;
   m_area_zorder =1;
  }
//+------------------------------------------------------------------+
//| Деструктор|
//+------------------------------------------------------------------+
MyLabel::~MyLabel(void)
  {
  }
//+------------------------------------------------------------------+
//| Обработка событий|
//+------------------------------------------------------------------+
void MyLabel::OnEvent(const int id,const long &lparam,const double &dparam,const string &sparam)
  {
//--- Обработка события перемещения курсора
   if(id==CHARTEVENT_MOUSE_MOVE)
     {
      //--- Оставить, если элемент скрыт
      if(!CElement::IsVisible())
         return;
      //--- Оставить, если номера подокон не совпадают
      if(CElement::m_subwin!=CElement::m_mouse.SubWindowNumber())
         return;
      //--- Проверка фокуса на элементе
      CElement::MouseFocus(m_mouse.X()>X() && m_mouse.X()<X2() && m_mouse.Y()>Y() && m_mouse.Y()<Y2());
      return;
     }
//--- Обработка нажатия левой кнопки мыши на объекте
   if(id==CHARTEVENT_OBJECT_CLICK)
     {
      //--- Нажатие на флажок
      if(OnClickLabel(sparam))
         return;
     }
  }
//+------------------------------------------------------------------+
//| Таймер|
//+------------------------------------------------------------------+
void MyLabel::OnEventTimer(void)
  {
//--- Если форма не заблокирована
   if(!m_wnd.IsLocked())
      //--- Изменение цвета объектов элемента
      ChangeObjectsColor();
  }
//+------------------------------------------------------------------+
//| Создает группу объектов флажков.|
//+------------------------------------------------------------------+
bool MyLabel::CreateLabel(const long chart_id,const int subwin,const string text,const int x,const int y)
  {
//--- Оставьте, если нет указателя формы
   if(!CElement::CheckWindowPointer(::CheckPointer(m_wnd)))
      return(false);
//--- Инициализация переменных
   m_id         =m_wnd.LastId()+1;
   m_chart_id   =chart_id;
   m_subwin     =subwin;
   m_x          =x;
   m_y          =y;
   m_label_text =text;
//--- Отступы от края
   CElement::XGap(CElement::X()-m_wnd.X());
   CElement::YGap(CElement::Y()-m_wnd.Y());
//--- Создание элемента

   if(!CreateLabel2())
      return(false);
//--- Скрыть элемент, если окно является диалоговым или свернуто.
   if(m_wnd.WindowType()==W_DIALOG || m_wnd.IsMinimized())
      Hide();
//---
   return(true);
  }


//+------------------------------------------------------------------+
//| Создает ярлык флажка|
//+------------------------------------------------------------------+
bool MyLabel::CreateLabel2(void)
  {
//--- Формирование имени объекта
   string name=CElement::ProgramName()+"_lable_"+(string)CElement::Id();
//--- Координаты
   int x =CElement::X()+m_label_x_gap;
   int y =CElement::Y()+m_label_y_gap;
//--- Цвет текста в зависимости от состояния
   color label_color=clrBlack;//(m_check_button_state) ? m_label_color : m_label_color_off;
//--- Установите объект
   if(!m_label.Create(m_chart_id,name,m_subwin,x,y))
      return(false);
//--- установить свойства
   m_label.Description(m_label_text);
   m_label.Font(FONT);
   m_label.FontSize(FONT_SIZE);
   m_label.Color(label_color);
   m_label.Corner(m_corner);
   m_label.Anchor(m_anchor);
   m_label.Selectable(false);
   m_label.Z_Order(m_zorder);
   m_label.Tooltip("\n");
//--- Отступы от края
   m_label.XGap(x-m_wnd.X());
   m_label.YGap(y-m_wnd.Y());
//--- Инициализация массива градиентов
   CElement::InitColorArray(label_color,m_label_color_hover,m_label_color_array);
//--- Храните указатель объекта
   CElement::AddToArray(m_label);
   return(true);
  }
//+------------------------------------------------------------------+
//| Перемещение элементов|
//+------------------------------------------------------------------+
void MyLabel::Moving(const int x,const int y)
  {
//--- Оставить, если элемент скрыт
   if(!CElement::IsVisible())
      return;
//--- Хранение отступов в полях элементов
   CElement::X(x+XGap());
   CElement::Y(y+YGap());
//--- Хранение координат в полях объектов
   m_label.X(x+m_label.XGap());
   m_label.Y(y+m_label.YGap());
//--- Обновление координат графических объектов
   m_label.X_Distance(m_label.X());
   m_label.Y_Distance(m_label.Y());
  }
//+------------------------------------------------------------------+
//| Изменение цвета объекта при наведении на него курсора |
//+------------------------------------------------------------------+
void MyLabel::ChangeObjectsColor(void)
  {
//--- Оставьте, если элемент заблокирован

//---
   color label_color=clrBlack;//(m_check_button_state) ? m_label_color : m_label_color_off;
   CElement::ChangeObjectColor(m_label.Name(),CElement::MouseFocus(),OBJPROP_COLOR,label_color,m_label_color_hover,m_label_color_array);
  }
//+------------------------------------------------------------------+
//| Показывает combobox|
//+------------------------------------------------------------------+
void MyLabel::Show(void)
  {
//--- Оставить, если элемент уже виден
   if(CElement::IsVisible())
      return;
//--- Сделайте все объекты видимыми
   for(int i=0; i<CElement::ObjectsElementTotal(); i++)
      CElement::Object(i).Timeframes(OBJ_ALL_PERIODS);
//--- Состояние видимости
   CElement::IsVisible(true);
  }
//+------------------------------------------------------------------+
//| Скрывает combobox|
//+------------------------------------------------------------------+
void MyLabel::Hide(void)
  {
//--- Оставить, если элемент уже виден
   if(!CElement::IsVisible())
      return;
//--- Скрыть все объекты
   for(int i=0; i<CElement::ObjectsElementTotal(); i++)
      CElement::Object(i).Timeframes(OBJ_NO_PERIODS);
//--- Состояние видимости
   CElement::IsVisible(false);
  }
//+------------------------------------------------------------------+
//| Перерисовка|
//+------------------------------------------------------------------+
void MyLabel::Reset(void)
  {
//--- Оставить, если это выпадающий элемент
   if(CElement::IsDropdown())
      return;
//--- Скрывать и показывать
   Hide();
   Show();
  }
//+------------------------------------------------------------------+
//| Удаление|
//+------------------------------------------------------------------+
void MyLabel::Delete(void)
  {
//--- Удаление объектов
   m_label.Delete();
//--- Очистка массива от объектов
   CElement::FreeObjectsArray();
//--- Инициализация переменных значениями по умолчанию
   CElement::MouseFocus(false);
   CElement::IsVisible(true);
  }
//+------------------------------------------------------------------+
//| Установите приоритеты|
//+------------------------------------------------------------------+
void MyLabel::SetZorders(void)
  {
   m_label.Z_Order(m_zorder);
  }
//+------------------------------------------------------------------+
//| Сбросьте приоритеты|
//+------------------------------------------------------------------+
void MyLabel::ResetZorders(void)
  {
   m_label.Z_Order(0);
  }
//+------------------------------------------------------------------+
//| Сбросьте цвет объектов элемента.|
//+------------------------------------------------------------------+
void MyLabel::ResetColors(void)
  {

//--- Сбросьте цвет
   m_label.Color(clrBlack);
//--- Обнулить фокус
   CElement::MouseFocus(false);
  }

//+------------------------------------------------------------------+
//| Щелчок по заголовку элемента|
//+------------------------------------------------------------------+
bool MyLabel::OnClickLabel(const string clicked_object)
  {

//--- Курсор мыши в данный момент находится над элементом
   m_label.Color(m_label_color_hover);
//--- Отправьте сообщение об этом
   ::EventChartCustom(m_chart_id,ON_CLICK_LABEL,CElement::Id(),0,m_label.Description());
   return(true);
  }
//+------------------------------------------------------------------+


void MyLabel::SetText(string text){
   m_label.Description(text);
}

void MyLabel::SetFontSize(int fontSize){
   m_label.FontSize(fontSize);
}

Затем создайте объект из класса MyLabel вот так и используйте его:

   //---Label
   MyLabel           m_overview_title_label;

Затем:

//+------------------------------------------------------------------+
//| Создает метку OverviewTitleLabel|
//+------------------------------------------------------------------+
bool CMainPanel::CreateOverviewTitleLabel(const string text)
  {

//--- Передайте объект панели
   m_overview_title_label.WindowPointer(m_window);
//--- Прикрепите к четвертой вкладке первой группы вкладок
   m_main_panel_tabs.AddToElementsArray(0,m_overview_title_label);  
//--- Координаты
   int x=m_window.X()+OVERVIE_TITLE_LABEL_GAP_X;
   int y=m_window.Y()+OVERVIE_TITLE_LABEL_GAP_Y;
//--- Установите свойства перед созданием
   m_overview_title_label.XSize(140);
   m_overview_title_label.YSize(18);
   m_overview_title_label.SetText(text);
   m_overview_title_label.SetFontSize(18);
   //m_overview_title_label.
//--- Создайте элемент управления
   if(!m_overview_title_label.CreateLabel(m_chart_id,m_subwin,text,x,y))
      return(false);
//--- Добавьте объект в общий массив групп объектов
   CWndContainer::AddToElementsArray(0,m_overview_title_label);
   return(true);
  }
 
Если мы увеличим количество вкладок, как по вертикали, так и по горизонтали, возможности прокрутки не будет, что приведет к расширению окна за его пределы и снижению эффективности.
123
Новый комментарий