initializing buffers

[Ian Venner]

This is part of the bollinger bands source code why is it neccessary to initialize the buffers to zero with EMPTY_VALUE ? Should I be doing this in my own indicators ?

//+------------------------------------------------------------------+
//| Bollinger Bands                                                  |
//+------------------------------------------------------------------+
int start()
  {
   int    i,k,counted_bars=IndicatorCounted();
   double deviation;
   double sum,oldval,newres;
//----
   if(Bars<=BandsPeriod) return(0);
//---- initial zero
   if(counted_bars<1)
      for(i=1;i<=BandsPeriod;i++)
        {
         MovingBuffer[Bars-i]=EMPTY_VALUE;
         UpperBuffer[Bars-i]=EMPTY_VALUE;
         LowerBuffer[Bars-i]=EMPTY_VALUE;
        }
//----
   int limit=Bars-counted_bars;
   if(counted_bars>0) limit++;
   for(i=0; i<limit; i++)
      MovingBuffer[i]=iMA(NULL,0,BandsPeriod,BandsShift,MODE_SMA,PRICE_CLOSE,i);
//----
   i=Bars-BandsPeriod+1;
   if(counted_bars>BandsPeriod-1) i=Bars-counted_bars-1;
   while(i>=0)
     {
      sum=0.0;
      k=i+BandsPeriod-1;
      oldval=MovingBuffer[i];
      while(k>=i)
        {
         newres=Close[k]-oldval;
         sum+=newres*newres;
         k--;
        }
      deviation=BandsDeviations*MathSqrt(sum/BandsPeriod);
      UpperBuffer[i]=oldval+deviation;
      LowerBuffer[i]=oldval-deviation;
      i--;
     }
//----
   return(0);
  }

[brewmanz]

EMPTY_VALUE means 'do not display/draw this value'

It is not the same as 0

[William Roeder]

And it's only doing that on the few initial bars buffer[Bars-1]..buffers[Bars-period]

Those bars can't be used as SMA(x) doesn't work when there's less then x bars on the chart.

[Ian Venner]

Ahhh yes thanks WHR thats what I was missing !! I couldnt see the point of doing that until you mentioned the SMA(x) and the periods, now it makes sense