мол4 - страница 2

[[Удален]]

Я себе когда-то такой собрал из функций Кима.

//+----------------------------------------------------------------------------+
//|                                                      CloseAllPositions.mq4 |
//|                                                       Copyright © 2008, "" |
//|  Версия   : 27.10.2008                                                     |
//|  Описание : Скрипт закрытия позиций по рыночной цене, с возможностью       |
//|             выбора параметров закрываемых позиций                          |
//+----------------------------------------------------------------------------+
#property copyright "Copyright © 2008, "
#property link      ""
#property show_inputs
//------- Внешние параметры скрипта -------------------------------------------+
extern string _P_Trade       = "---------- Параметры торговли";
extern string  sy            = ""; //наименование инструмента
                                   //(""   - любой символ,NULL - текущий символ)
extern int     op            = -1; //операция     (-1   - любая позиция)
extern int     mn            = -1; //MagicNumber  (-1   - любой магик)
extern string _P_Performance = "---------- Параметры исполнения";
extern bool    UseSound      = False;          // Исп. звуковой сигнал
extern string  SoundSuccess  = "ok.wav";       // Звук успеха
extern string  SoundError    = "timeout.wav";  // Звук ошибки
extern int     Slippage      = 3;              // Проскальзывание цены
extern int     NumberOfTry   = 5;              // Количество попыток
//------- Глобальные переменные скрипта ---------------------------------------+
color clCloseBuy  = Blue;      // Цвет значка закрытия покупки
color clCloseSell = Red;       // Цвет значка закрытия продажи
color clDelete    = Yellow;    // Цвет значка удаления ордера
//------- Подключение внешних модулей -----------------------------------------+
#include <stdlib.mqh>          // Стандартная библиотека МТ4

//+----------------------------------------------------------------------------+
//| script program start function                                              |
//+----------------------------------------------------------------------------+
void start() {
  int i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=k-1; i>=0; i--) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (mn<0 || OrderMagicNumber()==mn) ClosePosBySelect();
        }
      }
    }
  }
}
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия  : 19.02.2008                                                      |
//|  Описание: Закрытие одной предварительно выбранной позиции                 |
//+----------------------------------------------------------------------------+
void ClosePosBySelect() {
  bool   fc;
  color  clClose;
  double ll, pa, pb, pp;
  int    err, it;

  if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
    for (it=1; it<=NumberOfTry; it++) {
      if (!IsTesting() && (!IsExpertEnabled() || IsStopped())) break;
      while (!IsTradeAllowed()) Sleep(5000);
      RefreshRates();
      pa=MarketInfo(OrderSymbol(), MODE_ASK);
      pb=MarketInfo(OrderSymbol(), MODE_BID);
      if (OrderType()==OP_BUY) {
        pp=pb; clClose=clCloseBuy;
      } else {
        pp=pa; clClose=clCloseSell;
      }
      ll=OrderLots();
      fc=OrderClose(OrderTicket(), ll, pp, Slippage, clClose);
      if (fc) {
        if (UseSound) PlaySound(SoundSuccess); break;
      } else {
        err=GetLastError();
        if (UseSound) PlaySound(SoundError);
        if (err==146) while (IsTradeContextBusy()) Sleep(1000*11);
        Print("Error(",err,") Close ",GetNameOP(OrderType())," ",
              ErrorDescription(err),", try ",it);
        Print(OrderTicket(),"  Ask=",pa,"  Bid=",pb,"  pp=",pp);
        Print("sy=",OrderSymbol(),"  ll=",ll,"  sl=",OrderStopLoss(),
              "  tp=",OrderTakeProfit(),"  mn=",OrderMagicNumber());
        Sleep(1000*5);
      }
    }
  } else Print("Некорректная торговая операция. Close ",GetNameOP(OrderType()));
}
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 01.09.2005                                                     |
//|  Описание : Возвращает наименование торговой операции                      |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    op - идентификатор торговой операции                                    |
//+----------------------------------------------------------------------------+
string GetNameOP(int op) {
  switch (op) {
    case OP_BUY      : return("Buy");
    case OP_SELL     : return("Sell");
    case OP_BUYLIMIT : return("BuyLimit");
    case OP_SELLLIMIT: return("SellLimit");
    case OP_BUYSTOP  : return("BuyStop");
    case OP_SELLSTOP : return("SellStop");
    default          : return("Unknown Operation");
  }
}
//+----------------------------------------------------------------------------+