Просьба помочь одолеть индюка

Новый комментарий
 

Всем привет! Ребята, есть индикатор, рисует стрелочки. Когда накидываешь его на график - на истории отрисовывает стрелки нормально. Когда на графике стоит, стрелки шпарит почти на каждой свече, и даже на одной свече разнонаправленные может нарисовать. 

Мне кажется, он постоянно буферы переписывает почему-то. Но не факт.

Пробовал делать каждые N-секунд его переинициализацию путем вызова init() каждые, допустим, 5 секунд. Но че-то он не хочет.

Буду признателен за любую помощь.

#property copyright ""
#property link      ""
#property strict
//---- indicator settings
#property  indicator_chart_window
#property  indicator_buffers 2
#property  indicator_color1  Blue
#property  indicator_color2  Red
//---- indicator parameters
extern int  period = 4; //period
extern int  shift  = 0; //shift - сдвиг по бару
extern int st=1;//Расстояние для стрелок
extern bool arrowAlert=true;//Алерт при стрелках
extern int update=5;//Обновление каждые СЕКУНД
//---- indicator buffers
double BufferUp[],BufferDn[];
int q=1, otstup;
datetime forAlertBuy,forAlertSell;

datetime a;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   a=TimeCurrent();
   IndicatorBuffers(2);
//---- drawing settings
   SetIndexStyle(0,DRAW_ARROW,2);
   SetIndexArrow(0,233);
   SetIndexStyle(1,DRAW_ARROW,2);
   SetIndexArrow(1,234);

   SetIndexBuffer(0,BufferUp);//стрелка синяя верх
   SetIndexBuffer(1,BufferDn);//стрелка красная вниз
//---- name for DataWindow and indicator subwindow label
   IndicatorShortName("T3MA-ALARM ("+period+")");
//---- initialization done
   if(Digits==3 || Digits==5) q=10;
   otstup=st*q;
   return(0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int deinit()
  {
   ObjectDelete("low");
   ObjectDelete("high");
   return(0);
  }
//+----------------------------------------------------------------------+
//| Moving Average of Oscillator                                         |
//+----------------------------------------------------------------------+
int start()
  {

    if(TimeCurrent()-a>=update) // это попытка переинициализации
     {
      //ChartSetSymbolPeriod(0,Symbol(),_Period);
     ChartRedraw();
     init();
         a=TimeCurrent();
     }

//---- ArraySetAsSeries --------------------------------------------------  
   double Ma[],MaOn[];
   double y0[],y1[],y2[];
   int i;
//int    i;

   ArraySetAsSeries(Ma,true);
//---- IndicatorCounted --------------------------------------------------
   int counted_bars=IndicatorCounted();

   if(counted_bars<0) return(-1);
   
   if(counted_bars>0) counted_bars--;
   int limit1=Bars-counted_bars;

   if(counted_bars==0) limit1-=1+MathMax(period,shift)+2;

   int buffer_size=ArraySize(BufferUp);
   ArrayResize(Ma,buffer_size);
   ArrayResize(MaOn,buffer_size);

   ArrayResize(y0,buffer_size+shift+2);
   ArrayResize(y1,buffer_size+shift+2);
   ArrayResize(y2,buffer_size+shift+2);

   int limit=ArraySize(Ma);
//---- EMA --------------------------------------------------------------- 
   for(i=limit1; i>=0; i--)  Ma[i]  =iMA(NULL,0,period,0,MODE_EMA,PRICE_CLOSE,i);
   for(i=limit1; i>=0; i--)  MaOn[i]=iMAOnArray(Ma,limit,period,0,MODE_EMA,i);

   for(i=limit1; i>=0; i--)
     {
      y0[i+shift]=MaOn[i+shift];
      y1[i+1+shift]=MaOn[i+1+shift];
      y2[i+2+shift]=MaOn[i+2+shift];

      if(y0[i+shift]-y1[i+1+shift]<0 && y1[i+1+shift]-y2[i+2+shift]>0)
        {
         BufferDn[i+1]=iHigh(Symbol(),0,i+1) + otstup*Point;
         if(arrowAlert && forAlertSell!=Time[1])
           {
            Alert(Symbol()," TF:",_Period," SELL T3MA-ALARM");
            forAlertSell=Time[1];
           }

        }

      if(y0[i+shift]-y1[i+1+shift]>0 && y1[i+1+shift]-y2[i+2+shift]<0)
        {
         BufferUp[i+1]=iLow(Symbol(),0,i+1) - otstup*Point;

         if(arrowAlert && forAlertBuy!=Time[1])
           {
            Alert(Symbol()," TF:",_Period," BUY T3MA-ALARM");
            forAlertBuy=Time[1];
           }

        }
      //---- Signal Trend Up || Dn ---------------------------------------------   
      if(y0[i]-y1[i+1]>0) Comment("\n SWAPLONG = ",MarketInfo(Symbol(),MODE_SWAPLONG),
         "   SWAPSHORT = ",MarketInfo(Symbol(),MODE_SWAPSHORT),"\n BUY TREND ",DoubleToStr(Close[i],Digits),"; a: ",a);

      else if(y0[i]-y1[i+1]<0) Comment("\n SWAPLONG = ",MarketInfo(Symbol(),MODE_SWAPLONG),
         "   SWAPSHORT = ",MarketInfo(Symbol(),MODE_SWAPSHORT),"\n SELL TREND ",DoubleToStr(Close[i],Digits),"; a: ",a);
     }

//---- done
   return(0);

  }
//+---------------------------------------------------------------------+
 

Потому он такой и красивый - потому что практически не применимый. Рассчитывается средняя и средняя от нее, стрелки возникают при их пересечении. Мудрить тут нечего. Если сделать по-честному, то ничего особенного.


#property copyright ""
#property link      ""
#property strict
//---- indicator settings
#property  indicator_chart_window
#property  indicator_buffers 2
#property  indicator_color1  Blue
#property  indicator_color2  Red
//---- indicator parameters
extern int  period = 4; //period
extern int  shift  = 0; //shift - сдвиг по бару

//---- indicator buffers
double BufferUp[],BufferDn[],Ma[],MaOn[];


//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init(){


   IndicatorBuffers(4);

   SetIndexBuffer(0,BufferUp);
   SetIndexStyle(0,DRAW_ARROW,2);
   SetIndexArrow(0,233);
   
   SetIndexBuffer(1,BufferDn);
   SetIndexStyle(1,DRAW_ARROW,2);
   SetIndexArrow(1,234);
   
   SetIndexBuffer(2,Ma);   
   SetIndexBuffer(3,MaOn);      


   return(0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int deinit()
  {
   ObjectDelete("low");
   ObjectDelete("high");
   return(0);
  }
//+----------------------------------------------------------------------+
//| Moving Average of Oscillator                                         |
//+----------------------------------------------------------------------+
int start()
  {

   int ic=IndicatorCounted();

   int limit=Bars-ic-1;
   
   if(ic==0){
      limit-=(2+shift);
   }

   for(int i=limit; i>=0; i--)Ma[i]=iMA(NULL,0,period,0,MODE_EMA,PRICE_CLOSE,i);
   for(int i=limit; i>=0; i--)MaOn[i]=iMAOnArray(Ma,limit,period,0,MODE_EMA,i);

   for(int i=limit; i>=0; i--){
      
      double y0=MaOn[i+shift];
      double y1=MaOn[i+1+shift];
      double y2=MaOn[i+2+shift];

      if(y0-y1<0 && y1-y2>0){
         BufferDn[i]=iHigh(Symbol(),0,i);
      }

      if(y0-y1>0 && y1-y2<0){
         BufferUp[i]=iLow(Symbol(),0,i);
      }
   }

//---- done
   return(0);

  }
//+---------------------------------------------------------------------+
 
Спасибо, очень помогли! Попробуем применить, понадеемся на Русский Авось!
Новый комментарий
Причина обращения: