Toute question des nouveaux arrivants sur MQL4 et MQL5, aide et discussion sur les algorithmes et les codes.

Taras Slobodyanik 2021.07.22 14:33 #15421

Andy Dufresne:

Bonjour. Pouvez-vous expliquer à un nigaud comment initialiser un tableau de structure ? Pour un tableau normal, c'est simple

int HiddenFunc[3,2] = {1,2,3,4,5,6} ;

Mais qu'en est-il de l'ensemble des structures ? Initialiser un tableau avec cette structure, par exemple

struct MODE_KEY {string Key ; bool Act;} ;

comme les cours :
https://www.mql5.com/ru/docs/basis/types/classes

ou tableaux)

struct trade_settings
  {
   double take;         // значения цены фиксации прибыли
   double stop;         // значение цены защитного стопа
   uchar  slippage;     // значение допустимого проскальзывания
  };



   trade_settings ss[]={
                        {1.0, 2.0, 5},
                        {1.0, 2.0, 5},
                        {1.0, 2.0, 5}
                        };

Документация по MQL5: Основы языка / Типы данных / Структуры, классы и интерфейсы

www.mql5.com

Структуры, классы и интерфейсы - Типы данных - Основы языка - Справочник MQL5 - Справочник по языку алгоритмического/автоматического трейдинга для MetaTrader 5

законопослушный гражданин 2021.07.22 14:53 #15422

Bonjour.

Test des hiboux. (le code est joint ci-dessous).

owl utilise une martingale basée sur l'historique des ordres précédents (si perte, alors multiplier le lot par le coefficient martin...).

l'ordre précédent a été fermé par un stop avec par exemple 0,2 lot à (Martin = 2...). ensuite, je désactive l'"auto-trading" dans le terminal MT4, ou j'éteins complètement le terminal et le hibou arrête de trader.

Ensuite, quand j'active le bouton "auto-trading"... - Puis la chouette se met en marche et ouvre le lot suivant avec un volume de 0,4.

Alors, comment corriger le code, de sorte que lorsque vous désactivez "auto-trading", éteignez le terminal et le rallumez, le hibou commence la session de trading suivante avec le lot de départ,

spécifié dans les paramètres (par exemple 0.01) plutôt que de multiplier le dernier fermé dans l'historique ?

//+------------------------------------------------------------------+
#property copyright "Copyright © 2018, http://cmillion.ru"
#property link      "cmillion@narod.ru"
#property strict
#property description "Советник открывает позиции по индикатору RSI после SL увеличивает лот"
#property description "Следующая сделка не открывается, пока не закрыта предыдущая"
//-------------------------------------------------------------------
extern ENUM_TIMEFRAMES timeframe_RSI = 60;
extern int    period_RSI   = 14;
extern int    level_buy    = 30;
extern int    level_sell   = 70;

extern double Lot          = 0.1;
extern double K_Martin     = 2.0;

extern int    Stoploss     = 10,
              Takeprofit   = 50;
extern int    OrdersClose  = 5;

extern int    Magic        = 0;
extern int    DigitsLot    = 2;
extern int    slippage     = 3;
//-------------------------------------------------------------------
string AC;
datetime OpenTime;
double MINLOT,MAXLOT;
//-------------------------------------------------------------------
void OnTick()
{
   if (!IsTradeAllowed()) 
   {
      DrawLABEL("Торговля",0,0,0,Red,"Торговля запрещена");
      return;
   } 
   else DrawLABEL("Торговля",0,0,0,Lime,"Торговля разрешена");

   //---

   double STOPLEVEL=MarketInfo(Symbol(),MODE_STOPLEVEL);
   //---
   double OSL,OTP,OOP,SL,TP,Profit=0;
   int b=0,s=0,tip;
   for (int i=0; i<OrdersTotal(); i++)
   {    
      if (OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
      { 
         if (OrderSymbol()==Symbol() && Magic==OrderMagicNumber())
         { 
            tip = OrderType(); 
            OSL = NormalizeDouble(OrderStopLoss(),Digits);
            OTP = NormalizeDouble(OrderTakeProfit(),Digits);
            OOP = NormalizeDouble(OrderOpenPrice(),Digits);
            SL=OSL;TP=OTP;
            Profit+=OrderProfit()+OrderCommission()+OrderSwap();
            if (tip==OP_BUY)             
            {  
               b++; 
               if (OSL==0 && Stoploss!=0)
               {
                  if ((Bid-NormalizeDouble(OOP - Stoploss * Point,Digits)) / Point>=STOPLEVEL) SL = NormalizeDouble(OOP - Stoploss * Point,Digits);
               } 
               if (OTP==0 && Takeprofit!=0)
               {
                  if ((NormalizeDouble(OOP + Takeprofit * Point,Digits)-Ask) / Point>=STOPLEVEL) TP = NormalizeDouble(OOP + Takeprofit * Point,Digits);
               } 
               if (SL != OSL || TP != OTP)
               {  
                  if (!OrderModify(OrderTicket(),OOP,SL,TP,0,White)) Print("Error OrderModify ",GetLastError());
               }
            }                                         
            if (tip==OP_SELL)        
            {
               s++;
               if (OSL==0 && Stoploss!=0)
               {
                  if ((NormalizeDouble(OOP + Stoploss * Point,Digits)-Ask) / Point>=STOPLEVEL) SL = NormalizeDouble(OOP + Stoploss   * Point,Digits);
               }
               if (OTP==0 && Takeprofit!=0)
               {
                  if ((Bid-NormalizeDouble(OOP - Takeprofit * Point,Digits)) / Point>=STOPLEVEL) TP = NormalizeDouble(OOP - Takeprofit * Point,Digits);
               }
               if (SL != OSL || TP != OTP)
               {  
                  if (!OrderModify(OrderTicket(),OOP,SL,TP,0,White)) Print("Error OrderModify ",GetLastError());
               }
            } 
         }
      }
   }
   
   
   //---
   
   double AB = AccountBalance();
   
   //---
   
   DrawLABEL("Balance"        ,1,5,0,clrGreen,StringConcatenate("Balance ",DoubleToStr(AB,2),AC));
   DrawLABEL("Equity"         ,1,5,0,clrGreen,StringConcatenate("Equity ",DoubleToStr(AccountEquity(),2),AC));
   DrawLABEL("FreeMargin"     ,1,5,0,clrGreen,StringConcatenate("FreeMargin ",DoubleToStr(AccountFreeMargin(),2),AC));
   DrawLABEL("Take"           ,1,5,0,Color(Profit>0,Lime,Red),StringConcatenate("Profit ",DoubleToStr(Profit,2),AC));
   
   double Lots=0,RSI1=0,RSI0=0;
   if (b+s==0)
   {
      RSI0= iRSI (NULL,timeframe_RSI,period_RSI,PRICE_CLOSE,0);
      RSI1= iRSI (NULL,timeframe_RSI,period_RSI,PRICE_CLOSE,1);
   }
   else return;

   //---
   if (RSI0>=level_buy && RSI1<=level_buy)
   {
      Lots=LOT();

      if (Lots>MAXLOT) Lots = MAXLOT;
      if (Lots<MINLOT) Lots = MINLOT;
      
      if(SendOrder(OP_BUY, Lots, NormalizeDouble(Ask,Digits)))OpenTime=iTime(NULL,timeframe_RSI,1); 
   }

   //---
   
   if (RSI0<=level_sell && RSI1>=level_sell)
   {
      Lots=LOT();

      if (Lots>MAXLOT) Lots = MAXLOT;
      if (Lots<MINLOT) Lots = MINLOT;

      if(SendOrder(OP_SELL, Lots, NormalizeDouble(Bid,Digits))) OpenTime=iTime(NULL,timeframe_RSI,1); 
   }
}
//------------------------------------------------------------------
bool SendOrder(int tip, double lots, double price, double sl=0, double tp=0)
{
   if (tip<2)
   {
      if (AccountFreeMarginCheck(Symbol(),tip,lots)<0)
      {
         Alert("Недостаточно средств");
         return(0);
      }
   }
   for (int i=0; i<10; i++)
   {    
      if (OrderSend(Symbol(),tip, lots,price,slippage,sl,tp,NULL,Magic,0,clrNONE)!=-1) return(1);
         Alert(" попытка ",i," Ошибка открытия ордера ",Strtip(tip)," <<",(GetLastError()),">>  lot=",lots,"  pr=",price," sl=",sl," tp=",tp);
      Sleep(500);
      RefreshRates();
      if (IsStopped()) return(0);
   }
   return(0);
}
//------------------------------------------------------------------
string Strtip(int tip)
{
   switch(tip) 
   { 
   case OP_BUY:
      return("BUY"); 
   case OP_SELL:
      return("SELL"); 
   case OP_BUYSTOP:
      return("BUYSTOP"); 
   case OP_SELLSTOP:
      return("SELLSTOP"); 
   case OP_BUYLIMIT:
      return("BUYLIMIT"); 
   case OP_SELLLIMIT:
      return("SELLLIMIT"); 
   }
   return("error"); 
}
//------------------------------------------------------------------
void OnDeinit(const int reason)
{
   if (!IsTesting()) 
   {
      ObjectsDeleteAll(0);
   }
}
//-------------------------------------------------------------------
void DrawLABEL(string name, int CORNER, int X, int Y, color clr, string Name)
{
   if (ObjectFind(name)==-1)
   {
      ObjectCreate(name, OBJ_LABEL, 0, 0, 0);
      ObjectSet(name, OBJPROP_CORNER, CORNER);
      ObjectSet(name, OBJPROP_XDISTANCE, X);
      ObjectSet(name, OBJPROP_YDISTANCE, Y);
   }
   ObjectSetText(name,Name,10,"Arial",clr);
}
//+------------------------------------------------------------------+
int OnInit()
{
   MINLOT = MarketInfo(Symbol(),MODE_MINLOT);
   MAXLOT = MarketInfo(Symbol(),MODE_MAXLOT);
   Comment("Start ",TimeToStr(TimeCurrent(),TIME_DATE|TIME_SECONDS));
   
   AC = StringConcatenate(" ", AccountCurrency());
   
   int Y=15;
   DrawLABEL("Торговля"  ,1,5,Y,Red,"Торговля ");Y += 20;
   DrawLABEL("Balance"   ,1,5,Y,clrGreen,StringConcatenate("Balance ",DoubleToStr(AccountBalance(),2),AC));Y += 15;
   DrawLABEL("Equity"    ,1,5,Y,clrGreen,StringConcatenate("Equity ",DoubleToStr(AccountEquity(),2),AC));Y += 15;
   DrawLABEL("FreeMargin",1,5,Y,clrGreen,StringConcatenate("FreeMargin ",DoubleToStr(AccountFreeMargin(),2),AC));Y += 30;

   DrawLABEL("Take"           ,1,5,Y,Lime,"Profit ");Y += 20;
   
   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
color Color(bool P,color a,color b)
{
   if (P) return(a);
   else return(b);
}
//------------------------------------------------------------------
double LOT()
{
   int n=0;
   double OL=Lot;
   for (int j = OrdersHistoryTotal()-1; j >= 0; j--)
   {
      if (OrderSelect(j, SELECT_BY_POS,MODE_HISTORY))
      {
         if (OrderSymbol() == Symbol() && OrderMagicNumber() == Magic)
         {
            if (OrderProfit()<0) 
            {
               if (n==0) OL=NormalizeDouble(OrderLots()*K_Martin,DigitsLot);
               n++;
               if (n>=OrdersClose) {Comment("1");return(Lot);}
            }
            else
            {
               if (n==0) {Comment("2");return(Lot);}
               else {Comment("3");return(OL);}
            }
         }
      }
   }
   return(OL);
}
//------------------------------------------------------------------

Программные помощники MQL для работы на финансовых рынках

cmillion.ru

Скрипт показывает максимальную и минимальную корреляцию на выбранном отрезке истории, например за последние 10000 свечей. Таким образом можно заранее проанализировать какие пары и как коррелируют. В параметрах задаем Тф период корреляции и период анализа корреляции. Зеленым цветом выделяются пары с прямой корреляцией у которых корреляция выше...

Je rédigerai un conseiller Toute question de débutant, Je suis bon pour

Tretyakov Rostyslav 2021.07.22 16:19 #15423

законопослушный гражданин:

Bonjour.

Test des hiboux. (le code est joint ci-dessous).

owl utilise une martingale basée sur l'historique des ordres précédents (si perte, alors multiplier le lot par le coefficient martin...).

l'ordre précédent a été fermé par un stop avec par exemple 0,2 lot à (martin =2...) puis je désactive l'"auto-trading" dans le terminal MT4 ou je désactive complètement le terminal et le hibou arrête de trader.

Ensuite, quand j'active le bouton "auto-trading"... - Puis la chouette se met en marche et ouvre le lot suivant avec un volume de 0,4.

Alors, comment corriger le code, de sorte que lorsque vous désactivez "auto-trading", éteignez le terminal et le rallumez, le hibou commence la session de trading suivante avec le lot de départ,

spécifié dans les paramètres (par exemple 0.01) plutôt que de multiplier le dernier fermé dans l'historique ?

Vous créez une variable globale

datetime Start;

int OnInit()
{
   Start=TimeCurrent();
.....................
}
void OnTick()
{
   if (!IsTradeAllowed()) 
   {
      DrawLABEL("Торговля",0,0,0,Red,"Торговля запрещена");
      Start=TimeCurrent();
      return;
   } 
.....................
}

et ensuite s'il n'y a pas d'ordres ouverts/fermés plus tard "Start"

Lots=Lot;

законопослушный гражданин 2021.07.22 19:56 #15424

MakarFX:

Vous créez une variable globale

et ensuite, s'il n'y a pas d'ordres ouverts/fermés, "Start".

Merci.

J'ai déjà une datetime OpenTime ; - faut-il la remplacer par unedatetime Start ou l'ajouter ?

"S'il n'y a pas d'ordres ouverts/fermés plus tard que "Start "Lots=Lot ; " - on ne sait pas du tout ce qu'il faut en faire ?

Toute question de débutant, Pour ceux qui sont Signal USDCAD

Tretyakov Rostyslav 2021.07.22 20:13 #15425

законопослушный гражданин:

Merci.

Je ne suis pas encore très doué dans ce domaine. J'ai déjà datetime OpenTime ; - faut-il le remplacer pardatetime Start ou l'ajouter ?

" et ensuite s'il n'y a pas d'ordres ouverts/fermés plus tard " Démarrer "Lots=Lot ; " - on ne sait pas du tout à quoi se référer ?

Décrivez en quelques mots ce que vous attendez de cette EA (la logique de son fonctionnement),

Je pense que vous avez beaucoup de choses inutiles dans votre code ou je ne comprends pas quelque chose.

Yevhenii Levchenko 2021.07.23 12:01 #15426

Afin d'ajouter un indicateur en lui passant le handle d'un autre indicateur (comme applied_price), cet autre indicateur doit avoir un seul buffer ? Ou est-il possible d'avoir plusieurs tampons ? S'il y en a plus d'un, dans ce cas le premier prend les données uniquement à partir du tampon zéro du deuxième indicateur ?

Erreurs, bugs, questions Aide au codage [Toute question de débutant,

SGarnov 2021.07.24 12:34 #15427

Bon après-midi. Aide pour l'EA. Selon la stratégie, si un stop s'est déclenché, alors l'EA devrait ajouter (le nombre de points) à la prochaine prise en charge
de l'historique par ID, mais il ne le fait pas pour une raison quelconque.

Quel est le problème avec le code ?

if(isLimitOn && OrderSelect(OrderMagicNumber(), SELECT_BY_TICKET, MODE_HISTORY)){
            tpc += stop_loss;
            if(OrderSelect(lastMagic, SELECT_BY_TICKET)){
               if(OrderType() == OP_BUY) {
                  double tp_price = NormalizeDouble((OrderOpenPrice() + Point() * (tp + tpc)), Digits);
                  if(!OrderModify(OrderTicket(), OrderOpenPrice(), OrderStopLoss(), tp_price, OrderExpiration()))
                     Print("Ошибка модификации ордера:", GetLastError());
               }else if(OrderType() == OP_SELL){
                  double tp_price = NormalizeDouble((OrderOpenPrice() - Point() * (tp + tpc)), Digits);
                  if(!OrderModify(OrderTicket(), OrderOpenPrice(), OrderStopLoss(), tp_price, OrderExpiration()))
                     Print("Ошибка модификации ордера:", GetLastError());
               }
            }
               
            isLimitOn = false;
         }

Questions des débutants MQL4 Questions des débutants MQL5 De la théorie à

Tretyakov Rostyslav 2021.07.24 13:47 #15428

SGarnov:

Bon après-midi. Aide pour l'EA. Selon la stratégie, si un stop s'est déclenché, alors l'EA devrait ajouter (le nombre de points) à la prochaine prise en charge
de l'historique par ID, mais il ne le fait pas pour une raison quelconque.

Quel est le problème avec le code ?

il n'est pas clair que c'est "OrderMagicNumber()" et que c'est "stop_loss".

Evgenyi1990 2021.07.26 09:16 #15429

vérifié ?

Evgenyi1990 2021.07.26 09:17 #15430

Bonjour, j'ai besoin d'un conseiller. Où puis-je en trouver un de confiance ?

Toute question des nouveaux arrivants sur MQL4 et MQL5, aide et discussion sur les algorithmes et les codes. - page 1543