程序库: Expert - 页 2

[Алексей Тарабанов]

fxsaber:

哦，那些俄罗斯黑客....好吧，为什么要在你有点小麻烦的时候阻止所有专家呢？

顺便说一句，你还有一个错误。静态不工作。

[fxsaber]

Алексей Тарабанов:

对了，你还有一个错误。静态不工作。

我在这里没有看到错误

关于交易、自动交易系统和测试交易策略的论坛。

来自初学者的问题 MQL5 MT5 MetaTrader 5

fxsaber, 2018.08.02 17:09

// 如果触发 SL，则停止所有智能交易系统。

#include <MT4Orders.mqh>      //https://www.mql5.com/zh/code/16006
#include <fxsaber\Expert.mqh> //https://www.mql5.com/zh/code/19003

void OnTrade()
{
  static int PrevTotal = OrdersHistoryTotal();
  const int Total = OrdersHistoryTotal();
  
  for (int i = Total - 1; i >= PrevTotal; i--)
    if (OrderSelect(i, SELECT_BY_POS, MODE_HISTORY) && (OrderCloseReason() == DEAL_REASON_SL))
    {
      long Chart = ChartFirst();
  
      while (Chart != -1)
      {
        if ((Chart != ChartID()) && EXPERT::Is(Chart))
          EXPERT::Remove(Chart);
  
        Chart = ChartNext(Chart);
      }

      break;
    }        
    
  PrevTotal = Total;
}

[fxsaber]

// 该指标切断了所有通过智能交易系统进行交易的尝试。它只允许用手进行交易。
// 为了避免在终端运行时关闭指示灯，指示灯处于不可见模式。

#property indicator_chart_window
#property indicator_buffers 0
#property indicator_plots   0

#include <Symbol.mqh>         //https://www.mql5.com/zh/code/18855
#include <fxsaber\Expert.mqh> //https://www.mql5.com/zh/code/19003

void MyAlert( const string Str )
{
  string StrArray[];
  
  for (int i = StringSplit(Str, '\n', StrArray) - 1; i >= 0; i--)
    Alert(StrArray[i]);
}

bool NextOnCalculate( const string SymbName = NULL )
{
  const SYMBOL Symb(SymbName);
  
  MqlRates Rates[1] = {0};
  Rates[0].time = TimeCurrent();
          
  return(Symb.IsCustom() ? Symb.CloneRates(Rates) : ChartSetSymbolPeriod(0, _Symbol, _Period));
}

const SYMBOL SymbTimer("Timer");

void OnInit()
{
  if (_Symbol == SymbTimer.Name)
    ChartIndicatorGet(0, 0, ChartIndicatorName(0, 0, 0));    
  else if (SymbTimer.IsExist() && SymbTimer.On() && NextOnCalculate(SymbTimer.Name))
  {
    iCustom(SymbTimer.Name, PERIOD_CURRENT,
            ".." + StringSubstr(MQLInfoString(MQL_PROGRAM_PATH), StringLen(TerminalInfoString(TERMINAL_PATH)) + 5));
    
    SymbTimer.Off(); 
  }
}

string GetExpertData( const ulong Chart = 0 )
{
  string Str = NULL;

  MqlParam Parameters[];
  string Names[];

  if (EXPERT::Parameters(Chart, Parameters, Names))
  {
    Str += "\n" + ::ChartSymbol(Chart) + " " + ::EnumToString(::ChartPeriod(Chart)) + " " + Parameters[0].string_value + "\n";

    const int Amount = ::ArraySize(Names);

    for (int i = 0; i < Amount; i++)
      Str += (string)i + ": "+ Names[i] + " = " + Parameters[i + 1].string_value + "\n";
  }

  return(Str);
}

void Active( const int AlertTime = 5 )
{
  static const uint StartTime = GetTickCount();
  static uint PrevInterval = 0;
  const uint Interval = (GetTickCount() - StartTime) / 1000;
  const string Str = MQLInfoString(MQL_PROGRAM_NAME) + ": I've been watching you for " + TimeToString(Interval, TIME_SECONDS);
    
  long Chart = ChartFirst();

  if (Chart != -1)  
    do
    {
      if (EXPERT::Is(Chart))
        MyAlert(GetExpertData(Chart) + "Removed - " + (string)EXPERT::Remove(Chart));
        
      ChartSetString(Chart, CHART_COMMENT,  Str);
      ChartRedraw(Chart);
    }
    while ((Chart = ChartNext(Chart)) != -1);    
  else if (!(Interval % AlertTime) && (Interval != PrevInterval))
  {
    MyAlert(Str);
    
    PrevInterval = Interval;
  }
}

int OnCalculate( const int, const int, const int, const double &[] )
{
  static int i = 0;
  
  if ((_Symbol == SymbTimer.Name) && NextOnCalculate())
    Active();
  else if (i++ > 0)
    ChartIndicatorDelete(0, 0, ChartIndicatorName(0, 0, ChartIndicatorsTotal(0, 0) - 1));           
    
  return(0);
}

ZY 如果重新启动终端，有时可能会遇到（MT5 build 1881）挂起进程的情况。可以通过强制删除相应进程 terminal64.exe，并删除 MetaTrader 5\Bases\ustomC\history\Timer\*.hcc 来解决。

[Алексей Тарабанов]

谢谢您的帮助。太棒了

[fxsaber]

作者在文章 中非常详细地强调了该图书馆成果的细微差别。推荐阅读。

[Sergey Eremin]

Andrey Khatimlianskii:

MT4 除了 FileSave 和 FileLoad（各写了 3 行）之外，还缺少很多：

1. 没有 CHART_EXPERT_NAME（除了在解决了所有其他细微差别之后--名称标记--之外，没有任何东西可以替代它）。

在我的项目中，我是这样解决的（使用 "name "标记）：

      void Update()
      {                
         long chartId = ChartFirst();
         
         while(chartId > 0)
         {
            #ifdef __MQL4__
            string chartEAName = GetChartEAName(chartId);
            #endif 
            
            #ifdef __MQL5__     
            string chartEAName = ChartGetString(chartId, CHART_EXPERT_NAME);
            #endif
            
            if(chartEAName == m_eaName)
            {
               // ...
            }
            
            chartId = ChartNext(chartId);
         }
      }
      
      #ifdef __MQL4__
      string GetChartEAName(const long chartId)
      {
         if(!SaveTemplate(chartId))
         {
            return "";
         }
         
         string result = "";
         
         int handle = FileOpen("ea_name_checking.tpl",FILE_TXT|FILE_READ);
         if(handle == INVALID_HANDLE)
         {
            Print
            (
               "Error in ", __FILE__,", line ", __LINE__,
               ": can't open template file 'ea_name_checking.tpl', error code = ", GetLastError()
            );
         }
         else
         {
            string text = "";
            
            while(!FileIsEnding(handle)) 
            { 
               text = text + FileReadString(handle, (uint)FileSize(handle)) +"\r\n";
            }
            
            SubstringParser eaSectionTextParser(text, "<expert>", "</expert>");            
            string eaSectionText = eaSectionTextParser.Get();
            
            if(StringTrimLeft(StringTrimRight(eaSectionText)) != "")
            {
               SubstringParser eaNameParser(eaSectionText, "name=","\r\n");
               string eaName = StringTrimLeft(StringTrimRight(eaNameParser.Get()));
               
               if(eaName != "")               
               {
                  result = eaName;
               }
            }            
         }
         
         FileClose(handle);
         FileDelete("ea_name_checking.tpl");
         
         return result;
      }
      
      bool SaveTemplate(const long chartId)
      {
         ResetLastError();
         
         if(!ChartSaveTemplate(chartId, "\\Files\\ea_name_checking.tpl"))
         {            
            Print
            (
               "Error in ", __FILE__,", line ", __LINE__,
               ": can't save template to the file 'ea_name_checking.tpl', error code = ", GetLastError()
            );
            
            return false;
         }
         
         return true;
      }      
      #endif

其中 SubstringParser 有这样的代码：

#property strict

class SubstringParser
{
   private:
      string m_text;
      string m_subStart;
      string m_subEnd;
   
   public:
      SubstringParser(const string text, const string subStart, const string subEnd)
      {
         m_text = text;
         m_subStart = subStart;
         m_subEnd = subEnd;
      }
      
      string Get()
      {
         int startPhraseLengt = StringLen(m_subStart);
         int startPos = StringFind(m_text, m_subStart) + startPhraseLengt;
         int endPos = StringFind(m_text, m_subEnd, startPos);
                 
         if(startPos >= startPhraseLengt && endPos > startPos)
         {
            return StringSubstr(m_text, startPos, endPos - startPos);      
         }
         else
         {
            return "";
         }
      }
};

即保存图表模板，读取它，解析它并找到智能交易系统的名称。这仍然是一根拐杖，但目前（大约几个月内）运行良好。我认为，如果使用的是普通硬盘，就不应该经常这样做（例如，每一个刻度）。我希望CHART_EXPERT_NAME 有一天能出现在 MQL4 中。

[Stanislav Korotky]

会有支持运行脚本的新版本吗？

[fxsaber]

Stanislav Korotky:
会有支持运行脚本的新版本吗？

这个示例 不起作用吗？

[Stanislav Korotky]

fxsaber:

这个示例 不起作用？

它与我的使用情况不太相似。关于这个示例的主要问题是，如果在脚本参数中指定音乐文件名，而不是通过全局变量抛出，会发生什么情况？我可以把我的项目通过私人信息发给你。

[fxsaber]

Stanislav Korotky:

这与我的用例不太相似。关于该示例的主要问题是，如果在脚本参数中指定音乐文件名，而不是通过全局变量抛出，会发生什么情况？

我完全不记得原因了，但输入参数的选项马上就被提出来了。既然示例如此曲折，肯定是 MT5 的限制。