Fragen von Anfängern MQL5 MT5 MetaTrader 5 - Seite 1278

[Konstantin Nikitin]

Kira27:

(dc)) Die letzten Antworten auf die Fragen waren sehr hilfreich für das Verständnis des SB-Geräts.

Variable -- *Position. Sie ist rot markiert. Ist es nur eine Variable mit diesem Namen oder hat * eine Bedeutung? Es wird dieses Trailing kompiliert und enthält #include

Woher kommt sie, wurde sie irgendwo deklariert?) Als nächstes, übrigens nicht weniger interessant, was ist das - double &sl?

Lesen Sie erst einmal dieFunktionen. Es geht um Variablen in Funktionsdeklarationen.

Und fügen Sie auch den Code korrekt mit der Schaltfläche

[pit84]

Können Sie mir bitte sagen, was das Problem sein könnte? Ich setze einen EA auf einen Chart, er geht nicht rein, der Expert Advisor schreibt das:

2021.01.24 22:11:44.019 Nova V6 (EURUSD,H1) cannot load custom indicator 'Standard Deviation smoothing' [4802]
2021.01.24 22:11:44.020 Nova V6 (EURUSD,H1) Failed to create handle of the iCustom indicator for the symbol EURUSD/PERIOD_H1, error code 4802

Im Protokoll steht dies:

2021.01.24 22:18:04.506 Experts expert Nova V6 (EURUSD,H1) loaded successfully
2021.01.24 22:18:07.274 Experts initializing of Nova V6 (EURUSD,H1) failed with code 1
2021.01.24 22:18:07.288 Experts expert Nova V6 (EURUSD,H1) removed

[Vitaly Muzichenko]

pit84:

Können Sie mir bitte sagen, was das Problem sein könnte? Ich setze einen EA auf einen Chart, er geht nicht rein, der Expert Advisor schreibt das:

In meinem Tagebuch steht dies:

Es gibt keinen Indikator" Glättung derStandardabweichung " im Ordner "Indikator".

[Vladimir Karputov]

pit84:

Können Sie mir bitte sagen, was das Problem sein könnte? Ich setze einen EA auf einen Chart, er geht nicht rein, der Expert Advisor schreibt das:

Im Protokoll steht dies:

Kein benutzerdefinierter Indikator.

[pit84]

Das Interessanteste ist, dass es einen Indikator gibt, der ohne Probleme auf einem Chart platziert werden kann, aber der Expert Advisor will nicht

[Vladimir Karputov]

pit84:

Das Interessanteste ist, dass es einen Indikator und es geht auf den Chart ohne Probleme, aber die EA will nicht zu

Lesen Sie genau: An der Stelle, die Sie angeben, gibt es keinen Indikator.

Fügen Sie Ihren MQL5-Code über die Schaltfläche ein und fügen Sie ein Bildschirmfoto aus dem Windows Explorer ein, um das Vorhandensein des Indikators zu beweisen.

[Vladimir Karputov]

BillionerClub:

Nicht weit von der Kasse, aus dem Spaziergang, gleichen Fehler, sagen Sie mir, was der Fehler im Code ist?

Alle Telepathen sind im Urlaub. Leider gibt es niemanden, der Ihre Gedanken lesen kann.

[[Gelöscht]]

BillionerClub:

Nicht weit von der Kasse, von gehen, gleichen Fehler, sagen Sie mir, was ist der Fehler in den Code?

Von, weit, aus, zu, sagen, gehen, mit - HZ )))))))))))

[BillionerClub]

Vladimir Karputov:

Alle Telepathen sind im Urlaub. Leider gibt es niemanden, der Ihre Gedanken lesen kann.

Im Grunde suche ich selbst nach Fehlern in meinem Code, aber da es hier diskutiert wird, habe ich beschlossen, es Ihnen zu geben, vielleicht wird es auch diskutiert, vielleicht wird mein Code auch gelöst

[pit84]

//+------------------------------------------------------------------+
//|                                 Standard Deviation smoothing.mq5 |
//|                              Copyright © 2018, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2018, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.000"
#include <MovingAverages.mqh>
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   1
//--- the iStdDev plot
#property indicator_label1  "StdDev smoothing"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrGreenYellow
#property indicator_style1  STYLE_SOLID
#property indicator_width1  2
//--- input parameters 
input int                  Inp_StdDev_ma_period    = 20;          // period of averaging
input int                  Inp_StdDev_ma_shift     = 0;           // shift
input ENUM_MA_METHOD       Inp_StdDev_ma_method    = MODE_SMA;    // type of smoothing
input ENUM_APPLIED_PRICE   Inp_StdDev_applied_price= PRICE_CLOSE; // type of price
//--- indicator buffer 
double StdDevBuffer[];
double StdDevBufferTemp[];
int    handle_iStdDev;        // variable for storing the handle_iStdDev of the iStdDev indicator 
string short_name;            // name of the indicator on a chart 
int    bars_calculated=0;     // we will keep the number of values in the Standard Deviation indicator 
int    m_weightsum;
//+------------------------------------------------------------------+ 
//| Custom indicator initialization function                         | 
//+------------------------------------------------------------------+ 
int OnInit()
  {
   m_weightsum=0;
//--- assignment of array to indicator buffer 
   SetIndexBuffer(0,StdDevBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,StdDevBufferTemp,INDICATOR_CALCULATIONS);
//--- set shift 
   PlotIndexSetInteger(0,PLOT_SHIFT,Inp_StdDev_ma_shift);
//--- create handle_iStdDev of the indicator iStdDev   
   handle_iStdDev=iStdDev(Symbol(),Period(),Inp_StdDev_ma_period,
                          Inp_StdDev_ma_shift,Inp_StdDev_ma_method,Inp_StdDev_applied_price);
//--- if the handle_iStdDev is not created 
   if(handle_iStdDev==INVALID_HANDLE)
     {
      //--- tell about the failure and output the error code 
      PrintFormat("Failed to create handle_iStdDev of the iStdDev indicator for the symbol %s/%s, error code %d",
                  Symbol(),
                  EnumToString(Period()),
                  GetLastError());
      //--- the indicator is stopped early 
      return(INIT_FAILED);
     }
//--- show the symbol/timeframe the Standard Deviation indicator is calculated for 
   short_name=StringFormat("StdDev smoothing(%d)",Inp_StdDev_ma_period);
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- normal initialization of the indicator   
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+ 
//| Custom indicator iteration function                              | 
//+------------------------------------------------------------------+ 
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- number of values copied from the iStdDev indicator 
   int values_to_copy;
//--- determine the number of values calculated in the indicator 
   int calculated=BarsCalculated(handle_iStdDev);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());
      return(0);
     }
//--- if it is the first start of calculation of the indicator or if the number of values in the iStdDev indicator changed 
//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history) 
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- if the iStdDevBuffer array is greater than the number of values in the iStdDev indicator for symbol/period, then we don't copy everything  
      //--- otherwise, we copy less than the size of indicator buffers 
      if(calculated>rates_total)
         values_to_copy=rates_total;
      else
         values_to_copy=calculated;
     }
   else
     {
      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate() 
      //--- for calculation not more than one bar is added 
      values_to_copy=(rates_total-prev_calculated)+1;
     }
//--- fill the array with values of the Standard Deviation indicator 
//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation 
   if(!FillArrayFromBuffer(StdDevBufferTemp,Inp_StdDev_ma_shift,handle_iStdDev,values_to_copy))
      return(0);
   if(prev_calculated==0)
      for(int i=0;i<Inp_StdDev_ma_period-1;i++)
         StdDevBufferTemp[i]=0.0;
   switch(Inp_StdDev_ma_method)
     {
      case  MODE_SMA:
         SimpleMAOnBuffer(rates_total,prev_calculated,0,3,StdDevBufferTemp,StdDevBuffer);
         break;
      case  MODE_EMA:
         ExponentialMAOnBuffer(rates_total,prev_calculated,0,3,StdDevBufferTemp,StdDevBuffer);
         break;
      case  MODE_SMMA:
         SmoothedMAOnBuffer(rates_total,prev_calculated,0,3,StdDevBufferTemp,StdDevBuffer);
         break;
      default:
         LinearWeightedMAOnBuffer(rates_total,prev_calculated,0,9,StdDevBufferTemp,StdDevBuffer,m_weightsum);
         break;
     }
//--- memorize the number of values in the Standard Deviation indicator 
   bars_calculated=calculated;
//--- return the prev_calculated value for the next call 
   return(rates_total);
  }
//+------------------------------------------------------------------+ 
//| Filling indicator buffers from the iStdDev indicator             | 
//+------------------------------------------------------------------+ 
bool FillArrayFromBuffer(double &std_buffer[],  // indicator buffer of the Standard Deviation line 
                         int std_shift,         // shift of the Standard Deviation line 
                         int ind_handle,        // handle_iStdDev of the iStdDev indicator 
                         int amount             // number of copied values 
                         )
  {
//--- reset error code 
   ResetLastError();
//--- fill a part of the iStdDevBuffer array with values from the indicator buffer that has 0 index 
   if(CopyBuffer(ind_handle,0,-std_shift,amount,std_buffer)<0)
     {
      //--- if the copying fails, tell the error code 
      PrintFormat("Failed to copy data from the iStdDev indicator, error code %d",GetLastError());
      //--- quit with zero result - it means that the indicator is considered as not calculated 
      return(false);
     }
//--- everything is fine 
   return(true);
  }
//+------------------------------------------------------------------+ 
//| Indicator deinitialization function                              | 
//+------------------------------------------------------------------+ 
void OnDeinit(const int reason)
  {
//--- clear the chart after deleting the indicator 
   Comment("");
  }
//+------------------------------------------------------------------+

Vladimir Karputov:

Lesen Sie genau, wo Sie darauf hinweisen, dass es keinen Indikator gibt.

Fügen Sie Ihren MQL5-Code über die Schaltfläche ein und fügen Sie ein Bildschirmfoto aus dem Windows Explorer ein, um das Vorhandensein des Indikators zu beweisen.