Download MetaTrader 5

What is the default stop out level of MT5 demo?

To add comments, please log in or register
jon
465
jon  
What is the default stop out level of MT5 demo?
Vladimir Karputov
Moderator
49968
Vladimir Karputov  
jon:
What is the default stop out level of MT5 demo?
Account Properties:
//+------------------------------------------------------------------+
//|                                           Account Properties.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+ 
//| Script program start function                                    | 
//+------------------------------------------------------------------+ 
void OnStart()
  {
//--- Name of the company 
   string company=AccountInfoString(ACCOUNT_COMPANY);
//--- Name of the client 
   string name=AccountInfoString(ACCOUNT_NAME);
//--- Account number 
   long login=AccountInfoInteger(ACCOUNT_LOGIN);
//--- Name of the server 
   string server=AccountInfoString(ACCOUNT_SERVER);
//--- Account currency 
   string currency=AccountInfoString(ACCOUNT_CURRENCY);
//--- Demo, contest or real account 
   ENUM_ACCOUNT_TRADE_MODE account_type=(ENUM_ACCOUNT_TRADE_MODE)AccountInfoInteger(ACCOUNT_TRADE_MODE);
//--- Now transform the value of  the enumeration into an understandable form 
   string trade_mode;
   switch(account_type)
     {
      case  ACCOUNT_TRADE_MODE_DEMO:
         trade_mode="demo";
         break;
      case  ACCOUNT_TRADE_MODE_CONTEST:
         trade_mode="contest";
         break;
      default:
         trade_mode="real";
         break;
     }
//--- Stop Out is set in percentage or money 
   ENUM_ACCOUNT_STOPOUT_MODE stop_out_mode=(ENUM_ACCOUNT_STOPOUT_MODE)AccountInfoInteger(ACCOUNT_MARGIN_SO_MODE);
//--- Get the value of the levels when Margin Call and Stop Out occur 
   double margin_call=AccountInfoDouble(ACCOUNT_MARGIN_SO_CALL);
   double stop_out=AccountInfoDouble(ACCOUNT_MARGIN_SO_SO);
//--- Show brief account information 
   PrintFormat("The account of the client '%s' #%d %s opened in '%s' on the server '%s'",
               name,login,trade_mode,company,server);
   PrintFormat("Account currency - %s, MarginCall and StopOut levels are set in %s",
               currency,(stop_out_mode==ACCOUNT_STOPOUT_MODE_PERCENT)?"percentage":" money");
   PrintFormat("MarginCall=%G, StopOut=%G",margin_call,stop_out);
  }
//+------------------------------------------------------------------+
Files:
To add comments, please log in or register