Я что-то пропустил?

[---]

Скачал "для посмотреть" тетрис...

Я был НУ ОЧЕНЬ УДИВЛЁН!!!!! Сначала тем, что файл имел расширение *.mq5. А потом кода заглянул в код, так вообще! там же  классы, указатели и вау!!!

вот кусочек кода:

//+------------------------------------------------------------------+
//| Объект - стакан                                                  |
//+------------------------------------------------------------------+
class CTetrisField
  {
private:
   int               m_score;                            // счёт
   int               m_ypos;                             // текущее положение фигуры по вертикали в пикселах
   int               m_field[FIELD_HEIGHT][FIELD_WIDTH]; // матрица стакана
   int               m_rows[FIELD_HEIGHT];               // нумерация рядов стакана для именования брошенных блоков
   int               m_last_row;                         // последний свободный номер ряда
   CTetrisShape     *m_shape;                            // тетрисная фигура
   bool              m_bover;                            // игра закончена
public:
   void              CTetrisField() { m_shape=NULL; m_bover=false; }
   void              Init();
   void              Deinit();
   void              Down();
   void              Left();
   void              Right();
   void              Rotate();
   void              Drop();
private:
   void              NewShape();
   void              CheckAndDeleteRows();
   void              LabelOver();
  };
//+------------------------------------------------------------------+
//| Наряду с конструктором используется функция инициализации        |
//+------------------------------------------------------------------+
void CTetrisField::Init()
  {
   int i;
//--- стартуем рандомайзер от последнего известного ыремени сервера
   srand((uint)TimeCurrent());
//--- инициализируем массивы
   ArrayInitialize(m_field,0);
   for(i=0; i<FIELD_HEIGHT; i++)
      m_rows[i]=FIELD_HEIGHT-i-1;
   m_last_row=FIELD_HEIGHT;
//--- создаём объект стакана
   ObjectCreate(0,BACKGROUND_NAME,OBJ_BITMAP_LABEL,0,0,0,0,0);
   ObjectSetInteger(0,BACKGROUND_NAME,OBJPROP_XDISTANCE,2);
   ObjectSetInteger(0,BACKGROUND_NAME,OBJPROP_YDISTANCE,2);
   ObjectSetInteger(0,BACKGROUND_NAME,OBJPROP_BACK,true);
   ObjectSetString(0,BACKGROUND_NAME,OBJPROP_BMPFILE,"Tetris\\background.bmp");
//--- и объекты фигур
   for(i=0; i<4; i++)
     {
      string name=SHAPE_NAME+(string)i;
      ObjectCreate(0,name,OBJ_BITMAP_LABEL,0,0,0,0,0);
      ObjectSetInteger(0,name,OBJPROP_BACK,false);
      ObjectSetString(0,name,OBJPROP_BMPFILE,"Tetris\\blue_block.bmp");
     }
//--- создаём текстовую метку для вывода очков
   m_score=0;
//--- тень синего цвета
   ObjectCreate(0,SCORE_NAME+"1",OBJ_LABEL,0,0,0,0,0);
   ObjectSetInteger(0,SCORE_NAME+"1",OBJPROP_XDISTANCE,WIDTH_IN_PIXELS/2+VERT_BORDER+3);
   ObjectSetInteger(0,SCORE_NAME+"1",OBJPROP_YDISTANCE,HEIGHT_IN_PIXELS+24+HORZ_BORDER+3);
   ObjectSetInteger(0,SCORE_NAME+"1",OBJPROP_BACK,false);
   ObjectSetInteger(0,SCORE_NAME+"1",OBJPROP_COLOR,Blue);
   ObjectSetString(0, SCORE_NAME+"1",OBJPROP_FONT,"Arial");
   ObjectSetInteger(0,SCORE_NAME+"1",OBJPROP_FONTSIZE,24);
   ObjectSetInteger(0,SCORE_NAME+"1",OBJPROP_ANCHOR,ANCHOR_TOP);
   ObjectSetDouble(0,SCORE_NAME+"1",OBJPROP_ANGLE,0.0);
   ObjectSetString(0,SCORE_NAME+"1",OBJPROP_TEXT,"0");
//--- надпись жёлтого цвета
   ObjectCreate(0,SCORE_NAME,OBJ_LABEL,0,0,0,0,0);
   ObjectSetInteger(0,SCORE_NAME,OBJPROP_XDISTANCE,WIDTH_IN_PIXELS/2+VERT_BORDER);
   ObjectSetInteger(0,SCORE_NAME,OBJPROP_YDISTANCE,HEIGHT_IN_PIXELS+24+HORZ_BORDER);
   ObjectSetInteger(0,SCORE_NAME,OBJPROP_BACK,false);
   ObjectSetInteger(0,SCORE_NAME,OBJPROP_COLOR,Yellow);
   ObjectSetString(0, SCORE_NAME,OBJPROP_FONT,"Arial");
   ObjectSetInteger(0,SCORE_NAME,OBJPROP_FONTSIZE,24);
   ObjectSetInteger(0,SCORE_NAME,OBJPROP_ANCHOR,ANCHOR_TOP);
   ObjectSetDouble(0,SCORE_NAME,OBJPROP_ANGLE,0.0);
   ObjectSetString(0,SCORE_NAME,OBJPROP_TEXT,"0");
//--- генерируем первую фигуру
   NewShape();
  }

но мой последний 222 билд так и не смог это счастье скомпилировать...

Уважаемый Settler подЕлитесь компилятором?

я тоже хочу посчупать пятёрку.