How read buy and sell signal color from HMA histo alert indicator

New comment
 

here is indicator

here is indicator



//+------------------------------------------------------------------+
//|                                                HMA color nrp.mq4 |
//|                                                           mladen |
//+------------------------------------------------------------------+
//------------------------------------------------------------------
//
//   divisor modification idea by SwingMan
//
#property copyright "www.forex-station.com"
#property link      "www.forex-station.com"
//------------------------------------------------------------------
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_minimum 0
#property indicator_maximum 1
#property strict

//
//
//
//
//

enum enPrices
{
   pr_close,      // Close
   pr_open,       // Open
   pr_high,       // High
   pr_low,        // Low
   pr_median,     // Median
   pr_typical,    // Typical
   pr_weighted,   // Weighted
   pr_average,    // Average (high+low+open+close)/4
   pr_medianb,    // Average median body (open+close)/2
   pr_tbiased,    // Trend biased price
   pr_tbiased2,   // Trend biased (extreme) price
   pr_haclose,    // Heiken ashi close
   pr_haopen ,    // Heiken ashi open
   pr_hahigh,     // Heiken ashi high
   pr_halow,      // Heiken ashi low
   pr_hamedian,   // Heiken ashi median
   pr_hatypical,  // Heiken ashi typical
   pr_haweighted, // Heiken ashi weighted
   pr_haaverage,  // Heiken ashi average
   pr_hamedianb,  // Heiken ashi median body
   pr_hatbiased,  // Heiken ashi trend biased price
   pr_hatbiased2  // Heiken ashi trend biased (extreme) price
};
enum enMaTypes
{
   ma_sma,    // Simple moving average
   ma_ema,    // Exponential moving average
   ma_smma,   // Smoothed MA
   ma_lwma,   // Linear weighted MA
   ma_tema    // Triple exponential moving average - TEMA
};


extern ENUM_TIMEFRAMES    TimeFrame       = PERIOD_CURRENT; // Time frame to use
extern int                HMAPeriod       = 15;             // Hma Period to use
extern enPrices           HMAPrice        = pr_haweighted;  // Price to use
extern enMaTypes          HMAMethod       = ma_lwma;        // Hma average type
extern double             HMASpeed        = 1.8;            // Hma Speed
extern int                HistoWidth      = 3;              // Histogram bars width
extern color              UpHistoColor    = clrLimeGreen;   // Up histogram color
extern color              DnHistoColor    = clrRed;         // Down histogram color
extern bool               alertsOn        = true;           // Turn alerts on?
extern bool               alertsOnCurrent = false;          // Alerts on still open bar?
extern bool               alertsMessage   = true;           // Alerts should show popup message?
extern bool               alertsSound     = false;          // Alerts should play a sound?
extern bool               alertsEmail     = false;          // Alerts should send email?
extern bool               alertsPushNotif = false;          // Alerts should send notification?

//
//
//
//

double hma[];
double hmaDa[];
double hmaDb[];
double tem[];
double trend[];
int    HalfPeriod;
int    HullPeriod;
string indicatorFileName;
bool   returnBars;

//+------------------------------------------------------------------
//|                                                                 |
//+------------------------------------------------------------------
//
//

int init()
{
   IndicatorBuffers(5);
   SetIndexBuffer(0, hmaDa);   SetIndexStyle(0, DRAW_ARROW,EMPTY,HistoWidth,UpHistoColor);
   SetIndexBuffer(1, hmaDb);   SetIndexStyle(1, DRAW_ARROW,EMPTY,HistoWidth,DnHistoColor);
   SetIndexBuffer(2, hma);     
   SetIndexBuffer(3, tem);
   SetIndexBuffer(4, trend);
   
   HMAPeriod  = (int)fmax(2,HMAPeriod);
   HalfPeriod = (int)floor(HMAPeriod/HMASpeed);
   HullPeriod = (int)floor(MathSqrt(HMAPeriod));
   
   indicatorFileName = WindowExpertName();
   returnBars        = TimeFrame==-99;
   TimeFrame         = fmax(TimeFrame,_Period);
   IndicatorShortName(timeFrameToString(TimeFrame)+" HMA("+(string)HMAPeriod+")");
return(0);
}
int deinit() { return(0); }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+

int start()
{
   int i,counted_bars = IndicatorCounted();
   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         int limit = fmin(Bars-counted_bars,Bars-1);
         if (returnBars) { hmaDa[0] = fmin(limit+1,Bars-1); return(0); }
            
   //
   //
   //
   //
   //
   
   if (TimeFrame == Period())
   {
     for(i=limit; i>=0; i--)
     {
        double price = getPrice(HMAPrice,Open,Close,High,Low,i);
        tem[i] = iCustomMa(HMAMethod,price,HalfPeriod,i,0)*2-iCustomMa(HMAMethod,price,HMAPeriod,i,1);
        hma[i] = iCustomMa(HMAMethod,tem[i],HullPeriod,i,2);
        hmaDa[i] = EMPTY_VALUE;
        hmaDb[i] = EMPTY_VALUE;
        trend[i] = (i<Bars-1) ? (hma[i]>hma[i+1]) ? 1 : (hma[i]<hma[i+1]) ? -1 : trend[i+1] : 0;  
        if (trend[i] == 1)  hmaDa[i] = 1;
        if (trend[i] ==-1)  hmaDb[i] = 1;
        
   }
 
   //
   //
   //
   //
   //
   
   if (alertsOn)
   {
      int whichBar = 1; if (alertsOnCurrent) whichBar = 0;
      if (trend[whichBar] != trend[whichBar+1])
      if (trend[whichBar] == 1)
            doAlert("sloping up");
      else  doAlert("sloping down");       
   }  
   return(0);
   }
   
   //
   //
   //
   //
   //
      
   limit = (int)fmax(limit,fmin(Bars-1,iCustom(NULL,TimeFrame,indicatorFileName,-99,0,0)*TimeFrame/_Period));
   for(i=limit; i>=0; i--)
   {
      int y = iBarShift(NULL,TimeFrame,Time[i]);
         hmaDa[i] = iCustom(NULL,TimeFrame,indicatorFileName,PERIOD_CURRENT,HMAPeriod,HMAPrice,HMAMethod,HMASpeed,0,UpHistoColor,DnHistoColor,alertsOn,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,alertsPushNotif,0,y);
         hmaDb[i] = iCustom(NULL,TimeFrame,indicatorFileName,PERIOD_CURRENT,HMAPeriod,HMAPrice,HMAMethod,HMASpeed,0,UpHistoColor,DnHistoColor,alertsOn,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,alertsPushNotif,1,y);           
   }
return(0);
}

//------------------------------------------------------------------
//                                                                  
//------------------------------------------------------------------
//
//
//
//
//

#define _maInstances 3
#define _maWorkBufferx1 1*_maInstances
#define _maWorkBufferx2 2*_maInstances
#define _maWorkBufferx3 3*_maInstances

double iCustomMa(int mode, double price, double length, int r, int instanceNo=0)
{
   int bars = Bars; r = bars-r-1;
   switch (mode)
   {
      case ma_sma   : return(iSma(price,(int)length,r,bars,instanceNo));
      case ma_ema   : return(iEma(price,length,r,bars,instanceNo));
      case ma_smma  : return(iSmma(price,(int)length,r,bars,instanceNo));
      case ma_lwma  : return(iLwma(price,(int)length,r,bars,instanceNo));
      case ma_tema  : return(iTema(price,(int)length,r,bars,instanceNo));
      default       : return(price);
   }
}

//
//
//
//
//

double workSma[][_maWorkBufferx2];
double iSma(double price, int period, int r, int _bars, int instanceNo=0)
{
   if (ArrayRange(workSma,0)!= _bars) ArrayResize(workSma,_bars); instanceNo *= 2; int k;

   workSma[r][instanceNo+0] = price;
   workSma[r][instanceNo+1] = price; for(k=1; k<period && (r-k)>=0; k++) workSma[r][instanceNo+1] += workSma[r-k][instanceNo+0];  
   workSma[r][instanceNo+1] /= 1.0*k;
   return(workSma[r][instanceNo+1]);
}

//
//
//
//
//

double workEma[][_maWorkBufferx1];
double iEma(double price, double period, int r, int _bars, int instanceNo=0)
{
   if (ArrayRange(workEma,0)!= _bars) ArrayResize(workEma,_bars);

   workEma[r][instanceNo] = price;
   if (r>0 && period>1)
          workEma[r][instanceNo] = workEma[r-1][instanceNo]+(2.0/(1.0+period))*(price-workEma[r-1][instanceNo]);
   return(workEma[r][instanceNo]);
}

//
//
//
//
//

double workSmma[][_maWorkBufferx1];
double iSmma(double price, double period, int r, int _bars, int instanceNo=0)
{
   if (ArrayRange(workSmma,0)!= _bars) ArrayResize(workSmma,_bars);

   workSmma[r][instanceNo] = price;
   if (r>1 && period>1)
          workSmma[r][instanceNo] = workSmma[r-1][instanceNo]+(price-workSmma[r-1][instanceNo])/period;
   return(workSmma[r][instanceNo]);
}

//
//
//
//
//

double workLwma[][_maWorkBufferx1];
double iLwma(double price, double period, int r, int _bars, int instanceNo=0)
{
   if (ArrayRange(workLwma,0)!= _bars) ArrayResize(workLwma,_bars);
   
   workLwma[r][instanceNo] = price; if (period<=1) return(price);
      double sumw = period;
      double sum  = period*price;

      for(int k=1; k<period && (r-k)>=0; k++)
      {
         double weight = period-k;
                sumw  += weight;
                sum   += weight*workLwma[r-k][instanceNo];  
      }             
      return(sum/sumw);
}

//
//
//
//
//

double workTema[][_maWorkBufferx3];
#define _tema1 0
#define _tema2 1
#define _tema3 2

double iTema(double price, double period, int r, int bars, int instanceNo=0)
{
   if (period<=1) return(price);
   if (ArrayRange(workTema,0)!= bars) ArrayResize(workTema,bars); instanceNo*=3;

   //
   //
   //
   //
   //
      
   workTema[r][_tema1+instanceNo] = price;
   workTema[r][_tema2+instanceNo] = price;
   workTema[r][_tema3+instanceNo] = price;
   double alpha = 2.0 / (1.0+period);
   if (r>0)
   {
          workTema[r][_tema1+instanceNo] = workTema[r-1][_tema1+instanceNo]+alpha*(price                         -workTema[r-1][_tema1+instanceNo]);
          workTema[r][_tema2+instanceNo] = workTema[r-1][_tema2+instanceNo]+alpha*(workTema[r][_tema1+instanceNo]-workTema[r-1][_tema2+instanceNo]);
          workTema[r][_tema3+instanceNo] = workTema[r-1][_tema3+instanceNo]+alpha*(workTema[r][_tema2+instanceNo]-workTema[r-1][_tema3+instanceNo]); }
   return(workTema[r][_tema3+instanceNo]+3.0*(workTema[r][_tema1+instanceNo]-workTema[r][_tema2+instanceNo]));
}

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//
//

#define priceInstances 1
double workHa[][priceInstances*4];
double getPrice(int tprice, const double& open[], const double& close[], const double& high[], const double& low[], int i, int instanceNo=0)
{
  if (tprice>=pr_haclose)
   {
      if (ArrayRange(workHa,0)!= Bars) ArrayResize(workHa,Bars); instanceNo*=4;
         int r = Bars-i-1;
         
         //
         //
         //
         //
         //
         
         double haOpen;
         if (r>0)
                haOpen  = (workHa[r-1][instanceNo+2] + workHa[r-1][instanceNo+3])/2.0;
         else   haOpen  = (open[i]+close[i])/2;
         double haClose = (open[i] + high[i] + low[i] + close[i]) / 4.0;
         double haHigh  = fmax(high[i],fmax(haOpen,haClose));
         double haLow   = fmin(low[i] ,fmin(haOpen,haClose));

         if(haOpen  <haClose) { workHa[r][instanceNo+0] = haLow;  workHa[r][instanceNo+1] = haHigh; }
         else                 { workHa[r][instanceNo+0] = haHigh; workHa[r][instanceNo+1] = haLow;  }
                                workHa[r][instanceNo+2] = haOpen;
                                workHa[r][instanceNo+3] = haClose;
         //
         //
         //
         //
         //
         
         switch (tprice)
         {
            case pr_haclose:     return(haClose);
            case pr_haopen:      return(haOpen);
            case pr_hahigh:      return(haHigh);
            case pr_halow:       return(haLow);
            case pr_hamedian:    return((haHigh+haLow)/2.0);
            case pr_hamedianb:   return((haOpen+haClose)/2.0);
            case pr_hatypical:   return((haHigh+haLow+haClose)/3.0);
            case pr_haweighted:  return((haHigh+haLow+haClose+haClose)/4.0);
            case pr_haaverage:   return((haHigh+haLow+haClose+haOpen)/4.0);
            case pr_hatbiased:
               if (haClose>haOpen)
                     return((haHigh+haClose)/2.0);
               else  return((haLow+haClose)/2.0);        
            case pr_hatbiased2:
               if (haClose>haOpen)  return(haHigh);
               if (haClose<haOpen)  return(haLow);
                                    return(haClose);        
         }
   }
   
   //
   //
   //
   //
   //
   
   switch (tprice)
   {
      case pr_close:     return(close[i]);
      case pr_open:      return(open[i]);
      case pr_high:      return(high[i]);
      case pr_low:       return(low[i]);
      case pr_median:    return((high[i]+low[i])/2.0);
      case pr_medianb:   return((open[i]+close[i])/2.0);
      case pr_typical:   return((high[i]+low[i]+close[i])/3.0);
      case pr_weighted:  return((high[i]+low[i]+close[i]+close[i])/4.0);
      case pr_average:   return((high[i]+low[i]+close[i]+open[i])/4.0);
      case pr_tbiased:   
               if (close[i]>open[i])
                     return((high[i]+close[i])/2.0);
               else  return((low[i]+close[i])/2.0);        
      case pr_tbiased2:   
               if (close[i]>open[i]) return(high[i]);
               if (close[i]<open[i]) return(low[i]);
                                     return(close[i]);        
   }
   return(0);
}

//-------------------------------------------------------------------
//
//-------------------------------------------------------------------
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//------------------------------------------------------------------
//                                                                  
//------------------------------------------------------------------
//
//
//
//
//

void doAlert(string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
      if (previousAlert != doWhat || previousTime != Time[0]) {
          previousAlert  = doWhat;
          previousTime   = Time[0];

          //
          //
          //
          //
          //

          message = timeFrameToString(_Period)+" "+_Symbol+" at "+TimeToStr(TimeLocal(),TIME_SECONDS)+" Hull trend changed to "+doWhat;
             if (alertsMessage)   Alert(message);
             if (alertsPushNotif) SendNotification(message);
             if (alertsEmail)     SendMail(_Symbol+" Hull ",message);
             if (alertsSound)     PlaySound("alert2.wav");
      }
}



I try to read its buy and sell color histogram .

buy condition is

if previous red histo bar has value and current green histo bar has value , BUY 

 double HULLUP = iCustom (Symbol(),0,"HMA Histo alerts",HMAPeriod,0,0);
   double HULLDN = iCustom (Symbol(),0,"HMA Histo alerts",HMAPeriod,1,0);
   
     double up = iCustom (Symbol(),0,"HMA Histo alerts",HMAPeriods,0,0);
     
     double dn = iCustom (Symbol(),0,"HMA Histo alerts",HMAPeriods,1,0);
     
     double pup = iCustom (Symbol(),0,"HMA Histo alerts",HMAPeriods,0,1);
     
     double pdn = iCustom (Symbol(),0,"HMA Histo alerts",HMAPeriods,1,1);
   
   
   
    if(HULLDN!= EMPTY_VALUE&& pup != EMPTY_VALUE &&dn !=EMPTY_VALUE ) return(sell);
     if(HULLUP!= EMPTY_VALUE&& pdn != EMPTY_VALUE &&up !=EMPTY_VALUE ) return(buy);

but code cannot read RED AND GREEN .

what wrong in this HMA Histo indicator buffer value

Index page
Index page
  • forex-station.com
When it comes to the MetaTrader Platform, Forex Station is the #1 forex forum for sourcing Non Repainting MT4/MT5 Indicators, Trading Systems & EA's.
 
LONNV: but code cannot read RED AND GREEN . 
extern color              UpHistoColor    = clrLimeGreen;   // Up histogram color
extern color              DnHistoColor    = clrRed;         // Down histogram color

   SetIndexBuffer(0, hmaDa);   SetIndexStyle(0, DRAW_ARROW,EMPTY,HistoWidth,UpHistoColor);
   SetIndexBuffer(1, hmaDb);   SetIndexStyle(1, DRAW_ARROW,EMPTY,HistoWidth,DnHistoColor);
You should know that buffer index zero is green, one is red.


    if(HULLDN!= EMPTY_VALUE&& pup != EMPTY_VALUE &&dn !=EMPTY_VALUE ) return(sell);
     if(HULLUP!= EMPTY_VALUE&& pdn != EMPTY_VALUE &&up !=EMPTY_VALUE ) return(buy);

When it changes color, the previous value will be EMPTY_VALUE. Why are you looking for a non-EMPTY_VALUE.

 
William Roeder #:
You should know that buffer index zero is green, one is red.


When it changes color, the previous value will be EMPTY_VALUE. Why are you looking for a non-EMPTY_VALUE.

Cannot read value.

     double up = iCustom(Symbol(),0,"HMAhisto",0,0);
     
     double dn = iCustom(Symbol(),0,"HMAhisto",1,0);
     
     Print(" up " + up +"");
     Print(" Dn " + dn +"");
    
  


why ?

New comment