Вопрос к разработчикам.

Новый комментарий
 
Уважаемые создатели!!
Объясните пожалуйста следующий казус.
Берем стандартный пользовательский индикатор OsMA,
приравниваем индикаторные буферы константе.
Индикатор не показывает ничего а должен рисовать прямую линию.
Вот код индикатора:

//+------------------------------------------------------------------+
//|                                                         OsMA.mq4 |
//|                      Copyright © 2004, MetaQuotes Software Corp. |
//|                                       http://www.metaquotes.net/ |
//+------------------------------------------------------------------+
#property  copyright "Copyright © 2004, MetaQuotes Software Corp."
#property  link      "http://www.metaquotes.net/"
//---- indicator settings
#property  indicator_separate_window
#property  indicator_buffers 1
#property  indicator_color1  Silver
//---- indicator parameters
extern int FastEMA=12;
extern int SlowEMA=26;
extern int SignalSMA=9;
//---- indicator buffers
double     ind_buffer1[];
double     ind_buffer2[];
double     ind_buffer3[];

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- 2 additional buffers are used for counting.
   IndicatorBuffers(3);
//---- drawing settings
   SetIndexStyle(0,DRAW_HISTOGRAM,STYLE_SOLID,3);
   SetIndexDrawBegin(0,SignalSMA);
   IndicatorDigits(MarketInfo(Symbol(),MODE_DIGITS)+2);
//---- 3 indicator buffers mapping
   if(!SetIndexBuffer(0,ind_buffer1) &&
      !SetIndexBuffer(1,ind_buffer2) &&
      !SetIndexBuffer(2,ind_buffer3))
      Print("cannot set indicator buffers!");
//---- name for DataWindow and indicator subwindow label
   IndicatorShortName("OsMA("+FastEMA+","+SlowEMA+","+SignalSMA+")");
//---- initialization done
   return(0);
  }
//+------------------------------------------------------------------+
//| Moving Average of Oscillator                                     |
//+------------------------------------------------------------------+
int start()
  {
   int limit;
   int counted_bars=IndicatorCounted();
//---- check for possible errors
   if(counted_bars<0) return(-1);
//---- last counted bar will be recounted
   if(counted_bars>0) counted_bars--;
   limit=Bars-counted_bars;
//---- macd counted in the 1-st additional buffer
   for(int i=0; i<limit; i++)
      ind_buffer2[i]=1;
//---- signal line counted in the 2-nd additional buffer
   for(i=0; i<limit; i++)
      ind_buffer3[i]=1;
//---- main loop
   for(i=0; i<limit; i++)
      ind_buffer1[i]=ind_buffer2[i]+ind_buffer3[i];
//---- done
   return(0);
  }
//+------------------------------------------------------------------+



Вопрос: почему индикатор ничего не показывает?

 
разберёмся. спасибо, что показали
 
всё понятно. у индикатора нет диапазона "для размаха" - от 2 до 2 считается, что рисовать нечего. поставьте fixed minimum на 0 и увидите забор. надо будет подумать, как избегать подобных проблем
 
Огромное спасибо.
Подскажите еще пожалуйста, можно ли параметры диапазонов fixed minimum/fixed maximum задавать с помощью какой либо функции из самого индикатора, а не через пользовательское меню индикатора
 
#property indicator_minimum mmm
#property indicator_maximum nnn
Новый комментарий