Librerie: Caricatore di storia

Nuovo commento
 

Caricatore di storia:

Modulo funzionale Multicurrency Expert Advisor per organizzare l'accesso a qualsiasi dato storico con l'elaborazione del risultato dell'interrogazione.

Author: Nikolay Kositsin

 
Automated-Trading:

HistoryLoader:

Autore: Nikolay Kositsin

Errore di sintassi alla riga 91 (H mancante). "SERIES_SYNCRONIZED" dovrebbe essere "SERIES_SYNCHRONIZED".
 
elib:
Errore di sintassi alla riga 91 (H mancante). "SERIES_SYNCRONIZED" dovrebbe essere "SERIES_SYNCHRONIZED".

Niente dura per sempre sotto la luna!

//+------------------------------------------------------------------+
//| controllo della cronologia per il caricamento|
//+------------------------------------------------------------------+
int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)
  {
//----+
   datetime first_date=0;
   datetime times[100];
//--- controllare il simbolo e il periodo
   if(symbol == NULL || symbol == "") symbol = Symbol();
   if(period == PERIOD_CURRENT)     period = Period();
//--- controllare se il simbolo è selezionato nel MarketWatch
   if(!SymbolInfoInteger(symbol,SYMBOL_SELECT))
     {
      if(GetLastError()==ERR_MARKET_UNKNOWN_SYMBOL) return(-1);
      if(!SymbolSelect(symbol,true)) Print(__FUNCTION__,"(): Fallita l'aggiunta del carattere ",symbol," nella finestra di MarketWatch!!!".);
     }
//--- verifica se i dati sono presenti
   SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date);
   if(first_date>0 && first_date<=start_date) return(1);
//--- non chiedere il caricamento dei propri dati se si tratta di un indicatore
   if(MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR && Period()==period && Symbol()==symbol)
      return(-4);
//--- secondo tentativo
   if(SeriesInfoInteger(symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,first_date))
     {
      //--- ci sono dati caricati per costruire le serie temporali
      if(first_date>0)
        {
         //--- forzare la costruzione di serie temporali
         CopyTime(symbol,period,first_date+PeriodSeconds(period),1,times);
         //--- data di controllo
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(2);
        }
     }
//--- barre massime nel grafico dalle opzioni del terminale
   int max_bars=TerminalInfoInteger(TERMINAL_MAXBARS);
//--- caricare le informazioni sulla cronologia dei simboli
   datetime first_server_date=0;
   while(!SeriesInfoInteger(symbol,PERIOD_M1,SERIES_SERVER_FIRSTDATE,first_server_date) && !IsStopped())
      Sleep(5);
//--- fissare la data di inizio del caricamento
   if(first_server_date>start_date) start_date=first_server_date;
   if(first_date>0 && first_date<first_server_date)
      Print(__FUNCTION__,"(): Warning: first server date ",first_server_date," for ",symbol,
            " does not match to first series date ",first_date);
//-- caricare i dati passo dopo passo
   int fail_cnt=0;
   while(!IsStopped())
     {
      //--- attendere la creazione della serie temporale
      while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
         Sleep(5);
      //--- chiedere le barre costruite
      int bars=Bars(symbol,period);
      if(bars>0)
        {
         if(bars>=max_bars) return(-2);
         //--- chiedere il primo appuntamento
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(0);
        }
      //--- la copia della parte successiva forza il caricamento dei dati
      int copied=CopyTime(symbol,period,bars,100,times);
      if(copied>0)
        {
         //--- controllo dei dati
         if(times[0]<=start_date) return(0);
         if(bars+copied>=max_bars) return(-2);
         fail_cnt=0;
        }
      else
        {
         //--- non più di 100 tentativi falliti
         fail_cnt++;
         if(fail_cnt>=100) return(-5);
         Sleep(10);
        }
     }
//----+arresto
   return(-3);
  }
//+------------------------------------------------------------------+
 

Non funziona, muore al primo carattere....

Ecco il codice

//+------------------------------------------------------------------+ 
//|TestLoadHistory.mq5 | 
//| Copyright 2009, MetaQuotes Software Corp. | | 
//| https://www.mql5.com 
//+------------------------------------------------------------------+ 
#property copyright "2009, MetaQuotes Software Corp." 
#property link      "https://www.mql5.com" 
#property version   "1.02" 
#property script_show_inputs 

//--- parametri di ingresso 

//+------------------------------------------------------------------+ 
//| Funzione di avvio del programma di script| 
//+------------------------------------------------------------------+ 
void OnStart()
  {


   int      all_symbols=SymbolsTotal(false);   string  sym_name="";
   Print("Load symbols ",all_symbols);

   for(int k=0;k<all_symbols;k++)
      if((sym_name=SymbolName(k,false))!="")
        {
         SymbolSelect(sym_name,true);

         Print(k," Symbol name ",sym_name);

datetime time= (TimeCurrent()-60*60*24*5);


         int res=CheckLoadHistory(sym_name,PERIOD_M1,time);

         switch(res)
           {
            case -1 : Print("Unknown symbol ",sym_name);             break;
            case -2 : Print("Requested bars more than max bars in chart ",sym_name); break;
            case -3 : Print("Program was stopped ",sym_name);                        break;
            case -4 : Print("Indicator shouldn't load its own data ",sym_name);      break;
            case -5 : Print("Load failed ",sym_name);                                break;
            case  0 : Print("Loaded OK ",sym_name);                                  break;
            case  1 : Print("Loaded previously ",sym_name);                          break;
            case  2 : Print("Loaded previously and built ",sym_name);                break;
            default : Print("Unknown result ",sym_name);
           }

         datetime first_date;
         SeriesInfoInteger(sym_name,PERIOD_M1,SERIES_FIRSTDATE,first_date);
         int bars=Bars(sym_name,PERIOD_M1);
         Print("First date ",first_date," - ",bars," bars");
       }
//--- 

//--- 
  }
//+------------------------------------------------------------------+
//| controllo della cronologia per il caricamento|
//+------------------------------------------------------------------+
int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)
  {
//----+
   datetime first_date=0;
   datetime times[100];
//--- controllo del simbolo e del periodo
   if(symbol == NULL || symbol == "") symbol = Symbol();
   if(period == PERIOD_CURRENT)     period = Period();
//--- controllare se il simbolo è selezionato nel MarketWatch
   if(!SymbolInfoInteger(symbol,SYMBOL_SELECT))
     {
      if(GetLastError()==ERR_MARKET_UNKNOWN_SYMBOL) return(-1);
      if(!SymbolSelect(symbol,true)) Print(__FUNCTION__,"(): Fallita l'aggiunta del carattere ",symbol," nella finestra di MarketWatch!!!".);
     }
//--- verifica se i dati sono presenti
   SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date);
   if(first_date>0 && first_date<=start_date) return(1);
//--- non chiedere il caricamento dei propri dati se si tratta di un indicatore
   if(MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR && Period()==period && Symbol()==symbol)
      return(-4);
//--- secondo tentativo
   if(SeriesInfoInteger(symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,first_date))
     {
      //--- ci sono dati caricati per costruire le serie temporali
      if(first_date>0)
        {
         //--- forzare la creazione di serie temporali
         CopyTime(symbol,period,first_date+PeriodSeconds(period),1,times);
         //--- data di controllo
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(2);
        }
     }
//--- barre massime nel grafico dalle opzioni del terminale
   int max_bars=TerminalInfoInteger(TERMINAL_MAXBARS);
//--- caricare le informazioni sulla cronologia dei simboli
   datetime first_server_date=0;
   while(!SeriesInfoInteger(symbol,PERIOD_M1,SERIES_SERVER_FIRSTDATE,first_server_date) && !IsStopped())
      Sleep(5);
//--- fissare la data di inizio del caricamento
   if(first_server_date>start_date) start_date=first_server_date;
   if(first_date>0 && first_date<first_server_date)
      Print(__FUNCTION__,"(): Warning: first server date ",first_server_date," for ",symbol,
            " does not match to first series date ",first_date);
//-- caricare i dati passo dopo passo
   int fail_cnt=0;
   while(!IsStopped())
     {
      //--- attendere la creazione della serie temporale
      while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
         Sleep(5);
      //--- chiedere le barre costruite
      int bars=Bars(symbol,period);
      if(bars>0)
        {
         if(bars>=max_bars) return(-2);
         //--- chiedere il primo appuntamento
         if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))
            if(first_date>0 && first_date<=start_date) return(0);
        }
      //--- la copia della parte successiva forza il caricamento dei dati
      int copied=CopyTime(symbol,period,bars,100,times);
      if(copied>0)
        {
         //--- controllo dei dati
         if(times[0]<=start_date) return(0);
         if(bars+copied>=max_bars) return(-2);
         fail_cnt=0;
        }
      else
        {
         //--- non più di 100 tentativi falliti
         fail_cnt++;
         if(fail_cnt>=100) return(-5);
         Sleep(10);
        }
     }
//----+arresto
   return(-3);
  }
//+------------------------------------------------------------------+

e muore qui

while(!SeriesInfoInteger(symbol,period,SERIES_SYNCHRONIZED) && !IsStopped())
 

Ciao Nikolay

Historyloader.mqh ha solo una funzione di

int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)

non ha la funzione Loadhistory() come menzionato.
 
Nikolay Kositsin:

Niente dura per sempre sotto la luna!

Grazie mille, per me funziona!

Nuovo commento