Download MetaTrader 5
To add comments, please log in or register
Interested in MetaTrader 5 features? Learn more about them!
Justify
59
Justify 2014.11.09 22:46 
I'm learning MQL4.
I'm studying programming in MTF.
Now I try to put zigzag "M30" in the current graph.

I made the following code, but does not show me the signs. What am I doing wrong?

#property copyright "2006-2014, MetaQuotes Software Corp."
#property link      "https://www.mql4.com"
#property strict

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_color1  Red
//---- indicator parameters
input int InpDepth=12;     // Depth
input int InpDeviation=5;  // Deviation
input int InpBackstep=3;   // Backstep
//---- indicator buffers
double ExtZigzagBuffer[];
double ExtHighBuffer[];
double ExtLowBuffer[];
//--- globals
int    ExtLevel=3; // recounting's depth of extremums
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
   if(InpBackstep>=InpDepth)
     {
      Print("Backstep cannot be greater or equal to Depth");
      return(INIT_FAILED);
     }
//--- 2 additional buffers
   IndicatorBuffers(3);
//---- drawing settings
   SetIndexStyle(0,DRAW_SECTION);
   
//---- indicator buffers
   SetIndexBuffer(0,ExtZigzagBuffer);
   SetIndexBuffer(1,ExtHighBuffer);
   SetIndexBuffer(2,ExtLowBuffer);
   SetIndexEmptyValue(0,0.0);
//---- indicator short name
   IndicatorShortName("ZigZag("+string(InpDepth)+","+string(InpDeviation)+","+string(InpBackstep)+")");
//---- initialization done
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long& tick_volume[],
                const long& volume[],
                const int& spread[])
  {
   int    i,limit,counterZ,whatlookfor=0;
   int    back,pos,lasthighpos=0,lastlowpos=0;
   double extremum;
   double curlow=0.0,curhigh=0.0,lasthigh=0.0,lastlow=0.0;
//--- check for history and inputs
   if(rates_total<InpDepth || InpBackstep>=InpDepth)
      return(0);
//--- first calculations
   if(prev_calculated==0)
      limit=InitializeAll();
   else 
     {
      //--- find first extremum in the depth ExtLevel or 100 last bars
      i=counterZ=0;
      while(counterZ<ExtLevel && i<100)
        {
         if(ExtZigzagBuffer[i]!=0.0)
            counterZ++;
         i++;
        }
      //--- no extremum found - recounting all from begin
      if(counterZ==0)
         limit=InitializeAll();
      else
        {
         //--- set start position to found extremum position
         limit=i-1;
         //--- what kind of extremum?
         if(ExtLowBuffer[i]!=0.0) 
           {
            //--- low extremum
            curlow=ExtLowBuffer[i];
            //--- will look for the next high extremum
            whatlookfor=1;
           }
         else
           {
            //--- high extremum
            curhigh=ExtHighBuffer[i];
            //--- will look for the next low extremum
            whatlookfor=-1;
           }
         //--- clear the rest data
         for(i=limit-1; i>=0; i--)  
           {
            ExtZigzagBuffer[i]=0.0;  
            ExtLowBuffer[i]=0.0;
            ExtHighBuffer[i]=0.0;
           }
        }
     }
//--- main loop      
   for(i=limit; i>=0; i--)
     {
      //--- find lowest low in depth of bars
      extremum=low[iLowest(NULL,PERIOD_M30,MODE_LOW,InpDepth,i)];
      //--- this lowest has been found previously
      if(extremum==lastlow)
         extremum=0.0;
      else 
        { 
         //--- new last low
         lastlow=extremum; 
         //--- discard extremum if current low is too high
         if(low[i]-extremum>InpDeviation*Point)
            extremum=0.0;
         else
           {
            //--- clear previous extremums in backstep bars
            for(back=1; back<=InpBackstep; back++)
              {
               pos=i+back;
               if(ExtLowBuffer[pos]!=0 && ExtLowBuffer[pos]>extremum)
                  ExtLowBuffer[pos]=0.0; 
              }
           }
        } 
      //--- found extremum is current low
      if(low[i]==extremum)
         ExtLowBuffer[i]=extremum;
      else
         ExtLowBuffer[i]=0.0;
      //--- find highest high in depth of bars
      extremum=high[iHighest(NULL,PERIOD_M30,MODE_HIGH,InpDepth,i)];
      //--- this highest has been found previously
      if(extremum==lasthigh)
         extremum=0.0;
      else 
        {
         //--- new last high
         lasthigh=extremum;
         //--- discard extremum if current high is too low
         if(extremum-high[i]>InpDeviation*Point)
            extremum=0.0;
         else
           {
            //--- clear previous extremums in backstep bars
            for(back=1; back<=InpBackstep; back++)
              {
               pos=i+back;
               if(ExtHighBuffer[pos]!=0 && ExtHighBuffer[pos]<extremum)
                  ExtHighBuffer[pos]=0.0; 
              } 
           }
        }
      //--- found extremum is current high
      if(high[i]==extremum)
         ExtHighBuffer[i]=extremum;
      else
         ExtHighBuffer[i]=0.0;
     }
//--- final cutting 
   if(whatlookfor==0)
     {
      lastlow=0.0;
      lasthigh=0.0;  
     }
   else
     {
      lastlow=curlow;
      lasthigh=curhigh;
     }
   for(i=limit; i>=0; i--)
     {
      switch(whatlookfor)
        {
         case 0: // look for peak or lawn 
            if(lastlow==0.0 && lasthigh==0.0)
              {
               if(ExtHighBuffer[i]!=0.0)
                 {
                  lasthigh=iHigh(NULL,PERIOD_M30,i);
                  lasthighpos=i;
                  whatlookfor=-1;
                  ExtZigzagBuffer[i]=lasthigh;
                 }
               if(ExtLowBuffer[i]!=0.0)
                 {
                  lastlow=iLow(NULL,PERIOD_M30,i);
                  lastlowpos=i;
                  whatlookfor=1;
                  ExtZigzagBuffer[i]=lastlow;
                 }
              }
             break;  
         case 1: // look for peak
            if(ExtLowBuffer[i]!=0.0 && ExtLowBuffer[i]<lastlow && ExtHighBuffer[i]==0.0)
              {
               ExtZigzagBuffer[lastlowpos]=0.0;
               lastlowpos=i;
               lastlow=ExtLowBuffer[i];
               ExtZigzagBuffer[i]=lastlow;
              }
            if(ExtHighBuffer[i]!=0.0 && ExtLowBuffer[i]==0.0)
              {
               lasthigh=ExtHighBuffer[i];
               lasthighpos=i;
               ExtZigzagBuffer[i]=lasthigh;
               whatlookfor=-1;
              }   
            break;               
         case -1: // look for lawn
            if(ExtHighBuffer[i]!=0.0 && ExtHighBuffer[i]>lasthigh && ExtLowBuffer[i]==0.0)
              {
               ExtZigzagBuffer[lasthighpos]=0.0;
               lasthighpos=i;
               lasthigh=ExtHighBuffer[i];
               ExtZigzagBuffer[i]=lasthigh;
              }
            if(ExtLowBuffer[i]!=0.0 && ExtHighBuffer[i]==0.0)
              {
               lastlow=ExtLowBuffer[i];
               lastlowpos=i;
               ExtZigzagBuffer[i]=lastlow;
               whatlookfor=1;
              }   
            break;               
        }
     }
//--- done
   return(rates_total);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int InitializeAll()
  {
   ArrayInitialize(ExtZigzagBuffer,0.0);
   ArrayInitialize(ExtHighBuffer,0.0);
   ArrayInitialize(ExtLowBuffer,0.0);
//--- first counting position
   return(Bars-InpDepth);
  }
//+------------------------------------------------------------------+

 Thank you very much

Justify
59
Justify 2014.11.10 09:07  
Any solution?
whroeder1
13607
whroeder1 2014.11.10 12:42  
justify: What am I doing wrong?
int OnCalculate(... const double &low[],
:
  for(i=limit; i>=0; i--)
:
      extremum=low[iLowest(NULL,PERIOD_M30,MODE_LOW,InpDepth,i)];

 and

             if(ExtHighBuffer[i]!=0.0)
                 {
                  lasthigh=iHigh(NULL,PERIOD_M30,i);
 
  1. Buffers are time series arrays (higher index is the past) OnCalculate's arrays are not. As the documentation says "you should unconditionally call the ArraySetAsSeries() function for those arrays, which are expected to work with." or just use the predefined array Low.
  2. "i" is an index into the chart's time frame, 1 minute ago, 2 minutes ago, etc.
  3. You then pass that to iLowest as a M30 index, 1*30 minutes ago, 2*30 minutes ago, etc.
  4. iLowest then returns the lowest M30 index (n*30 minutes ago,) which you use to index the current chart's time frame low[] as n*1 minutes ago.
  5. Do not mix apples and oranges.
    int iM30   = iBarShift(NULL, PERIOD_M30, Time[i]);
    int iM30LL = iLowest(NULL,PERIOD_M30,MODE_LOW,InpDepth,iM30);
          extremum=iLow(NULL, PERIOD_M30, iM30LL);
    
    and
    
                 if(ExtHighBuffer[i]!=0.0)
                     {
                      iM30   = iBarShift(NULL, PERIOD_M30, Time[i]);
                      lasthigh=iHigh(NULL,PERIOD_M30,iM30);
     
  6. The easier way would be to just use the iFractals function and not the code.
    for(int i=Bars - 1 - IndicatorCounted(); i >= 0; --i){
       int iM30   = iBarShift(NULL, PERIOD_M30, Time[i]);
       ExtHighBuffer[i] = iFractals(NULL, PERIOD_M30, MODE_UPPER, iM30);
       ExtLowBuffer[i]  = iFractals(NULL, PERIOD_M30, MODE_LOWER, iM30);
    }

Justify
59
Justify 2014.11.10 13:49  

Thanks for your answer.
I'm learning. With the "ifractals" function already made that change. Now I wont do it withzigzag, but I see it's more complicated than it seems. But yet
quite understand.
I then have to change everything about high, low and bar time, so that the calculations made as if in M30, but give signals in the current chart.
It is what I have to do?

Thank  you very much

Justify
59
Justify 2014.11.10 20:53  

I tried several ways but still can not find the solution.

Thank you very much

SYED NAUFAL GADDAFI
1401
SYED NAUFAL GADDAFI 2014.11.11 12:06  

If I not mistaken, the zigzag would produce on current chart regardless timeframe settings. So, try on M30 chart.


By the way, M15 != M30 of how the chart is rendered. That is why the zigzag behaves like that (if I not mistaken).

/
To add comments, please log in or register