Ошибка при обращении к индикатору из советника

Новый комментарий
 

Здравствуйте!

Столкнулся со следующей проблемой.

Советник должен определять тренд по индикатору - Heiken_Ashi_short_alert

При обращении к индикаторным буферам из советника на каждом тике в журнале пишется следующее сообщение:

14:25:06 Heiken_Ashi_short_alert GBPUSD,M1: loaded successfully
14:25:06 Heiken_Ashi_short_alert GBPUSD,M1: initialized

Затем, через миуту работы начинают непрерывно появляться сообщения:

14:25:53 Custom indicator Heiken_Ashi_short_alert GBPUSD,M1: loaded successfully
14:25:53 Memory handler: cannot allocate 6439760 bytes of memory

Т.е. не хватает памяти. Это связано скорее всего с тем, что значения индикаторных буферов вычисляются с помощью iMAOnArray

Подскажите, пожалуйста, как решить эту проблему. И как правильно вставить этот индикатор в тело советника для повышения скорости работы.

Индикатор:

//+------------------------------------------------------------------+
//|                                         Heiken Ashi Smoothed.mq4 |
//+------------------------------------------------------------------+
//|                                                      mod by Raff |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2006, Forex-TSD.com "
#property link      "https://www.forex-tsd.com/"
#property link      "Alerts added by cja"
#property link      "Modified by PipeTrader"

#property indicator_chart_window
#property indicator_buffers 4
#property indicator_color1 Red
#property indicator_color2 ForestGreen
#property indicator_color3 Red
#property indicator_color4 ForestGreen
#property indicator_width1 1
#property indicator_width2 1
#property indicator_width3 3
#property indicator_width4 3
extern string wave="gbpjpy.wav";
//---- parameters
extern int MaMetod  = 2;
extern int MaPeriod = 6;
extern int MaMetod2  = 3;
extern int MaPeriod2 = 2;

extern bool POP_UP_Box_Alert = false;
extern bool Sound_Alert = true;
//---- buffers
double ExtMapBuffer1[];
double ExtMapBuffer2[];
double ExtMapBuffer3[];
double ExtMapBuffer4[];
double ExtMapBuffer5[];
double ExtMapBuffer6[];
double ExtMapBuffer7[];
double ExtMapBuffer8[];
//----
int ExtCountedBars=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//|------------------------------------------------------------------|
int init()
  {
//---- indicators
   IndicatorBuffers(8);

   SetIndexStyle(0,DRAW_HISTOGRAM, 0);
   SetIndexBuffer(0, ExtMapBuffer1);
   SetIndexStyle(1,DRAW_HISTOGRAM, 0);
   SetIndexBuffer(1, ExtMapBuffer2);
   SetIndexStyle(2,DRAW_HISTOGRAM, 0);
   SetIndexBuffer(2, ExtMapBuffer3);
   SetIndexStyle(3,DRAW_HISTOGRAM, 0);
   SetIndexBuffer(3, ExtMapBuffer4);
//----
   SetIndexDrawBegin(0,5);
//---- indicator buffers mapping
   SetIndexBuffer(0,ExtMapBuffer1);
   SetIndexBuffer(1,ExtMapBuffer2);
   SetIndexBuffer(2,ExtMapBuffer3);
   SetIndexBuffer(3,ExtMapBuffer4);
   SetIndexBuffer(4,ExtMapBuffer5);
   SetIndexBuffer(5,ExtMapBuffer6);
   SetIndexBuffer(6,ExtMapBuffer7);
   SetIndexBuffer(7,ExtMapBuffer8);
//---- initialization done
   return(0);
  }
//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//---- TODO: add your code here
  return(0);
  }  
bool Crossed (double haOpen , double haClose )
{

static string last_direction = "";
string current_direction = "";

if(haOpen<=haClose) current_direction = "LONG";
if(haOpen>haClose) current_direction = "SHORT";



if(current_direction != last_direction) 
{
      if(POP_UP_Box_Alert==true)Alert ("H/Ashi Direction change "+current_direction+"  " ,Symbol()," ",Period()," @ ",Bid);
      if(Sound_Alert==true)  PlaySound(wave);
      last_direction = current_direction;
      return (true);
}
else
{
      return (false);

}

  
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   double maOpen, maClose, maLow, maHigh;
   double haOpen, haHigh, haLow, haClose;
   if(Bars<=10) return(0);
   ExtCountedBars=IndicatorCounted();
//---- check for possible errors
   if (ExtCountedBars<0) return(-1);
//---- last counted bar will be recounted
   if (ExtCountedBars>0) ExtCountedBars--;
   int pos=Bars-ExtCountedBars-1;
   while(pos>=0)
     {
      maOpen=iMA(NULL,0,MaPeriod,0,MaMetod,MODE_OPEN,pos);
      maClose=iMA(NULL,0,MaPeriod,0,MaMetod,MODE_CLOSE,pos);
      maLow=iMA(NULL,0,MaPeriod,0,MaMetod,MODE_LOW,pos);
      maHigh=iMA(NULL,0,MaPeriod,0,MaMetod,MODE_HIGH,pos);

      haOpen=(ExtMapBuffer5[pos+1]+ExtMapBuffer6[pos+1])/2;
      haClose=(maOpen+maHigh+maLow+maClose)/4;
      haHigh=MathMax(maHigh, MathMax(haOpen, haClose));
      haLow=MathMin(maLow, MathMin(haOpen, haClose));

      if (haOpen<haClose) 
        {
         ExtMapBuffer7[pos]=haLow;
         ExtMapBuffer8[pos]=haHigh;
        } 
      else
        {
         ExtMapBuffer7[pos]=haHigh;
         ExtMapBuffer8[pos]=haLow;
        } 
      ExtMapBuffer5[pos]=haOpen;
      ExtMapBuffer6[pos]=haClose;

   pos--;
     }

   int i;
   for(i=0; i<Bars; i++) ExtMapBuffer1[i]=iMAOnArray(ExtMapBuffer7,Bars,MaPeriod2,0,MaMetod2,i);
   for(i=0; i<Bars; i++) ExtMapBuffer2[i]=iMAOnArray(ExtMapBuffer8,Bars,MaPeriod2,0,MaMetod2,i);
   for(i=0; i<Bars; i++) ExtMapBuffer3[i]=iMAOnArray(ExtMapBuffer5,Bars,MaPeriod2,0,MaMetod2,i);
   for(i=0; i<Bars; i++) ExtMapBuffer4[i]=iMAOnArray(ExtMapBuffer6,Bars,MaPeriod2,0,MaMetod2,i);
   
  

     Print(Crossed (ExtMapBuffer1[0],ExtMapBuffer2[0]));
//----
   return(0);
  }
//+------------------------------------------------------------------+
Файлы:
heiken_ashi_short_alert.mq4  6 kb
 
Analitik писал(а) >>

При обращении к индикаторным буферам из советника на каждом тике в журнале пишется следующее сообщение:

14:25:06 Heiken_Ashi_short_alert GBPUSD,M1: loaded successfully
14:25:06 Heiken_Ashi_short_alert GBPUSD,M1: initialized

Индикатор не должен загружаться и инициализироваться на каждом тике. Проверте корретность вызова индикатора из своего советника.
 
PapaYozh писал(а) >>
Индикатор не должен загружаться и инициализироваться на каждом тике. Проверте корретность вызова индикатора из своего советника.

При этом все входные параметры должны быть указаны явно.

Для описанных параметров:

extern string wave="gbpjpy.wav";
//---- parameters
extern int MaMetod  = 2;
extern int MaPeriod = 6;
extern int MaMetod2  = 3;
extern int MaPeriod2 = 2;

extern bool POP_UP_Box_Alert = false;
extern bool Sound_Alert = true;

должен быть такой код вызова

iCustom(NULL,0,"Heiken_Ashi_short_alert","gbpjpy.wav",2,6,3,2,false,true,0,0);
 
stringo писал(а) >>

При этом все входные параметры должны быть указаны явно.

Для описанных параметров:

должен быть такой код вызова

Забыл указать последнее "true" в вызове :-) Надо чаще отдыхать:-) Спасибо, всё работает!

Новый комментарий
Причина обращения: