Caratteristiche utili da KimIV - pagina 54

Nuovo commento
 

La funzione TakeProfitLastPos().

Questa funzione restituisce il livello di prezzo TakeProfit dell'ultima posizione aperta o -1. La funzione TakeProfitLastPos() accetta i seguenti parametri opzionali:

  • sy - Nome dello strumento. "" - qualsiasi simbolo, NULL - simbolo corrente. Il valore predefinito è "".
  • op - operazione commerciale. Valori validi: -1, OP_BUY, OP_SELL. Il valore predefinito è -1 - qualsiasi commercio.
  • mn - Identificatore commerciale, MagicNumber. Valore predefinito -1 - qualsiasi magia.
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 06.08.2008                                                     |
//|  Описание : Возвращает цену TakeProfit последней открытой позиций или -1.  |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double TakeProfitLastPos(string sy="", int op=-1, int mn=-1) {
  datetime t;
  double   r=-1;
  int      i, k=OrdersTotal();

  if ( sy=="0") sy=Symbol();
  for ( i=0; i< k; i++) {
    if (OrderSelect( i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()== sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if ( op<0 || OrderType()== op) {
            if ( mn<0 || OrderMagicNumber()== mn) {
              if ( t<OrderOpenTime()) {
                t=OrderOpenTime();
                r=OrderTakeProfit();
              }
            }
          }
        }
      }
    }
  }
  return( r);
}
Questa funzione può essere usata, per esempio, per determinare il livello di prezzo di TakeProfit dell'ultima posizione aperta per il successivo piazzamento di un ordine pendente a questo livello.
 
che ne dici di aprire il lotto "giusto" al momento giusto?
 
Potete dirmi se c'è un modo per cambiare la dimensione del lotto di un ordine in sospeso in MQL4?
 
sdgg >> :
Sapete se c'è un modo per cambiare la dimensione del lotto di un ordine in sospeso in MQL4?

No. Si cancella il vecchio ordine e se ne crea uno nuovo con il volume richiesto.

 
sdgg писал (а) >>
Potete dirmi se c'è un modo per cambiare il lotto di un ordine in sospeso in MQL4?

Gli sviluppatori non l'hanno fatto deliberatamente - per evitare problemi!

 

Si prega di consigliare come creare oggetti grafici in un EA che fa trading su due coppie di valute, che segnano su ogni grafico le posizioni di apertura e di chiusura per ogni coppia di valute. Un EA caricato su un singolo grafico creerà automaticamente questi segni solo su quel grafico. Forse c'è una tale funzione progettata per essere usata in EAs multivaluta?

 
RGT >> :

Si prega di consigliare come creare oggetti grafici in un EA che fa trading su due coppie di valute, che segnano su ogni grafico le posizioni di apertura e di chiusura per ogni coppia di valute. Un EA caricato su un singolo grafico creerà automaticamente questi segni solo su quel grafico. Forse c'è una tale funzione progettata per essere usata in EAs multivaluta?

Non esiste una tale funzione. Gli oggetti possono essere creati e gestiti solo sul grafico a cui l'EA è collegato.

 

Funzione TakeProfitLastClosePos().

Restituisce il livello di prezzo TakeProfit dell'ultima posizione chiusa o -1. La funzione TakeProfitLastClosePos() accetta i seguenti parametri opzionali:

  • sy - Nome dello strumento. "" - qualsiasi simbolo, NULL - simbolo corrente. Il valore predefinito è "".
  • op - operazione commerciale. Valori validi: -1, OP_BUY, OP_SELL. Il valore predefinito è -1 - qualsiasi commercio.
  • mn - Identificatore commerciale, MagicNumber. Valore predefinito -1 - qualsiasi magia.
//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 20.10.2008                                                     |
//|  Описание : Возвращает цену TakeProfit последней закрытой позиций или -1.  |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double TakeProfitLastClosePos(string sy="", int op=-1, int mn=-1) {
  datetime t;
  double   r=-1;
  int      i, k=OrdersHistoryTotal();

  if ( sy=="0") sy=Symbol();
  for ( i=0; i< k; i++) {
    if (OrderSelect( i, SELECT_BY_POS, MODE_HISTORY)) {
      if (OrderSymbol()== sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if ( op<0 || OrderType()== op) {
            if ( mn<0 || OrderMagicNumber()== mn) {
              if ( t<OrderCloseTime()) {
                t=OrderCloseTime();
                r=OrderTakeProfit();
              }
            }
          }
        }
      }
    }
  }
  return( r);
}
 
KimIV >> :

Funzione TakeProfitLastClosePos().

Restituisce il livello di prezzo TakeProfit dell'ultima posizione chiusa o -1. La funzione TakeProfitLastClosePos() accetta i seguenti parametri opzionali:

  • sy - Nome dello strumento. "" - qualsiasi simbolo, NULL - simbolo corrente. Il valore predefinito è "".
  • op - operazione commerciale. Valori validi: -1, OP_BUY, OP_SELL. Il valore predefinito è -1 - qualsiasi commercio.
  • mn - Identificatore commerciale, MagicNumber. Valore predefinito -1 - qualsiasi magia.

C'è una funzione che cambia il take profit dopo che è passato del tempo da quando la posizione è stata aperta?

 
drm1 писал(а) >>

c'è una funzione che cambia il take profit dopo un certo tempo dopo che la posizione è stata aperta?

ModificareOrdine()

Ecco, qui sotto ci sono alcuni esempi di come usarlo...

1...474849505152535455565758596061...128
Nuovo commento
Motivazione: