Market validation error 4107

[Josef Vobejda]

Hi,

I’ve been trying to pass the validation phase with my EA for a few days now. I understand what this error means and what causes it, but I’m still unable to fix it.

Exact logs:

EURUSD,H1: invalid stoploss for OrderSend function EURUSD,H1: OrderSend error 4107

I couldn't replicate the error in my strategy tester.
Here is the relevant code snippet

input int Sl = 100;                    //Stop loss in points
input int Tp = 0;                      //Take profit in points
input int entryOffset = 0;             //Entry offset


void OnTick(){
        double entry = rangeHigh + entryOffset * _Point;
        double sl = Sl != 0 ? entry - Sl * _Point : 0;
        if(!CheckStopLoss_Takeprofit(OP_BUY,sl,tp)){
                Print("The StopLoss or TakeProfit level is incorrect!");        
                return;
        }

        double lots  = CalcLots(sl != 0 ? entry - sl : 0);
        OrderSend(_Symbol,OP_BUY,lots,Round(Ask),5,Round(sl),Round(tp),eaComment,Magic);
}

double Round(double price){
   double tick_size = SymbolInfoDouble( _Symbol, SYMBOL_TRADE_TICK_SIZE );
   return round(price / tick_size) * tick_size;
}


bool CheckStopLoss_Takeprofit(int type,double SL,double TP)
  {
//--- get the SYMBOL_TRADE_STOPS_LEVEL level
   int stops_level=(int)SymbolInfoInteger(_Symbol,SYMBOL_TRADE_STOPS_LEVEL);
   if(stops_level!=0)
     {
      PrintFormat("SYMBOL_TRADE_STOPS_LEVEL=%d: StopLoss and TakeProfit must"+
                  " not be nearer than %d points from the closing price",stops_level,stops_level);
     }
//---
   bool SL_check=false,TP_check=false;
//--- check only two order types
   switch(type)
     {
      //--- Buy operation
      case  OP_BUY:
        {
         //--- check the StopLoss
         SL_check=((Bid-SL>stops_level*_Point && SL <= Bid) || SL == 0);
         if(!SL_check)
            PrintFormat("For order %s StopLoss=%.5f must be less than %.5f"+
                        " (Bid=%.5f - SYMBOL_TRADE_STOPS_LEVEL=%d points)",
                        "OP_BUY",SL,Bid-stops_level*_Point,Bid,stops_level);
         //--- check the TakeProfit
         TP_check=((TP-Bid>stops_level*_Point && TP >= Bid) || TP == 0);
         if(!TP_check)
            PrintFormat("For order %s TakeProfit=%.5f must be greater than %.5f"+
                        " (Bid=%.5f + SYMBOL_TRADE_STOPS_LEVEL=%d points)",
                        "OP_BUY",TP,Bid+stops_level*_Point,Bid,stops_level);
         //--- return the result of checking
         return(SL_check&&TP_check);
        }
      //--- Sell operation
      case  OP_SELL:
        {
         //--- check the StopLoss
         SL_check=((SL-Ask>stops_level*_Point && SL >= Ask) || SL == 0);
         if(!SL_check)
            PrintFormat("For order %s StopLoss=%.5f must be greater than %.5f "+
                        " (Ask=%.5f + SYMBOL_TRADE_STOPS_LEVEL=%d points)",
                        "OP_SELL",SL,Ask+stops_level*_Point,Ask,stops_level);
         //--- check the TakeProfit
         TP_check=((Ask-TP>stops_level*_Point && TP <= Ask) || TP == 0);
         if(!TP_check)
            PrintFormat("For order %s TakeProfit=%.5f must be less than %.5f "+
                        " (Ask=%.5f - SYMBOL_TRADE_STOPS_LEVEL=%d points)",
                        "OP_SELL",TP,Ask-stops_level*_Point,Ask,stops_level);
         //--- return the result of checking
         return(TP_check&&SL_check);
        }
      break;
     }
   return false;
  }

Any help is appreciated, thank you.

[dcstoyanov]

Josef Vobejda:

double Round(double price){
   double tick_size = SymbolInfoDouble( _Symbol, SYMBOL_TRADE_TICK_SIZE );
   return round(price / tick_size) * tick_size;
}

Maybe NormalizeDouble?

[Josef Vobejda]

dcstoyanov #:

Maybe NormalizeDouble?

double Round(double price){
   return NormalizeDouble(price,_Digits);
}

I just tried it like this, and it didn't make any difference.

[dcstoyanov]

Josef Vobejda #:

OrderSend(_Symbol,OP_BUY,lots,Round(Ask),5,Round(sl),Round(tp),eaComment,Magic)

By the way, it's

OrderSend(MqlTradeRequest&, MqlTradeResult&)

[Josef Vobejda]

dcstoyanov #:

By the way, it's

My ea is in mql4 sir.

[William Roeder]

Josef Vobejda: Any help is appreciated, thank you.

1. Try rounding your entry before using it in calculations.
2. You buy at the Ask. Your buy order's TP/SL (or Sell Stop's/Sell Limit's entry) are triggered when the Bid / OrderClosePrice reaches it. Using Ask±n, makes your SL shorter and your TP longer, by the spread. Don't you want the specified amount used in either direction?

dcstoyanov #: maybe NormalizeDouble?

 NormalizeDouble, Its use is usually wrong, as it is in your case.

1. Floating point has an infinite number of decimals, it's you were not understanding floating point and that some numbers can't be represented exactly. (like 1/10.)
             Double-precision floating-point format - Wikipedia, the free encyclopedia

   See also The == operand. - MQL4 programming forum (2013)

2. Print out your values to the precision you want with DoubleToString - Conversion Functions - MQL4 Reference.

3. SL/TP (stops) need to be normalized to tick size (not Point) — code fails on non-currencies.
             On 5Digit Broker Stops are only allowed to be placed on full pip values. How to find out in mql? - MQL4 programming forum #10 (2011)

   And abide by the limits Requirements and Limitations in Making Trades - Appendixes - MQL4 Tutorial and that requires understanding floating point equality Can price != price ? - MQL4 programming forum (2012)

4. Open price for pending orders need to be adjusted. On Currencies, Point == TickSize, so you will get the same answer, but it won't work on non-currencies. So do it right.
             Trailing Bar Entry EA - MQL4 programming forum (2013)
             Bid/Ask: (No Need) to use NormalizeDouble in OrderSend - MQL4 programming forum (2012)

5. Lot size must also be adjusted to a multiple of LotStep and check against min and max. If that is not a power of 1/10 then NormalizeDouble is wrong. Do it right.
             (MT4 2013)) (MT5 2022))

6. MathRound() and NormalizeDouble() are rounding in a different way. Make it explicit.
             MT4:NormalizeDouble - MQL5 programming forum (2017)
             How to Normalize - Expert Advisors and Automated Trading - MQL5 programming forum (2017)

7. Prices (and lots) you get from the terminal are already correct (normalized).

8. PIP, Point, or Tick are all different in general.
             What is a TICK? - MQL4 programming forum (2014)

[Josef Vobejda]

William Roeder #:
2. You buy at the Ask. Your buy order's TP/SL (or Sell Stop's/Sell Limit's entry) are triggered when the Bid / OrderClosePrice reaches it. Using Ask±n, makes your SL shorter and your TP longer, by the spread. Don't you want the specified amount used in either direction?

This fixed my issue. Thank you very much.