OrderClose() issue mql4

yas 2023.01.23 18:52

Hi everyone

I try to close some orders (buy/sell) with OrderClose()

My code is this:

void CloseBuyOrder()
  {
   for(int i = OrdersTotal()-1; i >= 0 ; i--)
     {
      if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES))
        {
         if(OrderSymbol() == Symbol())
            if(OrderMagicNumber() == magicnumber)
               if(OrderType() == OP_BUY)
                  while(!OrderClose(OrderTicket(), OrderLots(), Bid, slippage, clrYellow))
                    {
                     int err = GetLastError();
                     Print("Error in OrderClose. Error code= ",err, ErrorDescription(err));
                    }
        }
     }
  }

void CloseSellOrder()
  {
   for(int i = OrdersTotal()-1; i >= 0 ; i--)
     {
      if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES))
        {
         if(OrderSymbol() == Symbol())
            if(OrderMagicNumber() == magicnumber)
               if(OrderType() == OP_SELL)
                  while(!OrderClose(OrderTicket(), OrderLots(), Ask, slippage, clrYellow))
                    {
                     int err = GetLastError();
                     Print("Error in OrderClose. Error code= ",err, ErrorDescription(err));
                    }
        }
     }
  }

I call functions like this:

CloseBuyOrder();
RefreshRates();
CloseSellOrder();

As you can see firstly i try to close buy orders (that it work clearly)

but in next when i try to close sell orders i got invalid price error

Do you know whats wrong?

Vladislav Boyko 2023.01.23 19:57 #1

yas:

Hi everyone

I try to close some orders (buy/sell) with OrderClose()

My code is this:

I call functions like this:

As you can see firstly i try to close buy orders (that it work clearly)

but in next when i try to close sell orders i got invalid price error

Do you know whats wrong?

Pass the normalized price

NormalizeDouble(Bid, Digits())
NormalizeDouble(Ask, Digits())

Call RefreshRates() before every OrderClose()

// #1 Update prices (Bid/Ask)
RefreshRates();
// #2 Normalize the price
double price = NormalizeDouble(Bid, Digits());
// #3 Attempt to close
OrderClose(...)

while(!OrderClose(OrderTicket(), OrderLots(), Ask, slippage, clrYellow))

Don't use an infinite loop. You risk getting looped. Use the for() operator to limit the maximum number of iterations

yas 2023.01.23 20:01 #2

Vladislav Boyko #:

Pass the normalized price

Call RefreshRates() before every OrderClose()

Don't use an infinite loop. You risk getting looped. Use the for() operator to limit the maximum number of iterations

thank you a lot i got it

Vladislav Boyko 2023.01.23 20:06 #3

yas #:

thank you a lot i got it

Simple example

bool orderClose(int ticket, int type, double volume, int attempts = 3)
  {
   for(int i = 1; i <= attempts; i++)
     {
      RefreshRates();
      double price = type == 0 ? NormalizeDouble(Bid, Digits()) : NormalizeDouble(Ask, Digits());
      ResetLastError();
      if(OrderClose(ticket, volume, price, 999))
         return(true);
      PrintFormat("OrderClose error %i. Ticket %i", GetLastError(), ticket);
     }
   return(false);
  }

Daniel Cioca 2023.01.23 20:44 #4

If use OrderClosePrice() you can forget about the direction of the closing trade

William Roeder 2023.01.23 22:52 #5

Each server call takes time. When it finishes, your predefined variables will be wrong. RefreshRates after each call.
Or, stop using Bid/Ask and use OrderClosePrice() to be direction independent.
Prices you get from the terminal (Bid/Ask) are already normalized.

OrderClose is closing order expert advisor - miscellaneous Bot Closes trades immediately

Vladislav Boyko 2023.01.23 23:20 #6

William Roeder #:

RefreshRates after each call.

Is the "before" option much worse? Not only calling the server can take time. I prefer to update prices immediately before use (in trading functions).

William Roeder #:

Or, stop using Bid/Ask and use OrderClosePrice() to be direction independent.

I collect orders in an array. Like this:

struct STRUCT_ORDER
  {
   double price;
   double stopLoss;
   double takeProfit;
   double volume;
   int ticket;
   int type;
  };

STRUCT_ORDER orders[];

Do you think "OrderSelect() + OrderClosePrice()" is better than "RefreshRates() + ternary_operator"?

OrderClose is closing order automatic order closing Features of the mql4

Vladislav Boyko 2023.01.23 23:31 #7

Vladislav Boyko #:

Is the "before" option much worse? Not only calling the server can take time. I prefer to update prices immediately before use (in trading functions).

For example, you wait until the trade flow is free before closing the order

William Roeder 2023.01.23 23:44 #8

Vladislav Boyko #:

Is the "before" option much worse? Not only calling the server can take time. I prefer to update prices immediately before use (in trading functions).

Do you think "OrderSelect() + OrderClosePrice()" is better than "RefreshRates() + ternary_operator"?

On the first call, the refresh does nothing. After the last call, your code goes on; does the remaining code use any predefined variables and now require a refresh also? Are you sure?
Only blocking calls take time, what other calls do you have?
OCP does not require a refresh and a test. Simplify.

RefreshRates() [ARCHIVE!] Any rookie question, Help needed - line

Vladislav Boyko 2023.01.24 00:39 #9

William Roeder #:
On the first call, the refresh does nothing. After the last call, your code goes on; does the remaining code use any predefined variables and now require a refresh also? Are you sure?

If I need the value of a predefined variable to be actual, then I call RefreshRates() before using the predefined variable. I understand you, thanks.

William Roeder #:
Only blocking calls take time, what other calls do you have?

Usually I also do this check:

bool orderClose(int ticket, int type, double volume, int attempts = 3)
  {
   for(int i = 1; i <= attempts; i++)
     {
      if(isTradeAllowed() < 0)
         return(false);
      RefreshRates();
      double price = type == 0 ? NormalizeDouble(Bid, Digits()) : NormalizeDouble(Ask, Digits());
      ResetLastError();
      if(OrderClose(ticket, volume, price, 999))
         return(true);
      PrintFormat("OrderClose error %i. Ticket %i", GetLastError(), ticket);
     }
   return(false);
  }

int isTradeAllowed(uint MaxWaiting_sec = 10)
  {
   if(!IsTradeAllowed())
     {
      uint StartWaitingTime = GetTickCount();
      Print("Trade flow is busy! Waiting...");
      while(true)
        {
         if(IsStopped())
           {
            Print("The expert has been stopped by the user!"); 
            return(-1); 
           }
         if(GetTickCount() - StartWaitingTime > MaxWaiting_sec * 1000)
           {
            Print(StringConcatenate("Waiting limit exceeded (", MaxWaiting_sec, " sec.)!"));
            return(-2);
           }
         if(IsTradeAllowed())
           {
            Print("Trade flow is free!");
            return(0);
           }
         Sleep(100);
        }
     }
   return(1);
  }

William Roeder #:
OCP does not require a refresh and a test. Simplify.

Unless you have analyzed the order history before. In this case, the OCP will contain the price of the closed order from the history. I find it much easier to use a bid/ask (+ RefreshRates()) than it is to consider cases like this. Or re-select an order whose properties are already known.

I'm just interested in your opinion. Thank you for your responses

automatic order closing Close order After 1H Invalid price???

William Roeder 2023.01.24 01:39 #10

Vladislav Boyko #: Unless you have analyzed the order history before. In this case, the OCP will contain the price of the closed order from the history.

This post is not about history. It is about closing using Bid/Ask vs. OCP.

1 2

New comment