Array out of a range появляется только при импорте индикатора в эксперт.

Новый комментарий
 

Есть пользовательский индикатор который использует 3 Moving Average с разной длинной. Он нормально компилируется и нормально работает на графике показывая ожидаемый результат, но при попытке импортировать его в EA через iCustom отваливается с ошибкой "Array out of a range" причем в момент попытки получить данные одного из буферов (Причем не первого что особенно странно).

Ошибка: array out of range in 'Union_Oscillator.mq5' (142,64)

142 строку пометил комментарием в коде

Сам индикатор:

//+------------------------------------------------------------------+
//|                                             Union_Oscillator.mq5 |
//|                        Copyright 2020, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property indicator_separate_window

#property indicator_buffers 5
#property indicator_plots   1
#property indicator_type1   DRAW_COLOR_HISTOGRAM
#property indicator_color1  Green,Red,Black
#property indicator_width1  1
#property indicator_label1  "UO"
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
//--- indicator params
input ENUM_TIMEFRAMES timeframe=PERIOD_M1;
input ENUM_APPLIED_PRICE price=PRICE_MEDIAN;
input int fast_period=2;
input int middle_period=10;
input bool is_slow=true;
input int slow_period=20;

//--- indicator buffers
double ExtUOBuffer[];
double ExtColorBuffer[];
double ExtFastBuffer[];
double ExtMiddleBuffer[];
double ExtSlowBuffer[];
//--- handles for MAs
int    ExtFastSMAHandle;
int    ExtMiddleSMAHandle;
int    ExtSlowSMAHandle;
//--- bars minimum for calculation
#define DATA_LIMIT 33

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,ExtUOBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,ExtColorBuffer,INDICATOR_COLOR_INDEX);
   SetIndexBuffer(2,ExtFastBuffer,INDICATOR_CALCULATIONS);
   SetIndexBuffer(3,ExtFastBuffer,INDICATOR_CALCULATIONS);
   SetIndexBuffer(4,ExtSlowBuffer,INDICATOR_CALCULATIONS);
//--- set accuracy
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);
//--- sets first bar from what index will be drawn
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,33);
//--- name for DataWindow
   IndicatorSetString(INDICATOR_SHORTNAME,"UO");
//--- get handles
   ExtFastSMAHandle=iMA(NULL,timeframe,fast_period,0,MODE_SMA,price);
   ExtMiddleSMAHandle=iMA(NULL,timeframe,middle_period,0,MODE_SMA,price);
   ExtSlowSMAHandle=iMA(NULL,timeframe,slow_period,0,MODE_SMA,price);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- check for rates total
   if(rates_total<=DATA_LIMIT)
      return(0);// not enough bars for calculation
//--- not all data may be calculated
   int calculated=BarsCalculated(ExtFastSMAHandle);
   if(calculated<rates_total)
     {
      Print("Not all data of ExtFastSMAHandle is calculated (",calculated,"bars ). Error",GetLastError());
      return(0);
     }
   calculated=BarsCalculated(ExtSlowSMAHandle);
   if(calculated<rates_total)
     {
      Print("Not all data of ExtSlowSMAHandle is calculated (",calculated,"bars ). Error",GetLastError());
      return(0);
     }
//--- we can copy not all data
   int to_copy;
   if(prev_calculated>rates_total || prev_calculated<0)
      to_copy=rates_total;
   else
     {
      to_copy=rates_total-prev_calculated;
      if(prev_calculated>0)
         to_copy++;
     }
//--- get FastSMA buffer
   if(IsStopped())
      return(0); //Checking for stop flag
   if(CopyBuffer(ExtFastSMAHandle,0,0,to_copy,ExtFastBuffer)<=0)
     {
      Print("Getting fast SMA is failed! Error",GetLastError());
      return(0);
     }
//--- get MiddleSMA buffer
   if(IsStopped())
      return(0); //Checking for stop flag
   if(CopyBuffer(ExtMiddleSMAHandle,0,0,to_copy,ExtMiddleBuffer)<=0)
     {
      Print("Getting middle SMA is failed! Error",GetLastError());
      return(0);
     }
//--- get SlowSMA buffer
   if(IsStopped())
      return(0); //Checking for stop flag
   if(CopyBuffer(ExtSlowSMAHandle,0,0,to_copy,ExtSlowBuffer)<=0)
     {
      Print("Getting slow SMA is failed! Error",GetLastError());
      return(0);
     }

//--- first calculation or number of bars was changed
   int i,limit;
   if(prev_calculated<=DATA_LIMIT)
     {
      for(i=0; i<DATA_LIMIT; i++)
         ExtUOBuffer[i]=0.0;
      limit=DATA_LIMIT;
     }
   else
      limit=prev_calculated-1;

//--- main loop of calculations
   for(i=limit; i<rates_total && !IsStopped(); i++)
     {

      //--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
      // Проблемная строка
      //---------------------------------

      if(ExtFastBuffer[i]>ExtFastBuffer[i-1] && ExtMiddleBuffer[i]>ExtMiddleBuffer[i-1] && (!is_slow || ExtSlowBuffer[i]>ExtSlowBuffer[i-1])) // Проблема при вызове ExtMiddleBuffer[i]
        {
         ExtUOBuffer[i]=1.0; // buy
         ExtColorBuffer[i]=0.0; // blue color
         Comment("BUY");
        }
      else
         if(ExtFastBuffer[i]<ExtFastBuffer[i-1] && ExtMiddleBuffer[i]<ExtMiddleBuffer[i-1] && (!is_slow || ExtSlowBuffer[i]<ExtSlowBuffer[i-1]))
           {
            ExtUOBuffer[i]=-1.0; // sell
            ExtColorBuffer[i]=1.0; // red color
            Comment("SELL");
           }
         else
           {
            ExtUOBuffer[i]=0.0; // empty
            ExtColorBuffer[i]=2.0; // black color
            Comment("----");
           }
       

     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+



И инициализация и использование индикатора внутри советника:

#resource "\\Indicators\\Examples\\Union_Oscillator.ex5"

double UOBuffer[];
int ExtUOHandle;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnInit()
  {
   SetIndexBuffer(0, UOBuffer, INDICATOR_CALCULATIONS);

   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);
   
   ExtUOHandle = iCustom(NULL, PERIOD_CURRENT, "::Indicators\\Examples\\Union_Oscillator.ex5",
                  PERIOD_M1, PRICE_MEDIAN, 2, 10, true, 20);

   if(ExtUOHandle == INVALID_HANDLE)
     {
      Print("Error creating MA indicator-----------------------------------------------------------------------");
      return(INIT_FAILED);
     }

   return(INIT_SUCCEEDED);
  }


//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnTick()
  {
   int startFromIndex = 0;
   int bufferSize = 1;

//---------------- Fast MA
   if(CopyBuffer(ExtUOHandle, 0, startFromIndex, bufferSize, UOBuffer) <= 0)
     {
      Print("Loading ExtUOHandle failed ", GetLastError());
     }
   Comment("ExtUOHandle: ", UOBuffer[0]);
   Print(UOBuffer[0]);
  }
//+------------------------------------------------------------------+


Количество буферов в индикаторе #property indicator_buffers 5 совпадает с реальным количеством, и главное что если кинуть его на график он работает корректно, получается проблема где-то в импорте при помощи iCustom. Но где? Все необходимые параметры кажется передаются и в правильном порядке. Возможно проблема в том что iCustom вынуждает меня давать ей таймфрейм в качестве параметра, хотя это уже параметр самого индикатора.

Помогите пожалуйста разобраться что я делаю не так.













 
Павел Раввич:

у вас копипаст баг в привязке буферов. 

SetIndexBuffer(3,ExtFastBuffer,INDICATOR_CALCULATIONS); не тот буфер
 
Andrei Trukhanovich:

у вас копипаст баг в привязке буферов. 

Спасибо огромное! Столько мучился а ошибка такая простая. 
Новый комментарий
Причина обращения: