Experts: MQL5 Programming for Traders – 책의 소스 코드. 파트 7 - 페이지 2

새 코멘트
 
Denis Kirichenko #:

일반적으로 교과서의 경우 괄호 안에 쓰는 것이 좋습니다:

모든 연산자는 @= 형식의 연산자(여기서 강아지는 모든 연산자의 기호를 의미)는 항상 오른쪽 피연산자에 대해 실행되며 연산이 실행되기 전에 완전히 카운트됩니다. 이에 대해서는 2부의 수정 연산에서 다룹니다.

마진 계산 파일은 6부에서 설명하며, 여기서는 이전 부분을 숙지했다고 가정합니다. 책의 후반부로 갈수록 복잡성이 증가하지만, 저는 이에 대해 이의를 제기하지 않으므로 다음 섹션에서 이전 섹션의 큰 개념과 원리를 빌딩 블록으로 사용했지만 (기억을 되살리기 위해) 작은 것에는 언급하지 않으려고 노력했습니다.

 
Stanislav Korotky #:

...책의 후반부로 갈수록 복잡성이 증가하는데, 이 점에 대해서는 이견이 없으므로 이전 섹션의 큰 개념과 원리에 대해서는 다음 섹션에서 (기억을 되살리기 위해) 빌딩 블록으로 사용했던 부분을 참조하려고 했지만, 그런 작은 것들은 참조하지 않으려 했습니다.

스타니슬라프, 저는 당신과 달리 프로그래밍 수준이 좀 더 겸손합니다. 디버거에서 확인하기 쉽도록 코드를 작성하려고 노력합니다. 그래서 저는 삼항 연산자를 자주 사용하지 않습니다. 그리고 만약 사용한다면 괄호와 함께 사용합니다... 삼항연산자 여러 개를 괄호 안에 넣어서 쓰는 능숙한 분들도 계십니다. 이것은 제 동료 fxsaber의 매크로 프로그래밍 스타일에 가까운 것입니다. 아마도 모든 접근 방식에는 생명권이있을 것입니다. 그리고 그것은 이미 취향의 문제입니다 ...

튜토리얼에 큰 존경과 존경을 표합니다! 몇 가지 흥미로운 사항은 문서보다 더 자세히 설명되어 있습니다.

 
Aleksandr Slavskii #:

결국 볼륨이 3을 초과하면 여전히 마진을 잘못 계산하기 때문에 결국에는 거의 소용이 없습니다.

10개의 계약에 대한 증거금 계산.

확인을 위해 스크립트를 첨부해 주세요. 이제 전체 시장 개요에서 실행해 보았는데 거래량에 관계없이 표준 기능과 일치합니다.

 
Denis Kirichenko #:

그리고 컴파일러는 열받았습니다:

아마도 컴파일러에서 무언가 변경된 것 같습니다. 책이 출시될 당시에는 데모 목적으로 고의적인 불규칙성이 있는 경우를 제외하고는 모든 소스가 경고나 오류 없이 컴파일되었습니다.

 
Denis Kirichenko #:

저는 디버거에서 확인하기 쉽도록 코드를 작성하려고 노력합니다. 그래서 저는 삼항 연산자를 자주 사용하지 않습니다. 그리고 만약 사용한다면 괄호 안에....

동감입니다. 저도 간단한 경우를 제외하고는 이 규칙을 고수하지만 여기에는 모든 사람이 자신만의 단순함의 장벽이 있습니다. 코드의 가독성은 개별적으로 처리되며 일반적으로 "한 줄에 모두"와 "각 토큰을 별도의 줄에"접근 방식 사이의 "황금 평균"을 찾습니다. 대괄호도 마찬가지입니다. 소프트웨어 회사에는 일반적으로 소스 코드 레이아웃에 대한 일련의 규칙이 있지만, 이 경우에는 규칙이 없었습니다.

 
경제 캘린더 읽기 및 CSV로 내보내기와 관련된 버그 수정 및 개선 사항이 코드베이스에 게시되었습니다. 특히, 대부분 정렬된 큰 배열(일반적으로 MQL5 달력 API에서 수신)의 경우 정렬 알고리즘이 수정되어 속도 저하와 스택 오버플로가 제거되었습니다.
Economic Calendar CSV
Economic Calendar CSV
  • www.mql5.com
This script saves a predefined set of economic events from the MetaTrader's built-in economic calendar into CSV file.
 
Stanislav Korotky #:

확인을 위해 스크립트를 첨부해 주세요. 이제 전체 시장 개요에서 실행해 보았는데 볼륨에 관계없이 표준 기능과 일치합니다.

오, 이런. 그 메시지를 못 봤다니 믿을 수가 없네요. 오, 이런.

사실 저는 아무것도 바뀐 게 없습니다.

메타쿼트 서버, 터미널 버전 4420입니다.

코드는 다음과 같습니다.

#include "MarginProfitMeter.mqh"
//+------------------------------------------------------------------+
int OnInit(void)
  {
   EventSetTimer(1);
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
void OnTimer()
  {
   double margin = 0;
   double volume = 10;
   ENUM_ORDER_TYPE type = ORDER_TYPE_BUY;
   double price = SymbolInfoDouble(_Symbol, SYMBOL_ASK);
   if(_OrderCalcMargin(type, _Symbol, volume, price, margin))
      Print("Symbol ", _Symbol, "; volume ", volume, "; MarginProfitMeter margin = ", margin);

   margin = 0;
   if(OrderCalcMargin(type, _Symbol, volume, price, margin))
      Print("Symbol ", _Symbol, "; volume ", volume, "; OrderCalcMargin margin = ", margin);
  }
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   EventKillTimer();
  }
//+------------------------------------------------------------------+

결과는 다음과 같습니다.

18:53:40.877    11 (EURUSD,H1)  Symbol EURUSD; volume 10.0; MarginProfitMeter margin = 10421.6
18:53:40.877    11 (EURUSD,H1)  Symbol EURUSD; volume 10.0; OrderCalcMargin margin = 23264.8

누군가 잘못 계산하고 있습니다.


네임스페이스 MPM을 잘못 제거했을 수 있습니다. 그것이 무엇이고 왜 필요한지 모르겠지만 EA를 컴파일 할 수 없었습니다.

실제로 네임스페이스 MPM 줄을 제거하고 그 뒤에 중괄호를 붙이고 OrderCalcMargin으로 이름을 바꾸고 밑줄을 추가했습니다.

일반적으로 파일은 이 형식으로 컴파일됩니다. 이것이 오류일 가능성이 있나요?

//+------------------------------------------------------------------+
//|MarginProfitMeter.mqh |
//|저작권 (c) 2018-2022, Marketeer |
//| https://www.mql5.com/en/users/marketeer |
마진, 잠재적 수익/손실을 계산하는 함수 집합 //||
//| 포인트 가치 및 전환율.|
//+------------------------------------------------------------------+
// 인디케이터에서 허용되지 않는 내장 주문 계산 마진(OrderCalcMargin)과 유사합니다.
bool _OrderCalcMargin(const ENUM_ORDER_TYPE action, const string symbol,
                     double volume, double price, double &margin)
  {
   double marginInit, marginMain;
   MqlTick ticks;

// 주어진 매개변수 확인
   if((action != ORDER_TYPE_BUY && action != ORDER_TYPE_SELL) || volume < 0 || price < 0)
      return false;

// 수식에 사용된 모든 프로퍼티를 요청합니다.
   if(!SymbolInfoTick(symbol, ticks))
      return false;
   if(!SymbolInfoMarginRate(symbol, action, marginInit, marginMain))
      return false;
   const double contract = SymbolInfoDouble(symbol, SYMBOL_TRADE_CONTRACT_SIZE);
   long leverage = AccountInfoInteger(ACCOUNT_LEVERAGE);
   if(volume == 0)
      volume = SymbolInfoDouble(symbol, SYMBOL_VOLUME_MIN);
   if(price == 0)
      price = action == ORDER_TYPE_BUY ? ticks.ask : ticks.bid;

   if(margin == DBL_MAX)
      marginInit = marginMain;
   margin = 0;

   const ENUM_SYMBOL_CALC_MODE m = (ENUM_SYMBOL_CALC_MODE)SymbolInfoInteger(symbol, SYMBOL_TRADE_CALC_MODE);

   switch(m)
     {
      case SYMBOL_CALC_MODE_FOREX_NO_LEVERAGE:
         leverage = 1;

      case SYMBOL_CALC_MODE_FOREX:
         margin = volume * contract / leverage * marginInit;
         break;

      case SYMBOL_CALC_MODE_CFD:
         margin = volume * contract * price * marginInit;
         break;

      case SYMBOL_CALC_MODE_CFDINDEX:
         margin = volume * contract * price * SymbolInfoDouble(symbol, SYMBOL_TRADE_TICK_VALUE)
                  / SymbolInfoDouble(symbol, SYMBOL_TRADE_TICK_SIZE) * marginInit;
         break;

      case SYMBOL_CALC_MODE_CFDLEVERAGE:
         margin = volume * contract * price / leverage * marginInit;
         break;

      case SYMBOL_CALC_MODE_EXCH_STOCKS:
      case SYMBOL_CALC_MODE_EXCH_STOCKS_MOEX:
         if(price == 0)
            price = ticks.last;
         margin = volume * contract * price * marginInit;
         break;

      case SYMBOL_CALC_MODE_FUTURES:
      case SYMBOL_CALC_MODE_EXCH_FUTURES:
      case SYMBOL_CALC_MODE_EXCH_FUTURES_FORTS:
         margin = volume * SymbolInfoDouble(symbol, SYMBOL_MARGIN_INITIAL) * marginInit;
         break;
      default:
         PrintFormat("Unsupported symbol %s trade mode: %s", symbol, EnumToString(m));
     }

   string account = AccountInfoString(ACCOUNT_CURRENCY);
   string current = SymbolInfoString(symbol, SYMBOL_CURRENCY_MARGIN);
   if(current != account)
     {
      if(!_Convert(current, account, action == ORDER_TYPE_SELL, margin))
         return false;
     }

   return true;
  }

// '현재' 및 '계정' 통화로 구성된 단일 빌드에 대해 사용 가능한 심볼 검색
int _FindExchangeRate(const string current, const string account, string &result)
  {
   for(int i = 0; i < SymbolsTotal(true); i++)
     {
      const string symbol = SymbolName(i, true);
      const ENUM_SYMBOL_CALC_MODE m = (ENUM_SYMBOL_CALC_MODE)SymbolInfoInteger(symbol, SYMBOL_TRADE_CALC_MODE);
      if(m == SYMBOL_CALC_MODE_FOREX || m == SYMBOL_CALC_MODE_FOREX_NO_LEVERAGE)
        {
         string base = SymbolInfoString(symbol, SYMBOL_CURRENCY_BASE);
         string profit = SymbolInfoString(symbol, SYMBOL_CURRENCY_PROFIT);
         if(base == current && profit == account)
           {
            result = symbol;
            return +1;
           }
         else
            if(base == account && profit == current)
              {
               result = symbol;
               return -1;
              }
        }
     }
   return 0;
  }

// 과거 특정 시점에 지정된 기호의 비율을 추정합니다.
double GetHistoricPrice(const string symbol, const datetime moment, const bool ask)
  {
   const int offset = iBarShift(symbol, _Period, moment);
// 참고: 아이클로즈는 거래소 심볼에 대해 입찰가 대신 최종가를 보유할 수 있습니다.
// 이 문제를 빠르게 처리할 수 있는 방법은 없으며, 틱 기록 분석만 가능합니다.
   return iClose(symbol, _Period, offset) +
          (ask ? iSpread(symbol, _Period, offset) * SymbolInfoDouble(symbol, SYMBOL_POINT) : 0);
  }

// _'현재' 금액을 '계정' 금액으로 변환합니다.
bool _Convert(const string current, const string account,
             const bool ask, double &margin, const datetime moment = 0)
  {
   string rate;
   int dir = _FindExchangeRate(current, account, rate);
   if(dir == +1)
     {
      margin *= moment == 0 ?
                SymbolInfoDouble(rate, ask ? SYMBOL_BID : SYMBOL_ASK) :
                GetHistoricPrice(rate, moment, ask);
     }
   else
      if(dir == -1)
        {
         margin /= moment == 0 ?
                   SymbolInfoDouble(rate, ask ? SYMBOL_ASK : SYMBOL_BID) :
                   GetHistoricPrice(rate, moment, ask);
        }
      else
        {
         static bool once = false;
         if(!once)
           {
            Print("Can't convert ", current, " -> ", account);
            once = true;
           }
        }
   return true;
  }

// 특정 심볼의 포인트 값(계정 통화)을 반환합니다.
double PointValue(const string symbol, const bool ask = false, const datetime moment = 0)
  {
   const double point = SymbolInfoDouble(symbol, SYMBOL_POINT);
   const double contract = SymbolInfoDouble(symbol, SYMBOL_TRADE_CONTRACT_SIZE);
   const ENUM_SYMBOL_CALC_MODE m = (ENUM_SYMBOL_CALC_MODE)SymbolInfoInteger(symbol, SYMBOL_TRADE_CALC_MODE);
   double result = 0;

   switch(m)
     {
      case SYMBOL_CALC_MODE_FOREX_NO_LEVERAGE:
      case SYMBOL_CALC_MODE_FOREX:
      case SYMBOL_CALC_MODE_CFD:
      case SYMBOL_CALC_MODE_CFDINDEX:
      case SYMBOL_CALC_MODE_CFDLEVERAGE:
      case SYMBOL_CALC_MODE_EXCH_STOCKS:
      case SYMBOL_CALC_MODE_EXCH_STOCKS_MOEX:
         result = point * contract;
         break;

      case SYMBOL_CALC_MODE_FUTURES:
      case SYMBOL_CALC_MODE_EXCH_FUTURES:
      case SYMBOL_CALC_MODE_EXCH_FUTURES_FORTS:
         result = point * SymbolInfoDouble(symbol, SYMBOL_TRADE_TICK_VALUE) / SymbolInfoDouble(symbol, SYMBOL_TRADE_TICK_SIZE);
         break;
      default:
         PrintFormat("Unsupported symbol %s trade mode: %s", symbol, EnumToString(m));
     }

   string account = AccountInfoString(ACCOUNT_CURRENCY);
   string current = SymbolInfoString(symbol, SYMBOL_CURRENCY_PROFIT);

   if(current != account)
     {
      if(!_Convert(current, account, ask, result, moment))
         return 0;
     }

   return result;
  }
//+------------------------------------------------------------------+
 
Aleksandr Slavskii #:

코드는 다음과 같습니다.

결과는 다음과 같습니다.

누군가 잘못 계산하고 있습니다.


2024년 초(즉, 이 책을 쓴 후) 빌드 4150에 대한 뉴스( https://www.metatrader5.com/en/releasenotes/terminal/2342)에서 찾을 수 있습니다.

거래량별 변동 마진

서버 설정 및 기호 사양 인터페이스에서 볼륨에 대한 여백 의존성을 추가했습니다.

MQL5에서 이러한 속성에 접근하는 방법을 찾지 못했습니다.

특정 브로커/상품에서는 이 플로팅 마진 설정이 활성화되지 않을 수 있으므로 MQ 데모에서 확인하지 않았을 때 차이점을 보지 못했습니다.

MetaTrader 5 build 4150: Trading report export and new machine learning methods in MQL5
MetaTrader 5 build 4150: Trading report export and new machine learning methods in MQL5
  • 2024.01.18
  • MetaQuotes
  • www.metatrader5.com
Added export of trading reports to HTML and PDF files. With this option, you can easily share your trading achievements with colleagues and investors. New export commands are available in the File menu and in the report menu. Added ability to save the current state of the Market Watch window to a CSV file. To do this, select Export in the...
 
Stanislav Korotky #:

서버 설정 및 심볼 사양 인터페이스에 볼륨 여백 종속성을 추가했습니다.

MQL5에서 이러한 속성으로 이동하는 방법을 찾지 못했습니다.

나도 검색했지만 찾지 못했습니다.)
나는 그것이 내 머리 속의 버그라고 생각했지만 그렇지 않은 것으로 밝혀졌습니다.
고마워요.
 

레나트 팻쿨린

MQL5에서 이러한 속성을 가져올 수 있는 기능을 추가할 계획이 있나요?

트레이딩, 자동매매 시스템, 트레이딩 전략 테스트에 관한 포럼

전문가 조언: 트레이더를 위한 MQL5 프로그래밍 - 책의 소스 코드. 파트 7

스타니슬라브 코로트키, 2024.11.23 20:26

2024년 초(즉, 책이 쓰여진 후) 빌드 4150에 대한 뉴스에서 발견한 내용입니다 - https://www.metatrader5.com/en/releasenotes/terminal/2342.

거래량별 변동 마진

서버 설정 및 기호 사양 인터페이스에서 볼륨에 대한 마진 종속성을 추가했습니다.

MQL5에서 이러한 속성에 접근하는 방법을 찾지 못했습니다.

특정 브로커/상품에서는 이 플로팅 마진 설정이 활성화되지 않을 수 있으므로 MQ 데모에서 확인하지 않았을 때 차이점을 보지 못했습니다.


12345
새 코멘트