Libraries: Expert

fxsaber 2017.09.08 14:45 #1

Explanation of this

Forum on trading, automated trading systems and testing trading strategies

Questions from MQL4 MT4 MetaTrader 4 beginners

fxsaber, 2017.09.08 13:52

When using ChartApplyTemplate, mandatory synchronisation is required, which I do in the bible like this

  static bool TemplateApply( const long Chart_ID, const string &Str, const bool Sync = true )
  {
    string TmpStr = Str;

    const bool SyncFlag = (Sync && Chart_ID && (Chart_ID != ::ChartID()) && !::IsStopped());

    if (SyncFlag)
    {
      const color ColorStopLevel = (color)::ChartGetInteger(Chart_ID, CHART_COLOR_STOP_LEVEL);

      if ((bool)(ColorStopLevel >> 24))
        ::ChartSetInteger(Chart_ID, CHART_COLOR_STOP_LEVEL, ColorStopLevel & 0xFFFFFF);

      const int NewColorStopLevel = (int)EXPERT::StringBetween(TmpStr, EXPERT_STOPLEVEL, STRING_END) | (0x01 << 24);

      TmpStr = Str;
      EXPERT::StringReplace(TmpStr, EXPERT_STOPLEVEL, STRING_END, EXPERT_STOPLEVEL + (string)NewColorStopLevel + STRING_END);
    }

    short Data[];
    const bool Res = ::StringToShortArray(TmpStr, Data, 0, ::StringLen(TmpStr)) &&
                     ::FileSave(FILENAME, Data) && ::ChartApplyTemplate((ulong)Chart_ID, FILENAME);

    if (Res && SyncFlag)
    {
      long Value;

      while ((!::IsStopped() && ::ChartGetInteger(Chart_ID, CHART_COLOR_STOP_LEVEL, 0, Value) && (!(bool)((int)Value >> 24))))
        ::Sleep(0);

      ::ChartSetInteger(Chart_ID, CHART_COLOR_STOP_LEVEL, (int)Value & 0xFFFFFF);
    }

    return(Res);
  }

ChartApply is not immediately triggered. And any further actions can be done only after triggering.

To understand that the template has been applied, you need to change the template itself (the colour of one characteristic of the chart is changed in the bible - the 4th byte, responsible for transparency) and wait through Sleep (ChartGetInterger) when this value becomes a property of the chart. After that, set its normal value via ChartSetInteger.

If we need to run an Expert Advisor on the same chart where the script is thrown, then we need to open a new chart and run the same (script) on it through the template, and from there we need to run the Expert Advisor on the chart we need, having closed the auxiliary one. This is done by ExpertLoader_Example.mq5.

Why not put the Useful features from KimIV Once again, about multithreading

fxsaber 2017.09.11 15:13 #2

может быть полезна при написании различных управляющих панелей чартами/советниками и т.п.

The library runs without DLLs - fully satisfies the Market requirements.

fxsaber 2017.10.31 01:27 #3

A little hack - running EAs/scripts on OBJ_CHART-objects.

So launched Expert Advisors hang dead - they are not executed in any way. But scripts work perfectly well. Therefore, this opens some possibilities.

For example, you can use Order-functions from indicators on charts, where there is already a running Expert Advisor. And you don't need to open any new auxiliary charts.

Compile the script Scripts\OrderSend.mq5

#include <MT4Orders.mqh>       // https://www.mql5.com/en/code/16006
#include <GlobalVariables.mqh> // https://www.mql5.com/ru/forum/189649#comment_4854618

struct ORDERSEND
{
  int Type;
  double Volume;
  double Price;
  int SlipPage;
  double SL;
  double TP;
  long Magic;
  datetime Expiration;
  color Arrow_Color;
};

void OrderSend()
{
  const ORDERSEND Order = _GlobalVariableGet<ORDERSEND>("ORDERSEND");
  const string Symb = _GlobalVariableGet<string>("Symbol");
  const string comment = _GlobalVariableGet<string>("Comment");
      
  _GlobalVariableSet(__FUNCTION__, OrderSend(Symb, Order.Type, Order.Volume, Order.Price, Order.SlipPage, Order.SL, Order.TP, comment, Order.Magic, Order.Expiration, Order.Arrow_Color));
  
  _GlobalVariableDel("ORDERSEND");
  _GlobalVariableDel("Symbol");
  _GlobalVariableDel("Comment");  
}

void OnStart()
{
  OrderSend();
}

And run the indicator, which "can trade".

#include <fxsaber\Expert.mqh>  // https://www.mql5.com/en/code/19003
#include <GlobalVariables.mqh> // https://www.mql5.com/ru/forum/189649#comment_4854618

struct ORDERSEND
{
  int Type;
  double Volume;
  double Price;
  int SlipPage;
  double SL;
  double TP;
  long Magic;
  datetime Expiration;
  color Arrow_Color;
};

template <typename T>
long _GlobalVariableGet2( const string Name, const ulong MaxTime = 1 e6 )
{
  const ulong StartTime = GetMicrosecondCount();
  
  while (!IsStopped() && !GlobalVariableCheck(Name) && (GetMicrosecondCount() - StartTime < MaxTime))
    Sleep(0);
      
  return(_GlobalVariableGet<T>(Name));
}

// OrderSend, which works even from the indicator even on a chart with an Expert Advisor
long OrderSend( string Symb, const int Type, const double dVolume, const double Price, const int SlipPage, const double SL, const double TP,
                string comment = NULL, const long magic = 0, const datetime dExpiration = 0, color arrow_color = clrNONE )
{
  MqlParam Params[1];    
  Params[0].string_value = "Scripts\\OrderSend.ex5";

  ORDERSEND Order;

  Order.Type = Type;
  Order.Volume = dVolume;
  Order.Price = Price;
  Order.SlipPage = SlipPage;
  Order.SL = SL;
  Order.TP = TP;
  Order.Magic = magic;
  Order.Expiration = dExpiration;
  Order.Arrow_Color = arrow_color;

  const long Res = ObjectCreate(0, __FILE__, OBJ_CHART, 0, 0, 0) && _GlobalVariableSet("ORDERSEND", Order) &&
                   _GlobalVariableSet("Symbol", Symb) && _GlobalVariableSet("Comment", comment) &&
                   EXPERT::Run(ObjectGetInteger(0, __FILE__, OBJPROP_CHART_ID), Params) &&
                   ObjectDelete(0, __FILE__) ? _GlobalVariableGet2<long>(__FUNCTION__) : -1;  
  
  _GlobalVariableDel(__FUNCTION__);

  return(Res);
}

void OnInit()
{  
  Print(OrderSend(_Symbol, ORDER_TYPE_BUY, 1, SymbolInfoDouble(_Symbol, SYMBOL_ASK), 100, 0, 0, "From Indicator", 9));
}

int OnCalculate( const int, const int, const int, const double &[] )
{
  return(0);
}

Features of the mql5 Run script through Expert Useful features from KimIV

fxsaber 2018.01.30 15:13 #4

There are no technical limitations that do not allow to refine the library to a cross-platform state - to work in MT4 as well.

fxsaber 2018.02.07 20:02 #5

Forum on trading, automated trading systems and testing trading strategies

Managing Expert Advisors through a global algorithm

Totosha16, 2018.02.07 18:57

I am currently trying to solve a simple problem using your library, which boils down to the following: close all Expert Advisors on all charts except the current one (the one from which the ExpertRemove script is run. Can you tell me how to do it?

#include <fxsaber\Expert.mqh> // https://www.mql5.com/en/code/19003

void OnStart()
{    
  const long CurrentChart = ChartID();  
  long Chart = ChartFirst();

  while (Chart != -1)
  {
    if (Chart != CurrentChart)
      EXPERT::Remove(Chart);

    Chart = ChartNext(Chart);
  }
}

Zigzag indicators Any rookie question, so Libraries: MultiTester

fxsaber 2018.02.09 12:49 #6

Forum on trading, automated trading systems and testing trading strategies

Errors, bugs, questions

Vladislav Andruschenko, 2018.02.09 10:14 AM

How to get the list of external variables inside the Expert Advisor? so that I don't have to list them in the array repeatedly? i.e. when setting it on a chart, the Expert Advisor reads itself and looks at its external settings.

Forum on trading, automated trading systems and testing trading strategies.

Errors, bugs, questions

fxsaber, 2018.02.09 12:44 pm.

#include <fxsaber\Expert.mqh> // https://www.mql5.com/en/code/19003

input string Input1 = "Hello World!";
input int Input2 = 123;

string GetExpertData( const ulong Chart = 0 ) 
{ 
  string Str = NULL; 

  MqlParam Parameters[]; 
  string Names[]; 

  if (EXPERT::Parameters(Chart, Parameters, Names)) 
  { 
    Str += "\n" + ChartSymbol(Chart) + " " + EnumToString(ChartPeriod(Chart)) + " " + Parameters[0].string_value + "\n"; 

    const int Amount = ArraySize(Names); 

    for (int i = 0; i < Amount; i++) 
      Str += (string)i + ": "+ Names[i] + " = " + Parameters[i + 1].string_value + "\n"; 
  } 

  return(Str); 
}

void OnInit()
{
  Print(GetExpertData());
}

Result

0: Input1 = Hello World!
1: Input2 = 123

or like this

#include <fxsaber\Expert.mqh> // https://www.mql5.com/en/code/19003

input string Input1 = "Hello World!";
input int Input2 = 123;

void OnInit()
{
  MqlParam Parameters[];
  string Names[];   
  
  if (EXPERT::Parameters(0, Parameters, Names))
    ArrayPrint(Parameters);
}

Result

    [type] [integer_value] [double_value]      [string_value]
[0]    ...               0        0.00000 "Experts\Test2.ex5"
[1]    ...               0        0.00000 "Hello World!"     
[2]    ...             123      123.00000 "123"

Errors, bugs, questions Indicators: Setka (grid) Experts: Diff_TF_MA_EA

fxsaber 2018.02.23 00:38 #7

Forum on trading, automated trading systems and testing trading strategies

Errors, bugs, questions

fxsaber, 2018.02.22 23:53

Playing a sound file of any duration from the indicator.

Scripts\PlaySound.mq5 script.

#include <GlobalVariables.mqh> // https://www.mql5.com/ru/forum/189649#comment_4854618

void OnStart()
{
  const string SoundName = "SOUND";

  if (GlobalVariableCheck(SoundName))
  {
    PlaySound(_GlobalVariableGet<string>(SoundName));
  
    _GlobalVariableDel(SoundName);
  }
}

Indicator

#property indicator_chart_window

#property indicator_buffers 0
#property indicator_plots indicator_buffers

#include <fxsaber\Expert.mqh>  // https://www.mql5.com/en/code/19003
#include <GlobalVariables.mqh> // https://www.mql5.com/ru/forum/189649#comment_4854618

class PLAYER
{
public:
  const string Name;
  const long Chart;
  const long chartID;
  
  PLAYER( const long iChart = 0 ) : Name(__FILE__), Chart(iChart ? iChart : ::ChartID()),
                                    chartID(::ObjectCreate(this.Chart, this.Name, OBJ_CHART, 0, 0, 0)   &&
                                            ::ObjectSetInteger(this.Chart, this.Name, OBJPROP_XSIZE, 0) &&
                                            ::ObjectSetInteger(this.Chart, this.Name, OBJPROP_YSIZE, 0) ?
                                            ::ObjectGetInteger(this.Chart, this.Name, OBJPROP_CHART_ID) : this.Chart)
  {
  }
  
  ~PLAYER()
  {
    if (this.chartID != this.Chart)
      ::ObjectDelete(this.Chart, this.Name);
  }
  
  void PlaySound( string FileName, const string ScriptName = "Scripts\\PlaySound.ex5" ) const
  {
    static const string SoundName = "SOUND";
    
    if (_GlobalVariableSet(SoundName, FileName))
    {
      MqlParam Params[1];
      
      Params[0].string_value = ScriptName;
      
      if (!EXPERT::Run(this.chartID, Params))      
        _GlobalVariableDel(SoundName);
    }    
  }
};

int OnCalculate( const int rates_total , const int prev_calculated, const int, const double& [] )
{  
  if (!prev_calculated)
  {
    const PLAYER Player;
    
    Player.PlaySound("email.wav");
  }

  return(rates_total);
}

Andrey Khatimlianskii 2018.02.24 00:47 #8

MT4, as it turned out, is missing much more than FileSave and FileLoad (which are written in 3 lines each):

No CHART_EXPERT_NAME (and nothing to replace it with, except after fixing all the other nuances - the name tag).
Frontal FileLoad is not suitable, as far as I understand, because of ANSI-encoding of the saved template.
I had to write an analogue of TemplateToString, reading the file in text mode.
STRING_END must be empty, there is no "\r\n" in quadruple templates.
The <expert> tag in MT4 is also used for indicators, so even after all these edits, you can find out where the indicators are and where the EA is only by relying on the fact that the EA is specified last (and is it always so?). Well, and you need to get to it.

In general, a very necessary and convenient thing, thank you for the implementation!

Questions on OOP in Any questions from newcomers [ARCHIVE!] Any rookie question,

fxsaber 2018.03.06 18:53 #9

Andrey Khatimlianskii:

The <expert> tag in MT4 is also used for indicators, so even after all these edits, you can only find out where the indicators are and where the Expert Advisor is by relying on the fact that the Expert Advisor is specified last (and is it always so?). Well, and you need to get to it.

This source code may help to understand the question.

Forum on trading, automated trading systems and testing trading strategies.

How to find out the current colour of the indicator line in an indicator?

fxsaber, 2017.05.12 13:45

#property strict

#property indicator_chart_window
#property indicator_buffers 2

#define  PATH "MQL4\\indicators\\"

#include <TypeToBytes.mqh> // https://www.mql5.com/en/code/16280

string GetIndicatorName( void )
{
  const string StrName = ::MQLInfoString(MQL_PROGRAM_PATH);
  const int Pos = ::StringFind(StrName, PATH) + ::StringLen(PATH);
  
  return(::StringSubstr(StrName, Pos, ::StringLen(StrName) - Pos - 4));
}

void SeekToString( const int handle, const string Str )
{
  while (!::FileIsEnding(handle))
    if (::FileReadString(handle) == Str)
      break;
  
  return;
}  

struct BUFFER_STRUCT
{
  int Shift;
  int Type;
  color Color;
  ENUM_LINE_STYLE Style;
  int Width;
};

const BUFFER_STRUCT GetBufferProperties( const uint Num = 0, const bool FlagSave = true )
{
  BUFFER_STRUCT Res = {0};
  
  const string FileName = ::WindowExpertName() + ".tpl";

  if (FlagSave ? ::ChartSaveTemplate(0, "..\\MQL4\\Files\\" + FileName) : true)
  {
    const int handle = ::FileOpen(FileName, ::FILE_READ|::FILE_CSV);

    if (handle > 0)
    {
      ::SeekToString(handle, "name=" + ::GetIndicatorName());
      
      if (Num == 0)
        ::SeekToString(handle, "</expert>");
      else
      {
        const string TmpStr = "weight_" + (string)(Num - 1);
        
        while (!::FileIsEnding(handle))
          if (::StringFind(::FileReadString(handle), TmpStr) == 0)
            break;
      }
            
      if (!::FileIsEnding(handle))
      {
        static const string Property[] = {"shift", "draw", "color", "style", "weight"};
        const string StrNum = "_" + (string)Num + "=";
              
        for (int i = 0; i < ::ArraySize(Property); i++)
          _W(Res)[i * sizeof(int)] = (int)::StringToInteger(::StringSubstr(::FileReadString(handle), ::StringLen(Property[i] + StrNum)));
      }
      
      ::FileClose(handle);
    }
  }
  
  return(Res);
}  

void OnInit()
{  
  string Str = "Colors:";
  
  for (int i = 0; i < indicator_buffers; i++)
    Str += " " + (string)i + "-" + (string)::GetBufferProperties(i).Color;
    
  Alert(Str);
}

void start()
{
}

Features of the mql5 Unsupported filling mode Experts: SyncChart

Andrey Khatimlianskii 2018.03.07 03:10 #10

fxsaber:

This source may help to understand the issue.

Thank you! As always, a bit more complicated than I'd like ;)

Your codes have one undeniable advantage - they can be taken and used. But it is quite difficult to tweak anything in them, that's a disadvantage.

mlq4 or mlq5 for Martin plus loci Machine learning in trading: