Скачать MetaTrader 5

Помогите раскрасить график пожалуйста!

Авторизуйтесь или зарегистрируйтесь, чтобы добавить комментарий
Создавай интересные темы на форуме по автоматическому трейдингу!
Михаил
587
Михаил 2010.03.22 21:18 

Добрый вечер!

В голову пришла мысля примерно следующего содержания:

Ну раз уж тестера стратегий пока нет дай думаю по практикуюсь индикаторы рисовать!:) А так как стратегию я уже придумал и она  пока основана целиком на технических индикаторах то почему бы не написать свой индикатор который бы закрашивал свечи в соответствии с сигналами родных индикаторов? так и визуально можно определить успешность или на оборот безуспешность моей торговой системы:). Для примера я взял стохастик и решил разукрасить график в соответствии с его значениями. В результате у меня все бары графика окрашиваются в цвет соответствующий сигналу... Это мой первый кастом так что строго не судите:) ..... Поможите люди добрые!:)

#property version   "1.00"
#property indicator_chart_window
#property indicator_buffers 5
#property indicator_plots   1
#property indicator_label1  "Main"
#property indicator_type1   DRAW_COLOR_CANDLES

double OpenBuf[];
double HighBuf[];
double LowBuf[];
double CloseBuf[];
double MainBuf[];
double stochBuf[];
double stochsigBuf[];
int stoch=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
   SetIndexBuffer(0,OpenBuf,INDICATOR_DATA);
   SetIndexBuffer(1,HighBuf,INDICATOR_DATA);
   SetIndexBuffer(2,LowBuf,INDICATOR_DATA);
   SetIndexBuffer(3,CloseBuf,INDICATOR_DATA);
   SetIndexBuffer(4,MainBuf,INDICATOR_COLOR_INDEX);

   PlotIndexSetInteger(0,PLOT_SHOW_DATA,false);
   PlotIndexSetInteger(0,PLOT_COLOR_INDEXES,2);
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,1,Red);
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,2,DeepSkyBlue);

   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);

//---

   stoch=iStochastic(NULL,0,7,3,3,MODE_EMA,STO_LOWHIGH);

   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {

   int  i=0;
   if(i<prev_calculated) i=prev_calculated-1;
   for(i=0;i<rates_total;i++)
     {
      OpenBuf[i]=open[i];
      HighBuf[i]=high[i];
      LowBuf[i]=low[i];
      CloseBuf[i]=close[i];
      ArraySetAsSeries(stochBuf,true);
      ArraySetAsSeries(stochsigBuf,true);
      CopyBuffer(stoch,0,0,50,stochBuf);
      CopyBuffer(stoch,1,0,50,stochsigBuf);
      if(stochBuf[0]<stochsigBuf[0])
        {
         MainBuf[i]=1;
        }
      if(stochBuf[0]>stochsigBuf[0])
        {
         MainBuf[i]=2;
        }
     }
   return(rates_total);
  }
Документация по MQL5: Технические индикаторы
Документация по MQL5: Технические индикаторы
  • www.mql5.com
Технические индикаторы - Документация по MQL5
Dmitry Voronkov
5761
Dmitry Voronkov 2010.03.22 22:41  
OneBillionUSD писал(а) # :

Добрый вечер!

В голову пришла мысля примерно следующего содержания:

Ну раз уж тестера стратегий пока нет дай думаю по практикуюсь индикаторы рисовать!:) А так как стратегию я уже придумал и она  пока основана целиком на технических индикаторах то почему бы не написать свой индикатор который бы закрашивал свечи в соответствии с сигналами родных индикаторов? так и визуально можно определить успешность или на оборот безуспешность моей торговой системы:). Для примера я взял стохастик и решил разукрасить график в соответствии с его значениями. В результате у меня все бары графика окрашиваются в цвет соответствующий сигналу... Это мой первый кастом так что строго не судите:) ..... Поможите люди добрые!:)

В чем помощь нужна?

   PlotIndexSetInteger(0,PLOT_COLOR_INDEXES,2);
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,0,Red);
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,1,DeepSkyBlue);

 

      if(stochBuf[0]<stochsigBuf[0])
        {
         MainBuf[i]=0;
        }
     if(stochBuf[0]>stochsigBuf[0])
        {
         MainBuf[i]=1;
        }

решение проблемы с цветом.

дальше читай https://www.mql5.com/ru/articles/43  https://www.mql5.com/ru/articles/5

Способы вызова индикаторов в MQL5
Способы вызова индикаторов в MQL5
  • 2010.03.09
  • KlimMalgin
  • www.mql5.com
C появлением новой версии языка MQL, не только изменился подход к работе с индикаторами, но и появились новые способы создания индикаторов. Кроме того, появилась дополнительная гибкость при работе с индикаторными буферами - теперь вы можете самостоятельно указать нужное направление индексации и получать ровно столько значений индикатора, сколько вам требуется. В этой статье рассмотрены базовые методы вызова индикаторов и получения данных из индикаторных буферов.
Dmitry Voronkov
5761
Dmitry Voronkov 2010.03.22 23:46  

Вот твой индюк!

Если я правильно понял твой вопрос :)

 

#property version   "1.00"
#property indicator_chart_window
#property indicator_buffers 5
#property indicator_plots   1
#property indicator_label1  "Main"
#property indicator_type1   DRAW_COLOR_CANDLES

input int InpKPeriod=7;  // K period
input int InpDPeriod=3;  // D period
input int InpSlowing=3;  // Slowing

double OpenBuf[];
double HighBuf[];
double LowBuf[];
double CloseBuf[];
double MainBuf[];
double stochBuf[];
double stochsigBuf[];
int stoch=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
   SetIndexBuffer(0,OpenBuf,INDICATOR_DATA);
   SetIndexBuffer(1,HighBuf,INDICATOR_DATA);
   SetIndexBuffer(2,LowBuf,INDICATOR_DATA);
   SetIndexBuffer(3,CloseBuf,INDICATOR_DATA);
   SetIndexBuffer(4,MainBuf,INDICATOR_COLOR_INDEX);

   PlotIndexSetInteger(0,PLOT_SHOW_DATA,false);
   PlotIndexSetInteger(0,PLOT_COLOR_INDEXES,2);
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,0,Red);
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,1,DeepSkyBlue);
   ArraySetAsSeries(stochBuf,true);
   ArraySetAsSeries(stochsigBuf,true);

   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);

//---

   stoch=iStochastic(NULL,0,InpKPeriod,InpDPeriod,InpSlowing,MODE_EMA,STO_LOWHIGH);

   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   int count=BarsCalculated(stoch);
   if(count<=0)
     {
      Print("Not all data of iStochastic is calculated. Error",GetLastError());
      return(0);
     }
   if(CopyBuffer(stoch,0,0,rates_total,stochBuf)<=0 || 
      CopyBuffer(stoch,1,0,rates_total,stochsigBuf)<=0)
     {
      Print("Getting iStochastic data is failed! Error",GetLastError());
      return(0);
     }
   int start=MathMax(InpKPeriod,InpDPeriod);
   if(start<prev_calculated) start=prev_calculated-1;


   for(int i=start;i<rates_total;i++)
     {
      OpenBuf[i]=open[i];
      HighBuf[i]=high[i];
      LowBuf[i]=low[i];
      CloseBuf[i]=close[i];
      if(stochBuf[i]<stochsigBuf[i])
        {
         MainBuf[i]=0;
        }
      if(stochBuf[i]>stochsigBuf[i])
        {
         MainBuf[i]=1;
        }
     }
   return(rates_total);
  }
//+------------------------------------------------------------------+
Михаил
587
Михаил 2010.03.23 20:37  
vdv2001 писал(а) # :

В чем помощь нужна?

Дело было в том что у меня весь график окрашивался в тот цвет который соответствовал сигналу на нулевом баре.
Михаил
587
Михаил 2010.03.23 20:38  
vdv2001 писал(а) # :

Вот твой индюк!

Если я правильно понял твой вопрос :)

 

 Спасибо большое за пример! А про статью https://www.mql5.com/ru/articles/5 я совсем забыл!)
Переход на новые рельсы: пользовательские индикаторы в MQL5
Переход на новые рельсы: пользовательские индикаторы в MQL5
  • 2009.11.23
  • Андрей
  • www.mql5.com
Я не буду перечислять все новые возможности и особенности нового терминала и языка. Их действительно много, и некоторые новинки вполне достойны освещения в отдельной статье. Вы не увидите здесь кода, написанного по принципам объектно-ориентированного программирования — это слишком серьезная тема для того, чтобы просто быть упомянутой в контексте как дополнительная вкусность для кодописателей. В этой статье остановимся подробней на индикаторах, их строении, отображении, видах, а также особенностях их написания по сравнению с MQL4.
Авторизуйтесь или зарегистрируйтесь, чтобы добавить комментарий