Попробуйте найти код как в эксперте прицепить МА к ССI или Stoch - MQL4 и MetaTrader 4

Igor Kim 2008.05.09 18:27 #161

Сама функция:

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 10.05.2008                                                     |
//|  Описание : Возвращает корреляцию двух рядов.                              |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    x - массив значений первого ряда                                        |
//|    y - массив значений второго ряда                                        |
//+----------------------------------------------------------------------------+
double Correlation(double& x[], double& y[]) {
  double co=0, sa=0, sb=0, sc=0, xs=0, ys=0;
  int    i, k=MathMin(ArraySize(x), ArraySize(y));

  if (k>0) {
    for (i=0; i<k; i++) {
      xs+=x[i]; ys+=y[i];
    }
    xs/=k; ys/=k;
    for (i=0; i<k; i++) {
      sa+=(x[i]-xs)*(y[i]-ys);
      sb+=(x[i]-xs)*(x[i]-xs);
      sc+=(y[i]-ys)*(y[i]-ys);
    }
    sb=MathSqrt(sb*sc);
    if (sb!=0) co=sa/sb;
  }
  return(co);
}

ЗЫ. В прицепе скрипт для тестирование функции Correlation().

Файлы:

test_correlation.mq4 3 kb

Igor Kim 2008.05.10 09:14 #162

Функция GetIndexLastPos().

Эта функция возвращает индекс последней открытой позиции или -1. Более точный отбор проверяемых позиций задаётся внешними параметрами:

sy - Наименование рыночного инструмента. Если задать этот параметр, то функция учтёт позиции только заданного инструмента. Значение по умолчанию - "" означает любой рыночный инструмент. NULL означает текущий инструмент.
op - Торговая операция, тип позиции. Допустимые значения: OP_BUY, OP_SELL или -1. Значение по умолчанию -1 означает любую позицию.
mn - Идентификатор позиции, MagicNumber. Значение по умолчанию -1 означает любой идентификатор.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает индекс последней открытой позиции или -1            |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int GetIndexLastPos(string sy="", int op=-1, int mn=-1) {
  datetime o;
  int      i, k=OrdersTotal(), r=-1;

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (o<OrderOpenTime()) {
                o=OrderOpenTime();
                r=i;
              }
            }
          }
        }
      }
    }
  }
  return(r);
}

ЗЫ. В аттаче скрипт для тестирования функции GetIndexLastPos().

Файлы:

test_getindexlastpos.mq4 4 kb

Только "Полезные функции от Запрет на открытие ордеров Как написать код, что

Igor Kim 2008.05.10 09:22 #163

Функция GetLotLastPos().

Эта функция возвращает размер лота последней открытой позиции или -1. Более точный отбор проверяемых позиций задаётся внешними параметрами:

sy - Наименование рыночного инструмента. Если задать этот параметр, то функция учтёт позиции только заданного инструмента. Значение по умолчанию - "" означает любой рыночный инструмент. NULL означает текущий инструмент.
op - Торговая операция, тип позиции. Допустимые значения: OP_BUY, OP_SELL или -1. Значение по умолчанию -1 означает любую позицию.
mn - Идентификатор позиции, MagicNumber. Значение по умолчанию -1 означает любой идентификатор.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает размер лота последней открытой позиции или -1       |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double GetLotLastPos(string sy="", int op=-1, int mn=-1) {
  datetime o;
  double   l=-1;
  int      i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (o<OrderOpenTime()) {
                o=OrderOpenTime();
                l=OrderLots();
              }
            }
          }
        }
      }
    }
  }
  return(l);
}

ЗЫ. Во вложении скрипт для тестирования функции GetLotLastPos().

Файлы:

test_getlotlastpos.mq4 4 kb

Только "Полезные функции от Любые вопросы новичков по Как написать код, что

Rid 2008.05.10 14:41 #164

KimIV:

Функция GetIndexLastPos().

Эта функция возвращает индекс последней открытой позиции или -1. Более точный отбор проверяемых позиций задаётся внешними параметрами:

ЗЫ. В аттаче скрипт для тестирования функции GetIndexLastPos().

А индекс, это что ? Это номер бара последней открытой позиции ? Или что-то другое?

Igor Kim 2008.05.10 17:53 #165

rid писал (а):
А индекс, это что ? Это номер бара последней открытой позиции ? Или что-то другое?

Это порядковый номер позиции в списке открытых позиций и установленных ордеров. Нумерация начинается с нуля и является единой для позиций и ордеров.

gyl 2008.05.10 18:49 #166

Уважаемый, Игорь! Помогите пожалуйста. Проблема в том, что я немогу нигде найти код как в эксперте прицепить МА к ССI или Stoch. Причем сигнал на покупку или продажу должен быть при пересечении этой МА с уровнем CCI, например +100/-100.

Может быть уже есть какой-нибудь советник, где используется код, который мне нужен?

Крест! Советник на пересечении Universal MA Cross EA

Igor Kim 2008.05.11 06:55 #167

Функция GetMaxLotFromOpenPos().

Эта функция возвращает максимальный размер лота из числа открытых позиций. Более точный отбор проверяемых позиций задаётся внешними параметрами:

sy - Наименование рыночного инструмента. Если задать этот параметр, то функция учтёт позиции только заданного инструмента. Значение по умолчанию - "" означает любой рыночный инструмент. NULL означает текущий инструмент.
op - Торговая операция, тип позиции. Допустимые значения: OP_BUY, OP_SELL или -1. Значение по умолчанию -1 означает любую позицию.
mn - Идентификатор позиции, MagicNumber. Значение по умолчанию -1 означает любой идентификатор.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает максимальный размер лота из открытых позиций        |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double GetMaxLotFromOpenPos(string sy="", int op=-1, int mn=-1) {
  double l=0;
  int    i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (l<OrderLots()) l=OrderLots();
            }
          }
        }
      }
    }
  }
  return(l);
}

ЗЫ. В прицепе скрипт для тестирования функции GetMaxLotFromOpenPos().

Файлы:

test_getmaxlotfromopenpos.mq4 4 kb

Только "Полезные функции от Любые вопросы новичков по Запрет на открытие ордеров

Igor Kim 2008.05.11 06:59 #168

Функция GetMinLotFromOpenPos().

Эта функция возвращает минимальный размер лота из числа открытых позиций. Более точный отбор проверяемых позиций задаётся внешними параметрами:

sy - Наименование рыночного инструмента. Если задать этот параметр, то функция учтёт позиции только заданного инструмента. Значение по умолчанию - "" означает любой рыночный инструмент. NULL означает текущий инструмент.
op - Торговая операция, тип позиции. Допустимые значения: OP_BUY, OP_SELL или -1. Значение по умолчанию -1 означает любую позицию.
mn - Идентификатор позиции, MagicNumber. Значение по умолчанию -1 означает любой идентификатор.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает минимальный размер лота из открытых позиций         |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double GetMinLotFromOpenPos(string sy="", int op=-1, int mn=-1) {
  double l=0;
  int    i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (l==0 || l>OrderLots()) l=OrderLots();
            }
          }
        }
      }
    }
  }
  return(l);
}

ЗЫ. Во вложении скрипт для тестирования функции GetMinLotFromOpenPos().

Файлы:

test_getminlotfromopenpos.mq4 4 kb

Только "Полезные функции от Любые вопросы новичков по Запрет на открытие ордеров

Rid 2008.05.11 07:14 #169

GYL:

Уважаемый, Игорь! Помогите пожалуйста. Проблема в том, что я немогу нигде найти код как в эксперте прицепить МА к ССI или Stoch. Причем сигнал на покупку или продажу должен быть при пересечении этой МА с уровнем CCI, например +100/-100.

Может быть уже есть какой-нибудь советник, где используется код, который мне нужен?

Вопрос явно не в тему. Чтобы не отвлекать Игоря по пустякам привожу пример такого кусочка кода.НА примере стохастика и

double Stochastic_array[50];int j=0; while (j<50) {
Stochastic_array[j]= iStochastic(NULL, 0, Stochastic_period, 3,3,
                                     MODE_SMA,0,MODE_MAIN, j); j++; }
ArraySetAsSeries(Stochastic_array,true);
double MA_0 =iMAOnArray(Stochastic_array,0,MA_period,1,MODE_SMA,0) ;
double Stochastic_0=iStochastic(NULL,0,Stochastic_period,3,3,MODE_SMA,0,MODE_MAIN, 0);
double Stochastic_1=iStochastic(NULL,0,Stochastic_period,3,3,MODE_SMA,0,MODE_MAIN, 1);

МА. Пост. буду держать ровно сутки - потом удалю!

gyl 2008.05.11 08:27 #170

rid:

Вопрос явно не в тему. Чтобы не отвлекать Игоря по пустякам привожу пример такого кусочка кода.НА примере стохастика и

МА. Пост. буду держать ровно сутки - потом удалю!

Спасибо большое, Вы мне очень помогли.

Полезные функции от KimIV - страница 17

Функция GetIndexLastPos().

Функция GetLotLastPos().

Функция GetIndexLastPos().

Функция GetMaxLotFromOpenPos().

Функция GetMinLotFromOpenPos().