Простейший код простейшего эксперта

[Удален] 2006.09.03 21:46

Знаю, что аналогичный вопрос много раз задавался. Но тем не менее…

Эксперт очень простой: не закрывает позиции вообще, а открывает их по параболику.

Нулевой бар не используется. Работает он совершенно не так как ведет себя параболик на графике.

bool Buy = true;
bool Sell = true;
 
int start()
  {
   double Par = iCustom(NULL,0,"Parabolic",0.02,0.2,0,1);
   double C = Close[1];
   
   if(C>Par && Buy)
     {
      OrderSend(Symbol(),OP_BUY,0.1,Ask,3,0,0,NULL,0,0,Blue);
      Buy = false;
      Sell = true;
      return(0);
     }
    
   if(C<Par && Sell)
     {
      OrderSend(Symbol(),OP_SELL,0.1,Bid,3,0,0,NULL,0,0,Red);
      Buy  = true;
      Sell = false;
      return(0);
     }
      
  return(0);
  }

Результаты потикового тестирования эксперта на EURGPB H1 с 22.08.2006 по 03.09.2006

Результаты потикового тестирования эксперта на EURGPB H1 с 23.08.2006 по 03.09.2006

Dmitry Fedoseev 2006.09.04 00:13 #1

А если так?

double Par = iSAR(NULL,0,0.02,0.2,1);

[Удален] 2006.09.04 08:20 #2

Integer писал (а):
А если так?

double Par = iSAR(NULL,0,0.02,0.2,1);

Если так, то отлично работает. В этом собственно и вопрос. Почему?
Мне же нужно использовать именно iCustom, так как пользовательский параболик я хочу
модифицировать.

Dmitry Fedoseev 2006.09.04 14:43 #3

Если собираешься модифицировать, то и ошибку в нем поищи

Vitali 2006.09.04 17:45 #4

tyanin_arseniy писал (а):

Integer писал (а):
А если так?

double Par = iSAR(NULL,0,0.02,0.2,1);

Потому что iCustom и iSAR выдают различные значения. Неодинаковые. Проверьте.

[Удален] 2006.09.04 22:26 #5

Vita писал (а):

tyanin_arseniy писал (а):

Integer писал (а):
А если так?

double Par = iSAR(NULL,0,0.02,0.2,1);

Потому что iCustom и iSAR выдают различные значения. Неодинаковые. Проверьте.

Тем неменее в логике эксперта ошибки нет, и он должен срабатывать по пользовательскому параболику, чего на графике не наблюдается.

Dmitry Fedoseev 2006.09.04 22:30 #6

Ошибка в этом пользовательском параболике. Прикрипи его на график и посмотри что с ним произойдет на следующем баре.

[Удален] 2006.09.05 08:11 #7

Integer писал (а):
Ошибка в этом пользовательском параболике. Прикрипи его на график и посмотри что с ним произойдет на следующем баре.

После разворота индикатора его значения не меняются (визуальный режим тестирования).

[Удален] 2006.09.05 08:13 #8

Может кто нибудь дать ссылку на работающий пользовательский параболик ?

Renat Fatkhullin 2006.09.05 15:22 #9

Стандартное пожелание: прикладывайте, пожалуйста, полный код индикатора прямо в сообщение. Вы ведь хотите ответ получить по коду, которого никто не видит.

[Удален] 2006.09.05 17:37 #10

Индикатор стандартый, поставляемый с Meta Trader.

//+------------------------------------------------------------------+
//|                                                    Parabolic.mq4 |
//|                      Copyright © 2004, MetaQuotes Software Corp. |
//|                                       https://www.metaquotes.net// |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2004, MetaQuotes Software Corp."
#property link      "https://www.metaquotes.net//"
 
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_color1 Lime
//---- input parameters
extern double    Step=0.02;
extern double    Maximum=0.2;
//---- buffers
double SarBuffer[];
//----
int    save_lastreverse;
bool   save_dirlong;
double save_start;
double save_last_high;
double save_last_low;
double save_ep;
double save_sar;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- indicators
   SetIndexStyle(0,DRAW_ARROW);
   SetIndexArrow(0,159);
   SetIndexBuffer(0,SarBuffer);
//----
   return(0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void SaveLastReverse(int last,int dir,double start,double low,double high,double ep,double sar)
  {
   save_lastreverse=last;
   save_dirlong=dir;
   save_start=start;
   save_last_low=low;
   save_last_high=high;
   save_ep=ep;
   save_sar=sar;
  }
//+------------------------------------------------------------------+
//| Parabolic Sell And Reverse system                                |
//+------------------------------------------------------------------+
int start()
  {
   static bool first=true;
   bool   dirlong;
   double start,last_high,last_low;
   double ep,sar,price_low,price_high,price;
   int    i,counted_bars=IndicatorCounted();
//----
   if(Bars<3) return(0);
//---- initial settings
   i=Bars-2;
   if(counted_bars==0 || first)
     {
      first=false;
      dirlong=true;
      start=Step;
      last_high=-10000000.0;
      last_low=10000000.0;
      while(i>0)
        {
         save_lastreverse=i;
         price_low=Low[i];
         if(last_low>price_low)   last_low=price_low;
         price_high=High[i];
         if(last_high<price_high) last_high=price_high;
         if(price_high>High[i+1] && price_low>Low[i+1]) break;
         if(price_high<High[i+1] && price_low<Low[i+1]) { dirlong=false; break; }
         i--;
        }
      //---- initial zero
      int k=i;
      while(k<Bars)
        {
         SarBuffer[k]=0.0;
         k++;
        }
      //---- check further
      if(dirlong) { SarBuffer[i]=Low[i+1]; ep=High[i]; }
      else        { SarBuffer[i]=High[i+1]; ep=Low[i]; }
      i--;
     }
    else
     {
      i=save_lastreverse;
      start=save_start;
      dirlong=save_dirlong;
      last_high=save_last_high;
      last_low=save_last_low;
      ep=save_ep;
      sar=save_sar;
     }
//----
   while(i>=0)
     {
      price_low=Low[i];
      price_high=High[i];
      //--- check for reverse
      if(dirlong && price_low<SarBuffer[i+1])
        {
         SaveLastReverse(i,true,start,price_low,last_high,ep,sar);
         start=Step; dirlong=false;
         ep=price_low;  last_low=price_low;
         SarBuffer[i]=last_high;
         i--;
         continue;
        }
      if(!dirlong && price_high>SarBuffer[i+1])
        {
         SaveLastReverse(i,false,start,last_low,price_high,ep,sar);
         start=Step; dirlong=true;
         ep=price_high; last_high=price_high;
         SarBuffer[i]=last_low;
         i--;
         continue;
        }
      //---
      price=SarBuffer[i+1];
      sar=price+start*(ep-price);
      if(dirlong)
        {
         if(ep<price_high && (start+Step)<=Maximum) start+=Step;
         if(price_high<High[i+1] && i==Bars-2)  sar=SarBuffer[i+1];
 
         price=Low[i+1];
         if(sar>price) sar=price;
         price=Low[i+2];
         if(sar>price) sar=price;
         if(sar>price_low)
           {
            SaveLastReverse(i,true,start,price_low,last_high,ep,sar);
            start=Step; dirlong=false; ep=price_low;
            last_low=price_low;
            SarBuffer[i]=last_high;
            i--;
            continue;
           }
         if(ep<price_high) { last_high=price_high; ep=price_high; }
        }
      else
        {
         if(ep>price_low && (start+Step)<=Maximum) start+=Step;
         if(price_low<Low[i+1] && i==Bars-2)  sar=SarBuffer[i+1];
 
         price=High[i+1];
         if(sar<price) sar=price;
         price=High[i+2];
         if(sar<price) sar=price;
         if(sar<price_high)
           {
            SaveLastReverse(i,false,start,last_low,price_high,ep,sar);
            start=Step; dirlong=true; ep=price_high;
            last_high=price_high;
            SarBuffer[i]=last_low;
            i--;
            continue;
           }
         if(ep>price_low) { last_low=price_low; ep=price_low; }
        }
      SarBuffer[i]=sar;
      i--;
     }
//   sar=SarBuffer[0];
//   price=iSAR(NULL,0,Step,Maximum,0);
//   if(sar!=price) Print("custom=",sar,"   SAR=",price,"   counted=",counted_bars);
//   if(sar==price) Print("custom=",sar,"   SAR=",price,"   counted=",counted_bars);
//----
   return(0);
  }
//+------------------------------------------------------------------+

1 2

Новый комментарий