Domande dai principianti MQL5 MT5 MetaTrader 5

Vasiliy Sokolov 2016.05.10 10:11 #5741

Ecco la mia variante per risolvere il problema della ricerca a ripetizione:

//+------------------------------------------------------------------+
//|                                              FindRetryPrices.mq5 |
//|                                 Copyright 2016, Vasiliy Sokolov. |
//|                                              http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, Vasiliy Sokolov."
#property link      "http://www.mql5.com"
#property version   "1.00"
#include <Dictionary.mqh>

input int RatesPeriod = 10;                        // Период за который ищутся повторения
input int RoundPoints = 10;                        // Загрубление цены в прайсстепах
class CBar : public CObject
{
private:
   MqlRates m_bar;
public:
            CBar(MqlRates& bar){m_bar = bar;}
   datetime Date(){return m_bar.time;}
   double Open(){return m_bar.open;}
   double High(){return m_bar.high;}
   double Low(){return m_bar.low;}
   double Close(){return m_bar.close;}
};
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
{
   // Нахождение повторяющихся баров
   MqlRates rates[];
   int total = CopyRates(Symbol(), Period(), 0, RoundPoints, rates);
   CDictionary* BarsCollections = new CDictionary(total);
   for(int i = 0; i < total; i++)
   {
      double price = PriceToLevel(rates[i].high);
      CBar* bar = new CBar(rates[i]);
      if(!BarsCollections.ContainsKey(price))
         BarsCollections.AddObject(price, new CList());
      CList* equal_bars = BarsCollections.GetObjectByKey(price);
      equal_bars.Add(bar);
   }
   // Вывод повторов
   FOREACH_DICT(BarsCollections)
   {
      CList* list = node;
      if(list.Total() < 2)continue;
      string retry_bars = "";
      for(CBar* bar = list.GetFirstNode(); bar != NULL; bar = list.GetNextNode())
         retry_bars += " [" + TimeToString(bar.Date()) + ", " + DoubleToString(bar.High(), Digits()) + "]";
      printf("Обнаружено совпадение баров:" + retry_bars);
   }
   delete BarsCollections;
}
//+------------------------------------------------------------------+
//| Округляет цену в соответствии с параметром RoundPoints           |
//+------------------------------------------------------------------+
double PriceToLevel(double price)
{
   double price_step = RoundPoints*Point();
   double mn = MathFloor(price/price_step);
   return mn * price_step;
}

//+------------------------------------------------------------------+

Perché lo script funzioni, il file Dictionary deve essere copiato in MQL5\Include

La ricerca viene eseguita nel ciclo for one-pass evidenziato in giallo. La lista risultante non contiene ripetizioni (se A ripete B e B ripete A, verrà emesso un insieme {A, B} invece di due {A, B} e {B, A}). ).

L'output di questo script ha mostrato quanto segue:

2016.05.10 11:09:06.730 FindRetryPrices (Si Splice,M1)  Обнаружено совпадение баров: [2016.05.10 11:02, 67149] [2016.05.10 11:03, 67147] [2016.05.10 11:04, 67144]
2016.05.10 11:09:06.730 FindRetryPrices (Si Splice,M1)  Обнаружено совпадение баров: [2016.05.10 11:01, 67160] [2016.05.10 11:05, 67161]
2016.05.10 11:09:06.730 FindRetryPrices (Si Splice,M1)  Обнаружено совпадение баров: [2016.05.10 11:00, 67132] [2016.05.10 11:06, 67139]

File:

Dictionary.mqh 18 kb

Andrey Koldorkin 2016.05.10 13:01 #5742

Artyom Trishkin:

Dal riferimento:

Vasiliy Sokolov:

Ecco la mia versione della soluzione al problema della ricerca delle ripetizioni:

Grazie a tutti voi!!! Cercherò di capire tutto oggi. È importante non solo copiare un pezzo di codice in Expert Advisor, ma capire perché è scritto in questo modo, quindi forse farò altre domande.

Aleksey Vyazmikin 2016.05.10 13:44 #5743

Per favore aiutatemi a trovare una funzione per calcolare l'RSI standard, i requisiti sono semplici:

1. Restituisce il valore RSI a una data barra

2. Calcolare l'indice solo per quelle barre (se necessario), che sono richieste (desiderabile)

3. Essere in grado di calcolare sul TF specificato

4. Lavora a spese del punto 2 più velocemente dell'indicatore

Voglio integrare la funzione nell'Expert Advisor, se qualcuno ne ha una pronta, la prego di condividerla con me.

Lo chiedo perché l'indicatore è molto comune e non è un mistero.

Tutte le domande dei Scriverò un EA gratuitamente [Qualsiasi domanda da principiante,

Vasiliy Sokolov 2016.05.10 14:12 #5744

-Aleks-:

Per favore aiutatemi a trovare una funzione per calcolare l'RSI standard, i requisiti sono semplici:

1. Restituisce il valore RSI a una data barra

2. Calcolare l'indice solo per quelle barre (se necessario), che sono richieste (desiderabile)

3. Essere in grado di calcolare sul TF specificato

4. Lavora a spese del punto 2 più velocemente dell'indicatore

Voglio integrare la funzione nell'EA, se qualcuno ne ha una pronta, la prego di condividerla con me.

Lo chiedo perché l'indicatore è molto comune e non è un mistero.

Perché non vi piace l'iRSI standard? Non abbastanza segreto?

Aleksey Vyazmikin 2016.05.10 14:23 #5745

Vasiliy Sokolov:
Cosa c'è di sbagliato nell'iRSI standard? Non abbastanza segreto?

Ci sono le mie modifiche che dovrò fare alla funzione...

Vasiliy Sokolov 2016.05.10 14:40 #5746

-Aleks-:
Ci sono le mie modifiche che dovrò fare alla funzione...

Prendetene uno già pronto e modificatelo secondo le vostre esigenze:

//+------------------------------------------------------------------+
//|                                                          RSI.mq5 |
//|                        Copyright 2009, MetaQuotes Software Corp. |
//|                                              http://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright   "2009, MetaQuotes Software Corp."
#property link        "http://www.mql5.com"
#property description "Relative Strength Index"
//--- indicator settings
#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
#property  indicator_level1 30
#property  indicator_level2 70
#property indicator_buffers 3
#property indicator_plots   1
#property  indicator_type1   DRAW_LINE
#property  indicator_color1  DodgerBlue
//--- input parameters
input int InpPeriodRSI=14; // Period
//--- indicator buffers
double    ExtRSIBuffer[];
double    ExtPosBuffer[];
double    ExtNegBuffer[];
//--- global variable
int       ExtPeriodRSI;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
void OnInit()
  {
//--- check for input
   if(InpPeriodRSI<1)
     {
      ExtPeriodRSI=12;
      Print("Incorrect value for input variable InpPeriodRSI =",InpPeriodRSI,
            "Indicator will use value =",ExtPeriodRSI,"for calculations.");
     }
   else ExtPeriodRSI=InpPeriodRSI;
//--- indicator buffers mapping
   SetIndexBuffer(0,ExtRSIBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,ExtPosBuffer,INDICATOR_CALCULATIONS);
   SetIndexBuffer(2,ExtNegBuffer,INDICATOR_CALCULATIONS);
//--- set accuracy
   IndicatorSetInteger(INDICATOR_DIGITS,2);
//--- sets first bar from what index will be drawn
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,ExtPeriodRSI);
//--- name for DataWindow and indicator subwindow label
   IndicatorSetString(INDICATOR_SHORTNAME,"RSI("+string(ExtPeriodRSI)+")");
//--- initialization done
  }
//+------------------------------------------------------------------+
//| Relative Strength Index                                          |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const int begin,
                const double &price[])
  {
   int    i;
   double diff;
//--- check for rates count
   if(rates_total<=ExtPeriodRSI)
      return(0);
//--- preliminary calculations
   int pos=prev_calculated-1;
   if(pos<=ExtPeriodRSI)
     {
      //--- first RSIPeriod values of the indicator are not calculated
      ExtRSIBuffer[0]=0.0;
      ExtPosBuffer[0]=0.0;
      ExtNegBuffer[0]=0.0;
      double SumP=0.0;
      double SumN=0.0;
      for(i=1;i<=ExtPeriodRSI;i++)
        {
         ExtRSIBuffer[i]=0.0;
         ExtPosBuffer[i]=0.0;
         ExtNegBuffer[i]=0.0;
         diff=price[i]-price[i-1];
         SumP+=(diff>0?diff:0);
         SumN+=(diff<0?-diff:0);
        }
      //--- calculate first visible value
      ExtPosBuffer[ExtPeriodRSI]=SumP/ExtPeriodRSI;
      ExtNegBuffer[ExtPeriodRSI]=SumN/ExtPeriodRSI;
      if(ExtNegBuffer[ExtPeriodRSI]!=0.0)
         ExtRSIBuffer[ExtPeriodRSI]=100.0-(100.0/(1.0+ExtPosBuffer[ExtPeriodRSI]/ExtNegBuffer[ExtPeriodRSI]));
      else
        {
         if(ExtPosBuffer[ExtPeriodRSI]!=0.0)
            ExtRSIBuffer[ExtPeriodRSI]=100.0;
         else
            ExtRSIBuffer[ExtPeriodRSI]=50.0;
        }
      //--- prepare the position value for main calculation
      pos=ExtPeriodRSI+1;
     }
//--- the main loop of calculations
   for(i=pos;i<rates_total && !IsStopped();i++)
     {
      diff=price[i]-price[i-1];
      ExtPosBuffer[i]=(ExtPosBuffer[i-1]*(ExtPeriodRSI-1)+(diff>0.0?diff:0.0))/ExtPeriodRSI;
      ExtNegBuffer[i]=(ExtNegBuffer[i-1]*(ExtPeriodRSI-1)+(diff<0.0?-diff:0.0))/ExtPeriodRSI;
      if(ExtNegBuffer[i]!=0.0)
         ExtRSIBuffer[i]=100.0-100.0/(1+ExtPosBuffer[i]/ExtNegBuffer[i]);
      else
        {
         if(ExtPosBuffer[i]!=0.0)
            ExtRSIBuffer[i]=100.0;
         else
            ExtRSIBuffer[i]=50.0;
        }
     }
//--- OnCalculate done. Return new prev_calculated.
   return(rates_total);
  }
//+------------------------------------------------------------------+

Aleksey Vyazmikin 2016.05.10 14:56 #5747

Vasiliy Sokolov:

Prendetene uno già pronto e modificatelo secondo le vostre esigenze:

So che c'è un indicatore nel codice... La domanda era chi potrebbe averlo già cambiato...

Andrey Koldorkin 2016.05.10 22:18 #5748

Vasiliy Sokolov:

Ecco la mia variante per risolvere il problema della ricerca delle ripetizioni:

Vasily, quando apro#include <Dictionary.mqh>, si apre come nel corpo dell'EA. Dovrebbe essere così, o dovrebbe esserci qualche altro codice all'interno?

Perché nel codice, che vedo, non è chiaro come cerca le ripetizioni ((

OpenCl e i relativi Idee per esperti di Tendenza e livelli

Andrey Koldorkin 2016.05.10 22:33 #5749

Artyom Trishkin:

// строку int searchPeriod=(Search_Period<1)?1:Search_Period;
// можно расписать так:

input int Search_Period=10; // Количество копируемых свечей ... эту строку вы видите в настройках
int searchPeriod;           // Сюда будем записывать входной параметр
if(Search_Period<1) searchPeriod=1; // Если во входном параметре ввели ноль или меньше нуля, то параметр будет равен нулю
else searchPeriod=Search_Period;    // иначе примем входной параметр

// соответственно и строку int delta=(Delta<0)?0:Delta;
// можно расписать точно так же

È corretto supporre che questo sia un errore di battitura? Dovrebbe essere 0 invece di 1.

come questo:int searchPeriod=(Search_Period<1)?0:Search_Period;

e poi nello script eseguibile:

int copy_bars=(int)fmin(Search_Period,Bars(Symbol(),Period())); // il numero di candele da copiare

In questo caso, probabilmente dovremmo già usare una variabile: searchPeriod. giusto?

------

Un'altra domanda: cosa fa questa linea? Ho scoperto che ogni elemento della struttura si azzera. E non capisco cosa stiamo azzerando qui se sembra che abbiamo appena scritto questi dati e dovremmo usarli ulteriormente.

ZeroMemory(dataCandle); // Azzeramento dei dati nella struttura

Domande di OrderSend() Errori, bug, domande Tutte le domande dei

Artyom Trishkin 2016.05.11 00:03 #5750

Andrey Koldorkin:

È corretto supporre che questo sia un errore di battitura? Dovrebbe essere 0 invece di 1.

come questo:int searchPeriod=(Search_Period<1)?0:Search_Period;

e poi nello script eseguibile:

int copy_bars=(int)fmin(Search_Period,Bars(Symbol(),Period())); // il numero di candele da copiare

In questo caso, probabilmente dovremmo già usare una variabile: searchPeriod. giusto?

------

Un'altra domanda: cosa fa questa linea? Ho scoperto che ogni elemento della struttura si azzera. E non capisco cosa stiamo azzerando qui se sembra che abbiamo appena scritto questi dati e dovremmo usarli ulteriormente.

ZeroMemory(dataCandle); // cancellare i dati nella struttura

"come questo:int searchPeriod=(Search_Period<1)?0:Search_Period;"

No, non lo è. Ecco come si ha (letteralmente): se Search_Period impostato dall'utente nelle impostazioni è inferiore a uno, allora searchPeriod sarà uguale a zero; altrimenti, searchPeriod sarà uguale al valore di Search_Period impostato dall'utente nelle impostazioni. Questo non è corretto. Non abbiamo bisogno di un intervallo di ricerca che sia uguale a zero. Quindi, se questo intervallo è impostato dall'utente a 0 o meno di zero (meno di uno), allora imposteremo questo intervallo uguale al minimo - uno.

"int copy_bars=(int)fmin(Search_Period,Bars(Symbol(),Period())); // numero di candele da copiare
qui, in teoria, dovremmo già usare la variabile: searchPeriod. giusto? "

Sì, è vero, è un refuso.

"Un'altra domanda: cosa fa questa linea, a cosa serve? Ho scoperto che azzera ogni elemento della struttura. E qui non riesco a capire perché e cosa stiamo azzerando se abbiamo appena scritto questi dati e dovremmo usarli ulteriormente. ZeroMemory(dataCandle); // Azzeramento dei dati nella struttura".

Lo facciamo prima di riempire la struttura con i dati. Prima lo azzeriamo e poi lo riempiamo. Guarda - lo azzeriamo prima del ciclo. E poi nel ciclo riempiamo la struttura con i dati.

Tutte le domande dei [Qualsiasi domanda da principiante, Errori, bug, domande

Domande dai principianti MQL5 MT5 MetaTrader 5 - pagina 575