Как закрыть позиции без перебора в советнике?

Anton Novokhatskii 2024.04.10 10:40 #11

Вопрос в том, как закрыть позиции без перебора. Я думаю, если в mql есть функция трейлинга из mt, то и функция глобального закрытия должна быть где то, только не могу ее найти

Alexey Viktorov 2024.04.10 11:53 #12

Anton Novokhatskii #:

Сейчас для закрытия позиций использую такую функцию. Измерять не приходится, когда начинается закрытие, видно что сильно отстает он инструмента mt. Может у вас есть на примере функция проще?

Это самый худший вариант. Попробуйте то-же самое, только без использования СБ. Будет чуток быстрей.

Потом вместо закрытия позиций открывайте противоположные таким-же лотом в асинхронном режиме. OrderSendAsync()

Artyom Trishkin 2024.04.10 11:58 #13

Anton Novokhatskii #:

А какая разница? что в одну что в другую сторону смысл будет один, просто закрываться будет в другую сторону

Нет. Сильно нет

Dmitriy Gizlyk 2024.04.10 12:07 #14

Anton Novokhatskii #:

А какая разница? что в одну что в другую сторону смысл будет один, просто закрываться будет в другую сторону

После закрытия позиции она уходит из списка открытых позиций. К примеру есть 2 открытые позиции.

m_position.SelectByIndex(0)

Вернет первую позицию, которую закроет

trade.PositionClose(m_position.Ticket());

После закрытия осталась 1 открытая позиция и

m_position.SelectByIndex(1)

вернет ошибку. И выход из цикла. Но осталась отрытая позиция, которая будет закрываться при следующем тике.

Следовательно, на каждом тике у Вас будет закрываться только половина открытых позиций. Отсюда большое время закрытия большого количества позиций.

Есть советник, если есть [ВНИМАНИЕ, ТЕМА ЗАКРЫТА!] Любой Как получить время первой

Anton Novokhatskii 2024.04.10 12:17 #15

Dmitriy Gizlyk #:

После закрытия позиции она уходит из списка открытых позиций. К примеру есть 2 открытые позиции.

Вернет первую позицию, которую закроет

После закрытия осталась 1 открытая позиция и

вернет ошибку. И выход из цикла. Но осталась отрытая позиция, которая будет закрываться при следующем тике.

Следовательно, на каждом тике у Вас будет закрываться только половина открытых позиций. Отсюда большое время закрытия большого количества позиций.

Спасибо за разьяснение, попробую изменить)

Yuriy Bykov 2024.04.10 12:51 #16

Про ошибку в цикле, идущем по возрастанию, уже объяснили выше.
Использую у себя такой метод в классе, который отвечает за открытие/закрытие позиций. Он закрывает все позиции по одному символу с нужным магиком:

class CVirtualSymbolReceiver : public CReceiver {
   static ulong s_magic;
   string            m_symbol;         // Символ

   CPositionInfo     m_position;       // Объект для получения свойств рыночных позиций
   CTrade            m_trade;          // Объект для совершения торговых операций

   ...
};

...

//+------------------------------------------------------------------+
//| Полное закрытие объёма по символу                                |
//+------------------------------------------------------------------+
bool CVirtualSymbolReceiver::CloseFull() {
   bool res = true;

   ulong ticket;
   bool found = true;

   while(found && !IsStopped()) {
      found = false;
      for(int i = 0; i < PositionsTotal(); i++) {
         if (m_position.SelectByIndex(i)) {
            if(m_position.Magic() == s_magic && (m_position.Symbol() == m_symbol)) {
               found = true;
               ticket = m_position.Ticket();
               res &= m_trade.PositionClose(ticket);
               break;
            }
         }
      }
      if(!res) {
         found = false;
      }
   }
   return res;
}

Если вам нужно просто закрыть абсолютно все позиции, то код можно упростить примерно так:

//+------------------------------------------------------------------+
//| Полное закрытие всех позиций                                     |
//+------------------------------------------------------------------+
void CloseFull() {
   CTrade trade;
   CPosition position;
   ulong ticket;
   bool found = true;

   while(found && !IsStopped()) {
      found = false;
      for(int i = PositionsTotal() - 1; i >= 0; i--) {
         if (position.SelectByIndex(i)) {
            found = true;
            ticket = position.Ticket();
            trade.PositionClose(ticket);
         }
      }
   }
}

В этой функции даже если какая-то операция закрытия закончится неудачно, все открытые позиции будут перебираться повторно, пока не будут закрыты все.