baxromsaid 2020.03.11 12:55 #11941

Sono su un Android.

Vladimir Karputov 2020.03.11 13:09 #11942

baxromsaid:
Non so come aprire un conto demo.

baxromsaid:
Sono su Android.

MetaQuotes non è un broker - quindi è possibile aprire un conto demo solo sui server MetaQuotes-Demo.

Un conto di trading reale deve essere aperto con un broker.

odyn 2020.03.14 11:24 #11943

Ciao conoscitori!

Potete dirmi perché nel mio codice le variabili vol e ask non ottengono valori? Il valore zero è sempre visualizzato in Stampa. Lo spread si "blocca" normalmente, mostra il valore corretto.

Allego l'EA al grafico LTCUSD.

Qual è l'errore?

#include <Trade\SymbolInfo.mqh>
CSymbolInfo m_symbol;
int a=0,b=0,c=0,spread=0,i=0,j=0;
double x=0,y=0,z=0,m=0,ask=0;
input int vyb=7;
bool bool_1=true,bool_2=true,bool_3=true;
string str_1="",str_2="",str_3="",name="",Text[101];
ulong vol=0;

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
  name=_Symbol;
  Print("текущий символ: ",name); 
  spread=m_symbol.Spread();
  Print("спред по символу: ",spread);
  vol=m_symbol.Volume();
  Print("обьєм по символу ",name," - ",vol);
  ask=m_symbol.Ask();
  Print("Цена Аск равно ",ask);

[ARCHIVIO] Qualsiasi domanda da Errori, bug, domande domanda per gli esperti

Vladimir Karputov 2020.03.14 11:48 #11944

odyn:

Ciao conoscitori!

Potete dirmi perché il mio codice non imposta vol e ask? Il valore zero è sempre visualizzato in Stampa. Lo spread si "blocca" normalmente, mostra il valore corretto.

Allego l'EA al grafico LTCUSD.

Qual è l'errore?

Dovresti applicare il metodo CSymbolInfo::Refresh o CSymbolInfo::RefreshRates prima di ottenerlo - a seconda di ciò che ti serve.

Ecco il codice di queste funzioni:

//+------------------------------------------------------------------+
//| Refresh cached data                                              |
//+------------------------------------------------------------------+
bool CSymbolInfo::Refresh(void)
  {
   long tmp=0;
//---
   if(!SymbolInfoDouble(m_name,SYMBOL_POINT,m_point))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_TICK_VALUE,m_tick_value))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_TICK_VALUE_PROFIT,m_tick_value_profit))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_TICK_VALUE_LOSS,m_tick_value_loss))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_TICK_SIZE,m_tick_size))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_TRADE_CONTRACT_SIZE,m_contract_size))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_VOLUME_MIN,m_lots_min))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_VOLUME_MAX,m_lots_max))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_VOLUME_STEP,m_lots_step))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_VOLUME_LIMIT,m_lots_limit))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_SWAP_LONG,m_swap_long))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_SWAP_SHORT,m_swap_short))
      return(false);
   if(!SymbolInfoInteger(m_name,SYMBOL_DIGITS,tmp))
      return(false);
   m_digits=(int)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_ORDER_MODE,tmp))
      return(false);
   m_order_mode=(int)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_TRADE_EXEMODE,tmp))
      return(false);
   m_trade_execution=(ENUM_SYMBOL_TRADE_EXECUTION)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_TRADE_CALC_MODE,tmp))
      return(false);
   m_trade_calcmode=(ENUM_SYMBOL_CALC_MODE)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_TRADE_MODE,tmp))
      return(false);
   m_trade_mode=(ENUM_SYMBOL_TRADE_MODE)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_SWAP_MODE,tmp))
      return(false);
   m_swap_mode=(ENUM_SYMBOL_SWAP_MODE)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_SWAP_ROLLOVER3DAYS,tmp))
      return(false);
   m_swap3=(ENUM_DAY_OF_WEEK)tmp;
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_INITIAL,m_margin_initial))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_MAINTENANCE,m_margin_maintenance))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_LONG,m_margin_long))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_SHORT,m_margin_short))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_LIMIT,m_margin_limit))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_STOP,m_margin_stop))
      return(false);
   if(!SymbolInfoDouble(m_name,SYMBOL_MARGIN_STOPLIMIT,m_margin_stoplimit))
      return(false);
   if(!SymbolInfoInteger(m_name,SYMBOL_EXPIRATION_MODE,tmp))
      return(false);
   m_trade_time_flags=(int)tmp;
   if(!SymbolInfoInteger(m_name,SYMBOL_FILLING_MODE,tmp))
      return(false);
   m_trade_fill_flags=(int)tmp;
//--- succeed
   return(true);
  }
//+------------------------------------------------------------------+
//| Refresh cached data                                              |
//+------------------------------------------------------------------+
bool CSymbolInfo::RefreshRates(void)
  {
   return(SymbolInfoTick(m_name,m_tick));
  }

Документация по MQL5: Стандартная библиотека / Торговые классы / CSymbolInfo / Refresh

www.mql5.com

Стандартная библиотека / Торговые классы / CSymbolInfo / Refresh - справочник по языку алгоритмического/автоматического трейдинга для MetaTrader 5

odyn 2020.03.14 12:03 #11945

Vladimir Karputov:

È necessario applicare il metodo CSymbolInfo::Refresh o CSymbolInfo::RefreshRates prima di ottenere - a seconda di ciò che serve

Grazie mille, caro Vladimir!

Forse puoi anche dirmi come ottenere il nome del simbolo con il metodoCSymbolInfo Name? Quando cerco di farlo

#include <Trade\SymbolInfo.mqh>
CSymbolInfo m_symbol;
int a=0,b=0,c=0,spread=0,i=0,j=0;
double x=0,y=0,z=0,m=0,ask=0;
input int vyb=7;
bool bool_1=true,bool_2=true,bool_3=true;
string str_1="",str_2="",str_3="",name="",Text[101];
ulong vol=0;

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
  name=m_symbol.Name(Symbol())
  Print("текущий символ: ",name);

Ottengo un valore booleano true nella variabile name.

Vladimir Karputov 2020.03.14 14:38 #11946

odyn:

Grazie mille, caro Vladimir!

Forse puoi anche suggerire: come ottenere il nome di un simbolo usando il metodoCSymbolInfo Name? Quando provo a farlo in questo modo

Ottengo un valore booleano true nella variabile name.

Lo faccio - inizializzo la variabile della classe CSymbolInfo.

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
***
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return(INIT_FAILED);
     }
   RefreshRates();
***
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Refreshes the symbol quotes data                                 |
//+------------------------------------------------------------------+
bool RefreshRates()
  {
//--- refresh rates
   if(!m_symbol.RefreshRates())
     {
      if(InpPrintLog)
         Print(__FILE__," ",__FUNCTION__,", ERROR: ","RefreshRates error");
      return(false);
     }
//--- protection against the return value of "zero"
   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)
     {
      if(InpPrintLog)
         Print(__FILE__," ",__FUNCTION__,", ERROR: ","Ask == 0.0 OR Bid == 0.0");
      return(false);
     }
//---
   return(true);
  }

Se volete ottenere un nome (per esempio quando confrontate il simbolo di posizione con il simbolo corrente), dovete usare il metodo CSymbolInfo::Name().

Esempio di utilizzo:

//+------------------------------------------------------------------+
//| Is position exists                                               |
//+------------------------------------------------------------------+
bool IsPositionExists(void)
  {
   for(int i=PositionsTotal()-1; i>=0; i--)
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)
            return(true);
//---
   return(false);
  }

L'aiuto mostra due forme di chiamata al metodo Name

Nome

Ottiene il nome dello strumento finanziario.

string  Name() const

Valore restituito

Nome dello strumento finanziario.

Nome

Imposta il nome dello strumento finanziario per lavorare ulteriormente con esso.

bool  Name(string name)

Valore restituito

No.

Документация по MQL5: Стандартная библиотека / Торговые классы / CSymbolInfo / Name

www.mql5.com

Стандартная библиотека / Торговые классы / CSymbolInfo / Name - справочник по языку алгоритмического/автоматического трейдинга для MetaTrader 5

odyn 2020.03.14 15:16 #11947

Vladimir Karputov:

Se si vuole ottenere un nome (ad esempio quando si confronta un simbolo di posizione con il simbolo corrente), è necessario utilizzare il metodo CSymbolInfo::Name().

Esempio di utilizzo:

L'aiuto mostra due forme di chiamata al metodo Name

Nome

Ottiene il nome dello strumento finanziario.

Valore restituito

Nome dello strumento finanziario.

Ho una domanda su questa forma di metodo Nome.

Come ottengo il NOME dello strumento nella variabile? Perché facendo così:

#include <Trade\SymbolInfo.mqh>
CSymbolInfo m_symbol;
string str_1="",str_2="",str_3="",name="";
name=m_symbol.Name();
Print("текущий символ: ",name);

Come ottenere una stringa con il nome dello strumento, usando ilmetodo CSymbolInfo::Name()?

Документация по MQL5: Стандартная библиотека / Торговые классы / CSymbolInfo / Name

www.mql5.com

Стандартная библиотека / Торговые классы / CSymbolInfo / Name - справочник по языку алгоритмического/автоматического трейдинга для MetaTrader 5

Vladimir Karputov 2020.03.14 15:23 #11948

odyn:

Ho una domanda su questa particolare forma del metodo Name.

Come faccio a mettere il NOME dello strumento in una variabile? Perché facendo così:

Come posso ottenere una stringa con il nome dello strumento, usando ilmetodo CSymbolInfo::Name()?

Prima loINIZIALIZZIAMO. Poi usiamo il metodo Name().

Eseguiamo il codice sul carattere ''.

//+------------------------------------------------------------------+
//|                                                            1.mq5 |
//|                              Copyright © 2020, Vladimir Karputov |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2019, Vladimir Karputov"
#property version   "1.00"
#include <Trade\SymbolInfo.mqh>
//---
CSymbolInfo    m_symbol;                     // object of CSymbolInfo class
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return;
     }
   string name=m_symbol.Name();
   Print("текущий символ: ",name);
//---
  }
//+------------------------------------------------------------------+

Risultato:

1 (EURUSD,H1)   текущий символ: EURUSD

odyn 2020.03.14 15:45 #11949

Vladimir Karputov:

Prima si INIZIALIZZA. Poi usiamo il metodo Name().

Eseguite il codice sul carattere ''.

Risultato:

Capito. Grazie per la vostra pazienza )).

PS: il mio compilatore sta dando la colpa al ritorno nel tuo codice. Quando l'ho rimosso, va bene.

Vladimir Karputov 2020.03.14 15:49 #11950

odyn:

Capito. Grazie per la vostra pazienza )).

PS: il mio compilatore sta dando la colpa al ritorno nel tuo codice. Quando l'ho rimosso, va bene.

Questo è uno script (ho dato un esempio di script), non un EA. Se avete copiato il mio codice in EA, ci sarà un errore.

Domande dai principianti MQL5 MT5 MetaTrader 5 - pagina 1195

Nome

Nome

Nome