Newbie Question : Crossover EA is not executing any buy or sell order. Any Help with coding please.

Samarthan Bidari 2020.03.25 15:57

#property copyright "Frobo"
#property link      "https://www.frobo.com"

input int MAPeriodShort=9;
input int MAPeriodLong=21;
input int MAShift=0;
input ENUM_MA_METHOD MAMethodS= MODE_SMA;
input ENUM_MA_METHOD MAMethodL= MODE_SMA;
input ENUM_APPLIED_PRICE MAPrice= PRICE_CLOSE;
input double stopLoss=0.1;
input double takeProfit=0.3;
input int volume=1;

enum orderType{
   orderBuy,
   orderSell
};

datetime candleTimes[],lastCandleTime;

MqlTradeRequest request;
MqlTradeResult result;
MqlTradeCheckResult checkResult;

bool checkNewCandle(datetime &candles[],datetime &last){
        bool newCandle=false;

        CopyTime(_Symbol,_Period,0,3,candles);

        if(last!=0){
                if(candles[0]>last){
                        newCandle=true;
                        last=candles[0];
                }
        }else{
                last=candles[0];
        }

        return newCandle;
}

bool closePosition(){
        double vol=0;
        long type=WRONG_VALUE;
        long posID=0;

        ZeroMemory(request);

        if(PositionSelect(_Symbol)){
                vol=PositionGetDouble(POSITION_VOLUME);
                type=PositionGetInteger(POSITION_TYPE);
                posID=PositionGetInteger(POSITION_IDENTIFIER);

                request.sl=PositionGetDouble(POSITION_SL);
                request.tp=PositionGetDouble(POSITION_TP);     
        }else{
                return false;
        }

        request.symbol=_Symbol;
        request.volume=vol;
        request.action=TRADE_ACTION_DEAL;
        request.type_filling=ORDER_FILLING_FOK;
        request.deviation=10;
        double price=0;


        if(type==POSITION_TYPE_BUY){
                //Buy
                request.type=ORDER_TYPE_BUY;
                price=NormalizeDouble(SymbolInfoDouble(_Symbol,SYMBOL_ASK),_Digits);
        }else if(POSITION_TYPE_SELL){
                //Sell
                request.type=ORDER_TYPE_SELL;
                price=NormalizeDouble(SymbolInfoDouble(_Symbol,SYMBOL_BID),_Digits);
        }

        request.price=price;

        if(OrderCheck(request,checkResult)){
                Print("Checked!");
        }else{
                Print("Not correct! ERROR :"+IntegerToString(checkResult.retcode));
                return false;
        }

        if(OrderSend(request,result)){
                Print("Successful send!");
        }else{
                Print("Error order not send!");
                return false;
        }

        if(result.retcode==TRADE_RETCODE_DONE || result.retcode==TRADE_RETCODE_PLACED){
                Print("Trade Placed!");
                return true;
        }else{
                return false;
        }   
   
}

bool makePosition(orderType type){
        ZeroMemory(request);
        request.symbol=_Symbol;
        request.volume=volume;
        request.action=TRADE_ACTION_DEAL;
        request.type_filling=ORDER_FILLING_FOK;
        double price=0;

        if(type==orderBuy){
                //Buy
                request.type=ORDER_TYPE_BUY;
                price=NormalizeDouble(SymbolInfoDouble(_Symbol,SYMBOL_ASK),_Digits);
                request.sl=NormalizeDouble(price-stopLoss,_Digits);
                request.tp=NormalizeDouble(price+takeProfit,_Digits);
                
        }else if(type==orderSell){
                //Sell
                request.type=ORDER_TYPE_SELL;
                price=NormalizeDouble(SymbolInfoDouble(_Symbol,SYMBOL_BID),_Digits);
                request.sl=NormalizeDouble(price+stopLoss,_Digits);
                request.tp=NormalizeDouble(price-takeProfit,_Digits);

        }
        request.deviation=10;
        request.price=price;


        if(OrderCheck(request,checkResult)){
                Print("Checked!");
        }else{
                Print("Not Checked! ERROR :"+IntegerToString(checkResult.retcode));
                return false;
        }

        if(OrderSend(request,result)){
                Print("Ordem enviada com sucesso!");
        }else{
                Print("Ordem não enviada!");
                return false;
        }

        if(result.retcode==TRADE_RETCODE_DONE || result.retcode==TRADE_RETCODE_PLACED){
                Print("Trade Placed!");
                return true;
        }else{
                return false;
        }
}

int OnInit(){
        ArraySetAsSeries(candleTimes,true);
        return(0);
}



void OnTick(){
        
        if(checkNewCandle(candleTimes,lastCandleTime)){
                double maS[];
                double maL[];
                ArraySetAsSeries(maS,true);
                ArraySetAsSeries(maL,true);
                double candleClose[];
                ArraySetAsSeries(candleClose,true);
                int maSHandle= iMA(_Symbol,_Period,MAPeriodShort,MAShift,MAMethodS,MAPrice);
                int maLHandle= iMA(_Symbol,_Period,MAPeriodLong,MAShift,MAMethodL,MAPrice);
                CopyBuffer(maSHandle,0,0,3,maS);
                CopyBuffer(maLHandle,0,0,3,maL);
                CopyClose(_Symbol,_Period,0,3,candleClose);

                if((maS[1] < maL[1])&&(maS[0]>maL[0])){
                        //cross up
                        Print("Cross above!");
                        closePosition();
                        makePosition(orderBuy);

                }else if((maS[1]>maL[1])&&(maS[0]<maL[0])){
                        //cross down
                        Print("Cross under!");
                        closePosition();
                        makePosition(orderSell);     

                }else{
                        //trailing

                }
        }
  
}

G'Day Guys,

I have just started to learn programing on mql5. this EA is not executing any buy or sell order. Any help with where did i do wrong please?

William Roeder 2020.03.25 16:56 #1

        }else if(POSITION_TYPE_SELL){

Not a boolean.

```
                price=NormalizeDouble(SymbolInfoDouble(_Symbol,SYMBOL_ASK),_Digits);
                request.sl=NormalizeDouble(price-stopLoss,_Digits);
                request.tp=NormalizeDouble(price+takeProfit,_Digits);
```
You buy at the Ask and sell at the Bid. So for buy orders you pay the spread on open. For sell orders you pay the spread on close.
1. Your buy order's TP/SL (or Sell Stop's/Sell Limit's entry) are triggered when the Bid reaches it. Not the Ask. Your SL is shorter by the spread and your TP would be longer. Don't you want the same/specified amount for either direction?
2. Your sell order's TP/SL (or Buy Stop's/Buy Limit's entry) will be triggered when the Ask reaches it. To trigger at a specific Bid price, add the average spread.
  MODE_SPREAD (Paul) - MQL4 programming forum - Page 3 #25
3. The charts show Bid prices only. Turn on the Ask line to see how big the spread is (Tools → Options (control+O) → charts → Show ask line.)

datetime candleTimes[],lastCandleTime;

void OnTick(){        
        if(checkNewCandle(candleTimes,lastCandleTime)){

What is the value of lastCandleTime (don't say zero,) and what does checkNewCandle return given that value?

```
                price=NormalizeDouble(SymbolInfoDouble(_Symbol,SYMBOL_ASK),_Digits);
```
You used NormalizeDouble, It's use is usually wrong, as it is in your case.
1. Floating point has infinite number of decimals, it's your not understanding floating point and that some numbers can't be represented exactly. (like 1/10.)
  Double-precision floating-point format - Wikipedia, the free encyclopedia
  See also The == operand. - MQL4 programming forum
2. Print out your values to the precision you want with DoubleToString - Conversion Functions - MQL4 Reference.
3. SL/TP (stops) need to be normalized to tick size (not Point.) (On 5Digit Broker Stops are only allowed to be placed on full pip values. How to find out in mql? - MQL4 programming forum) and abide by the limits Requirements and Limitations in Making Trades - Appendixes - MQL4 Tutorial and that requires understanding floating point equality Can price != price ? - MQL4 programming forum
4. Open price for pending orders need to be adjusted. On Currencies, Point == TickSize, so you will get the same answer, but it won't work on Metals. So do it right: Trailing Bar Entry EA - MQL4 programming forum or Bid/Ask: (No Need) to use NormalizeDouble in OrderSend - MQL4 programming forum
5. Lot size must also be adjusted to a multiple of LotStep and check against min and max. If that is not a power of 1/10 then NormalizeDouble is wrong. Do it right.
6. MathRound() and NormalizeDouble() are rounding in a different way. Make it explicit.
  MT4:NormalizeDouble - General - MQL5 programming forum
  How to Normalize - Expert Advisors and Automated Trading - MQL5 programming forum
7. Prices you get from the terminal are already normalized.

                int maSHandle= iMA(_Symbol,_Period,MAPeriodShort,MAShift,MAMethodS,MAPrice);
                int maLHandle= iMA(_Symbol,_Period,MAPeriodLong,MAShift,MAMethodL,MAPrice);

It takes time for indicators to generate data. Get your handles in OnInit.

```
input double stopLoss=0.1;
input double takeProfit=0.3;
                request.sl=NormalizeDouble(price-stopLoss,_Digits);
                request.tp=NormalizeDouble(price+takeProfit,_Digits);
```
0.1 is 10 PIPs on JPY pairs but 3000 PIPs on non-JPY pairs and invalid tick size on metals. PIP, Point, or Tick are all different in general.
          What is a TICK? - MQL4 programming forum

Unless you manually adjust your SL/TP for each separate symbol, using Point means code breaks on 4 digit brokers, exotics (e.g. USDZAR where spread is over 500 points,) and metals. Compute what a PIP is and use it, not points.
          How to manage JPY pairs with parameters? - MQL4 programming forum
          Slippage defined in index points - Currency Pairs - Expert Advisors and Automated Trading - MQL5 programming forum
```
input int volume=1;
        request.volume=vol;
```
Control your risk.
1. Never risk more than a small percentage of your account, certainly less than 2% per trade, 6% total to the account. Risk depends on your initial stop loss, lot size, and the value of the pair. It does not depend on margin and leverage. No SL means you have infinite risk.
2. You place the stop where it needs to be — where the reason for the trade is no longer valid. E.g. trading a support bounce the stop goes below the support.
3. AccountBalance * percent/100 = RISK = OrderLots * (|OrderOpenPrice - OrderStopLoss| * DeltaPerLot + CommissionPerLot) (Note OOP-OSL includes the spread, and DeltaPerLot is usually around $10/pip but it takes account of the exchange rates of the pair vs. your account currency.)
4. Do NOT use TickValue by itself - DeltaPerLot and verify that MODE_TICKVALUE is returning a value in your deposit currency, as promised by the documentation, or whether it is returning a value in the instrument's base currency.
            MODE_TICKVALUE is not reliable on non-fx instruments with many brokers - MQL4 programming forum 2017.10.10
            Is there an universal solution for Tick value? - Currency Pairs - General - MQL5 programming forum 2018.02.11
            Lot value calculation off by a factor of 100 - MQL5 programming forum 2019.07.19
5. You must normalize lots properly and check against min and max.
6. You must also check FreeMargin to avoid stop out
Most pairs are worth about $10 per PIP. A $5 risk with a (very small) 5 PIP SL is $5/$10/5 or 0.1 Lots maximum.
bidari: where did i do wrong please?
Use the debugger or print out your variables, including _LastError and prices and find out why. Do you really expect us to debug your code for you?

Yet Another OrderSend Error Custom optimization based on USD pair lot sizes

New comment