Indicateurs: Soutien et résistance

Nouveau commentaire
 

Soutien et résistance:

Indicateur des niveaux de support et de résistance basé sur l'indicateur des fractales.

Soutien et résistance

Author: Nikolay Kositsin

 

L'indicateur ne fonctionne pas correctement. Les niveaux ne sont correctement reflétés que sur l'historique, lorsque de nouvelles barres apparaissent, elles ne sont pas suivies.

Dans la figure : la ligne rouge, le moment où l'indicateur a été attaché au graphique. Tout est correct à gauche de la ligne, et faux à droite.

Correct et incorrect

 
gdtt:

L'indicateur ne fonctionne pas correctement. Les niveaux ne sont correctement reflétés que sur l'historique, lorsque de nouvelles barres apparaissent, elles ne sont pas suivies.

Dans la figure : la ligne rouge, le moment où l'indicateur a été attaché au graphique. Tout est correct à gauche de la ligne, et faux à droite.

Ah oui, j'ai complètement oublié que le fractal est une dinde qui compte à l'envers ! Réparons-le !
 

Depuis la dernière mise à jour de MT5, cet indicateur ne fonctionne plus. Il ne fait qu'imprimer des points sur le haut et le bas de chaque bougie.

Qu'est-ce qui ne va pas ?

 
yohmm:

Depuis la dernière mise à jour de MT5, cet indicateur ne fonctionne plus. Il ne fait qu'imprimer des points sur le haut et le bas de chaque bougie.

Qu'est-ce qui ne va pas ?

Cet indicateur fonctionne normalement. Build 1016.
 

Oui, j'ai la Build 1016. J'ai téléchargé l'indicateur à nouveau et je l'ai recompilé avec 0 erreur(s) et 0 avertissement(s). Il ne fonctionne toujours pas, il montre juste les points sur le haut et le bas.

Mais ce n'est pas grave, j'utilise Fibo retracement ou dessine des niveaux s/r par moi-même maintenant.

 
yohmm:

Oui, j'ai la Build 1016. J'ai téléchargé l'indicateur à nouveau et je l'ai recompilé avec 0 erreur(s) et 0 avertissement(s). Il ne fonctionne toujours pas, il montre juste les points sur le haut et le bas.

Mais ce n'est pas grave, j'utilise Fibo retracement ou je dessine des niveaux s/r moi-même maintenant.

Pouvez-vous télécharger le graphique ?
 
belido:
Pouvez-vous télécharger le graphique ?

Bien sûr, le voici :

Captures d'écran de la plateforme de trading MetaTrader

EURUSD, M5, 2014.11.28

MetaQuotes Software Corp, MetaTrader 5, Démo

temp_file_screenshot_27398.png

EURUSD, M5, 2014.11.28, MetaQuotes Software Corp, MetaTrader 5, Démo


 
J'ai le même problème ! une réinstallation de metatrader n'aide pas non plus...:-(
Dossiers :
sup.png  36 kb
 

Essayez ceci


//+------------------------------------------------------------------+
//|Support et résistance.mq5 |
//|Copyright © 2005, Dmitry |
//|Mise à jour décembre 2014
//+------------------------------------------------------------------+
#property copyright "Copyright © 2006, MetaQuotes Software Corp.
#property link      "http://www.metaquotes.net/"
//---- version
#property version   "1.01"
//---- indicateur dans la fenêtre graphique
#property indicator_chart_window 
//---- 2 tampons d'indicateurs sont utilisés
#property indicator_buffers 2
//---- 2 graphiques sont utilisés
#property indicator_plots   2
//+----------------------------------------------+
//| Options de l'indicateur baissier |
//+----------------------------------------------+
//---- type de dessin en tant que flèche
#property indicator_type1   DRAW_ARROW
//---- Couleur magenta
#property indicator_color1  Magenta
//---- Largeur de ligne
#property indicator_width1  1
//---- Label de soutien
#property indicator_label1  "Support"
//+----------------------------------------------+
//| Indicateur haussier options |
//+----------------------------------------------+
//---- type de dessin en tant que flèche
#property indicator_type2   DRAW_ARROW
//---- Couleur de la chaux
#property indicator_color2  Lime
//---- Largeur de ligne
#property indicator_width2  1
//---- Label Résistance
#property indicator_label2 "Resistance"

//+----------------------------------------------+
//| Paramètres d'entrée de l'indicateur
//+----------------------------------------------+
//entrée int iPeriod=70 ; // période ATR
//+----------------------------------------------+

//---- déclaration de tableaux dynamiques, utilisés comme tampons d'indicateurs
double SellBuffer[];
double BuyBuffer[];
//---
int StartBars;
int FRA_Handle;
//+------------------------------------------------------------------+
//| Fonction d'initialisation de l'indicateur personnalisé
//+------------------------------------------------------------------+
void OnInit()
  {
//---- initialisation des variables globales
   StartBars=6;
//---- obtenir la poignée de l'indicateur iFractals
   FRA_Handle=iFractals(NULL,0);
   if(FRA_Handle==INVALID_HANDLE)Print(" INVALID_HANDLE FRA");

//---- définir SellBuffer comme tampon d'indicateur
   SetIndexBuffer(0,SellBuffer,INDICATOR_DATA);
//---- définir l'index de la barre de départ à tracer
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,StartBars);
//---- set label for support
   PlotIndexSetString(0,PLOT_LABEL,"Support");
//---- set arrow char code
   PlotIndexSetInteger(0,PLOT_ARROW,159);
//---- indexation en tant que séries chronologiques
   ArraySetAsSeries(SellBuffer,true);

//---- définir BuyBuffer comme tampon indicateur
   SetIndexBuffer(1,BuyBuffer,INDICATOR_DATA);
//---- définir l'indice de la barre de départ à tracer
   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,StartBars);
//--- définir l'étiquette de la résistance
   PlotIndexSetString(1,PLOT_LABEL,"Resistance");
//---- set arrow char code
   PlotIndexSetInteger(1,PLOT_ARROW,159);
//---- indexation en tant que série chronologique
   ArraySetAsSeries(BuyBuffer,true);

//---- set precision
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//---- nom court de l'indicateur
   string short_name="Support & Resistance";
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//---- 
  }
//+------------------------------------------------------------------+
//| Fonction d'itération de l'indicateur personnalisée|
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[]
                )
  {
//---- vérification des barres
   if(BarsCalculated(FRA_Handle)<rates_total
      || rates_total<StartBars)
      return(0);

//---- déclaration des variables locales
   int to_copy,limit,bar;
   double FRAUp[],FRALo[];

//---- calcul des barres à copier
//---- et indice de départ (limite) pour la boucle de recalcul des barres
   if(prev_calculated>rates_total || prev_calculated<=0)// vérification du premier appel
     {
      to_copy=rates_total;           // barres à copier
      limit=rates_total-StartBars-1; // indice de départ
     }
   else
     {
      to_copy=rates_total-prev_calculated+3; // barres à copier
      limit=rates_total-prev_calculated+2;   // indice de départ
     }

//---- indexation en tant que séries chronologiques
   ArraySetAsSeries(FRAUp,true);
   ArraySetAsSeries(FRALo,true);
   ArraySetAsSeries(high,true);
   ArraySetAsSeries(low,true);

//---- copier les données de l'indicateur dans les tableaux
   if(CopyBuffer(FRA_Handle,0,0,to_copy,FRAUp)<=0) return(0);
   if(CopyBuffer(FRA_Handle,1,0,to_copy,FRALo)<=0) return(0);
 
//---- boucle principale
   for(bar=limit; bar>=0; bar--)
     {
       BuyBuffer[bar] = 0.0;
       SellBuffer[bar] = 0.0;
       
     
       if(FRAUp[bar] != DBL_MAX) BuyBuffer[bar] = high[bar]; else BuyBuffer[bar] = BuyBuffer[bar+1];
       
       
       if(FRALo[bar] != DBL_MAX) SellBuffer[bar] = low[bar]; else SellBuffer[bar] = SellBuffer[bar+1];
     }
//---- 
   return(rates_total);
  }
//+------------------------------------------------------------------+
123
Nouveau commentaire