实时的提基

Andrey Khatimlianskii 2020.01.29 12:33 #31

Vladimir Mikhailov:

实验的一个小总结，有打勾分析。

1.OnTick处理程序跳过了大量的ticks。
因此，如果你想通过传入的勾股来分析交易的条数，那是没有意义的。
采用这种方法，在测试器中的算法结果和真实的交易结果将是不同的。

作为一种选择，你可以通过使用CopyTicks()或CopyTicksRange()函数来获取历史上的ticks，从而分析选定时期或一定数量的最后一次交易的条形。
在这种情况下，在测试器中测试算法的结果和真实交易结果是一样的。
其缺点是算法的性能较低。

是的，专家顾问可能会错过点位。因此，不是指标就是CopyTicks。

而性能下降是由于什么？只复制所需的部分（自上次成功检索数据后出现的部分）。

prostotrader 2020.01.29 17:06 #32

Andrey Khatimlianskii:

如果无论如何都要使用CopyTicks，为什么要 "实时 "收集它们？

你可以在任何时候把刻度线复制到正确的深度。

安德鲁，请阅读该主题的标题

添加

你不能用CopyTicks()把它弄到正确的深度，它只有2000个刻度!

Andrey Khatimlianskii 2020.01.30 11:35 #33

prostotrader:

安德烈，请阅读该主题的标题

事实上，任务最初的设置是不正确的，怎么办？

实时分析ticks是可能的，但有必要使用指标或CopyTicks来避免空隙。

嫖娼者。

你不能用CopyTicks()获得所需的深度，但只有2000个刻度!

没有这样的限制，见文件中的例子。

Пример вывода
Si-12.16: received 11048387  ticks in 4937 ms
Last tick time = 2016.09.26 18:32:59.775 
First tick time = 2015.06.18 09:45:01.000

Документация по MQL5: Доступ к таймсериям и индикаторам / CopyTicks

www.mql5.com

[in] Количество запрашиваемых тиков. Если параметры from и count не указаны, то в массив ticks_array[] будут записаны все доступные последние тики, но не более 2000. Первый вызов CopyTicks() инициирует синхронизацию базы тиков, хранящихся на жёстком диске по данному символу. Если тиков в локальной базе не хватает, то недостающие тики...

prostotrader 2020.01.30 12:20 #34

Andrey Khatimlianskii:

事实上，任务最初的设置是不正确的，怎么办？

实时刻度分析是可能的，但你必须使用一个指标或CopyTicks来确保没有遗漏。

没有这样的限制，见文件中的例子。

1.不一定是一个指标!

如果你指的是帮助，它说

在专家顾问和脚本中，CopyTicks()函数最多可以等待45秒....。

如果你读到最后，它说

输出速度：终端为每个字符在缓存中存储了4096个最后的刻度，以便快速访问（堆栈运行的字符为65536个刻度），对这些数据的查询是最快的。

当一包新的刻度线到达终端时，OnBookEvent()事件被触发，因此

有可能从专家顾问那里收集刻度线。举个例子，检查一下。

//+------------------------------------------------------------------+
//|                                                   Ticks_test.mq5 |
//|                                      Copyright 2019 prostotrader |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2019 prostotrader"
#property link      "https://www.mql5.com"
#property version   "1.00"
//---
bool is_book;
MqlTick ticks[];
ulong last_time, mem_time;
bool is_first;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
    is_first = false;
    is_book = MarketBookAdd(Symbol());
    int result = CopyTicks(Symbol(), ticks, COPY_TICKS_ALL, 0, 1);
    if(result > 0)
    {
      last_time = ticks[0].time_msc;
      is_first = true;
    }
    else
    {
      Alert("No start time!");
      return(INIT_FAILED);
    }   
   
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
    if(is_book == true) MarketBookRelease(Symbol());
   
  }
void PrintResult(const int cnt)
{
  if(cnt > 0)
  {
    for(int i= 0; i<cnt; i++)
    {
      if((ticks[i].flags&TICK_FLAG_ASK)==TICK_FLAG_ASK) Print("Tick is ", "TICK_FLAG_ASK"); else
      if((ticks[i].flags&TICK_FLAG_BID)==TICK_FLAG_BID) Print("Tick is ", "TICK_FLAG_BID"); else
      if((ticks[i].flags&TICK_FLAG_BUY)==TICK_FLAG_BUY) Print("Tick is ", "TICK_FLAG_BUY"); else
      if((ticks[i].flags&TICK_FLAG_LAST)==TICK_FLAG_LAST) Print("Tick is ", "TICK_FLAG_LAST"); else
      if((ticks[i].flags&TICK_FLAG_SELL)==TICK_FLAG_SELL) Print("Tick is ", "TICK_FLAG_SELL"); else
      if((ticks[i].flags&TICK_FLAG_VOLUME)==TICK_FLAG_VOLUME) Print("Tick is ", "TICK_FLAG_VOLUME"); else
      Print("Unknown flag is ", ticks[i].flags);
    }
  }
}  
//+------------------------------------------------------------------+
//| BookEvent function                                               |
//+------------------------------------------------------------------+
void OnBookEvent(const string &symbol)
  {
    if(Symbol() == symbol)
    {
      int result;
      if(is_first == true)
      {
        Print("First packet of ticks:");
        result = CopyTicks(Symbol(), ticks, COPY_TICKS_ALL, last_time, 0);
        if(result > 0)
       {
         PrintResult(result);
         is_first = false;
         mem_time = last_time;
         last_time = ticks[0].time_msc + 1;
       } 
      }
      else
      {
        result = CopyTicks(Symbol(), ticks, COPY_TICKS_ALL, mem_time, 0);
        if(result > 0)
        {
          for(int i= 0; i<result; i++)
          {
            if(ticks[i].time_msc == mem_time)
            {
              Print("Tick with old time:");
              if((ticks[i].flags&TICK_FLAG_ASK)==TICK_FLAG_ASK) Print("Tick is ", "TICK_FLAG_ASK"); else
              if((ticks[i].flags&TICK_FLAG_BID)==TICK_FLAG_BID) Print("Tick is ", "TICK_FLAG_BID"); else
              if((ticks[i].flags&TICK_FLAG_BUY)==TICK_FLAG_BUY) Print("Tick is ", "TICK_FLAG_BUY"); else
              if((ticks[i].flags&TICK_FLAG_LAST)==TICK_FLAG_LAST) Print("Tick is ", "TICK_FLAG_LAST"); else
              if((ticks[i].flags&TICK_FLAG_SELL)==TICK_FLAG_SELL) Print("Tick is ", "TICK_FLAG_SELL"); else
              if((ticks[i].flags&TICK_FLAG_VOLUME)==TICK_FLAG_VOLUME) Print("Tick is ", "TICK_FLAG_VOLUME"); else
              Print("Unknown flag is ", ticks[i].flags);
            }
          }
        }
        result = CopyTicks(Symbol(), ticks, COPY_TICKS_ALL, last_time, 0);
        if(result > 0)
        {
          Print("Ticks with new time:");
          PrintResult(result);
          mem_time = last_time;
          last_time = ticks[0].time_msc + 1;
        }
      }
    }
 }
//+------------------------------------------------------------------+

2.有这样的限制，请自己检查（CopyTicksRange() 没有限制）。

Andrey Khatimlianskii 2020.01.30 12:44 #35

prostotrader:

1.不一定是一个指标!

当一个新的蜱虫包到达终端时，OnBookEvent()事件被触发，所以

有可能从专家顾问那里收集刻度线。举个例子，看看吧。

OnBookEvent并不能保证不漏掉这些点滴。如果那里有繁重的计算，就会出现和OnTick一样的跳转。

而且，通过CopyTicks从哪里复制必要的深度的ticks并不重要。

嫖娼者。

2.有这样的限制，请自己检查

它只存在于参数0，0，这在帮助中被明确提到。

Если параметры from и count не указаны, то в массив ticks_array[] будут записаны все доступные последние тики, но не более 2000.

prostotrader 2020.01.30 12:52 #36

Andrey Khatimlianskii:

OnBookEvent并不保证不会漏掉任何一个点位。

我重复

OnBookEvent()恰恰给出了这样的保证，即新的一批蜱虫已经到来!

从参考资料来看。

发放率。终端在快速访问缓存中为每个字符存储了4096个最后的刻度（对于堆栈运行的字符，65536个刻度），对这些数据的查询是最快的。

结束语：----

如果OnBookEvent没有被触发，MT5中的所有交易（交易所）都可能被扔进垃圾桶！这是不可能的。

新的蜱虫包到达了 - 100%触发了OnBookEvent，CopyTicks()显示有多少蜱虫到达。

数据已经存储在缓存中，而且是最快的访问速度!

这就是为什么在指标和EA中可以实时实现ticks的收集（当市场运行时）。

由以下人员添加

拿着上面的代码，检查一下，比起争论...

prostotrader 2020.01.30 14:14 #37

蜱虫采集器的代码是正确的，但有一些实施错误。

并稍后发布。

添加

实时收集专家顾问的所有刻度线

请使用

//+------------------------------------------------------------------+
//|                                                   Ticks_test.mq5 |
//|                                      Copyright 2019 prostotrader |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2019 prostotrader"
#property link      "https://www.mql5.com"
#property version   "1.00"
//---
bool is_book;
MqlTick ticks[];
ulong last_time, mem_cnt;
bool is_first;
int t_cnt, result;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
{
  is_book = MarketBookAdd(Symbol());
  result = CopyTicks(Symbol(), ticks, COPY_TICKS_ALL, 0, 1);
  if(result > 0)
  {
    last_time = ulong(ticks[0].time_msc);
    is_first = true;
  }
  else
  {
    is_first = false;
    Alert("No start time!");
    return(INIT_FAILED);
  }   
  return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+ 
//| возвращает строковое описание тика                               | 
//+------------------------------------------------------------------+ 
string GetTickDescription(MqlTick &tick) 
  { 
   string res = string(tick.time) + "." +  string(tick.time_msc%1000); 
// 
   bool buy_tick = ((tick.flags&TICK_FLAG_BUY)==TICK_FLAG_BUY); 
   bool sell_tick = ((tick.flags&TICK_FLAG_SELL)==TICK_FLAG_SELL); 
   bool ask_tick = ((tick.flags&TICK_FLAG_ASK)==TICK_FLAG_ASK); 
   bool bid_tick = ((tick.flags&TICK_FLAG_BID)==TICK_FLAG_BID); 
   bool last_tick = ((tick.flags&TICK_FLAG_LAST)==TICK_FLAG_LAST); 
   bool volume_tick = ((tick.flags&TICK_FLAG_VOLUME)==TICK_FLAG_VOLUME); 
// 
   if((buy_tick== true) || (sell_tick == true)) 
   { 
     res = res + (buy_tick?StringFormat(" Buy Tick: Last=%G Volume=%d ",tick.last,tick.volume):""); 
     res = res + (sell_tick?StringFormat(" Sell Tick: Last=%G Volume=%d ",tick.last,tick.volume):""); 
     res = res + (ask_tick?StringFormat(" Ask=%G ",tick.ask):""); 
     res = res + (bid_tick?StringFormat(" Bid=%G ",tick.ask):""); 
   } 
   else 
   { 
     res = res + (ask_tick?StringFormat(" Ask=%G ",tick.ask):""); 
     res = res + (bid_tick?StringFormat(" Bid=%G ",tick.ask):""); 
     res = res + (last_tick?StringFormat(" Last=%G ",tick.last):""); 
     res = res + (volume_tick?StringFormat(" Volume=%d ",tick.volume):""); 
   } 
   return res; 
  } 
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
  if(is_book == true) MarketBookRelease(Symbol());
}
//+------------------------------------------------------------------+
//| BookEvent function                                               |
//+------------------------------------------------------------------+
//void OnTick()
void OnBookEvent(const string &symbol)
{
  if(Symbol() == symbol)
  {
    if(is_first == true)
    {
      result = CopyTicks(Symbol(), ticks, COPY_TICKS_ALL, last_time, 0);
      if(result > 0)
      {
        Print("First packet of ticks:");
        t_cnt = 0;
        for(int i= 0; i<result; i++)
        {
          if(ticks[i].time_msc == ticks[0].time_msc) t_cnt++;
          Print(GetTickDescription(ticks[i]));
        }
        is_first = false;
        last_time = ulong(ticks[0].time_msc);
      } 
    }
    else
    {
      result = CopyTicks(Symbol(), ticks, COPY_TICKS_ALL, last_time, 0);
      if(result > 0)
      {
        if(result > t_cnt)
        {
          mem_cnt = t_cnt;
          t_cnt = 0;
          for(int i= 0; i<(result - int(mem_cnt)); i++)
          {
            if(ticks[i].time_msc == ticks[0].time_msc) t_cnt++;
            Print(GetTickDescription(ticks[i]));
          } 
          if(last_time == ulong(ticks[0].time_msc))
          {
            t_cnt += int(mem_cnt);
          }
          else last_time = ulong(ticks[0].time_msc + 1);
        }
        else
        {
          t_cnt = 0;
          last_time++;
        }
      }
      else
      {
        t_cnt = 0;
        last_time++;
      }
    }
  }
}
//+------------------------------------------------------------------+

prostotrader 2020.01.30 15:00 #38

为了比较ticks收集器是如何工作的，你可以从它的一个点上做一个所有交易的Ribbon

(通过在两处用COPY_TICKS_TRADE代替COPY_TICKS_ALL），并将其与交易色带进行比较。

嵌入仪器玻璃中。

如果票据的流动性很强，打印时可能会有很长的延迟。

Aleksey Mavrin 2020.01.30 15:49 #39

prostotrader:

 if((ticks[i].flags&TICK_FLAG_ASK)==TICK_FLAG_ASK) {Print("Tick is ", "TICK_FLAG_ASK", " Tick time: ", ticks[i].time, ".", string(t_msc));} else
          if((ticks[i].flags&TICK_FLAG_BID)==TICK_FLAG_BID) {Print("Tick is ", "TICK_FLAG_BID", " Tick time: ", ticks[i].time,  ".", string(t_msc));} else
          if((ticks[i].flags&TICK_FLAG_BUY)==TICK_FLAG_BUY) {Print("Tick is ", "TICK_FLAG_BUY", " Tick time: ", ticks[i].time,  ".", string(t_msc));} else
          if((ticks[i].flags&TICK_FLAG_LAST)==TICK_FLAG_LAST) {Print("Tick is ", "TICK_FLAG_LAST", " Tick time: ", ticks[i].time,  ".", string(t_msc));} else
          if((ticks[i].flags&TICK_FLAG_SELL)==TICK_FLAG_SELL) {Print("Tick is ", "TICK_FLAG_SELL", " Tick time: ", ticks[i].time,  ".", string(t_msc));} else
          if((ticks[i].flags&TICK_FLAG_VOLUME)==TICK_FLAG_VOLUME) {Print("Tick is ", "TICK_FLAG_VOLUME", " Tick time: ", ticks[i].time,  ".", string(t_msc));} else

蜱虫不能同时拥有一个以上的标志吗？

Aleksey Mavrin 2020.01.30 15:51 #40

prostotrader:

重复进行

OnBookEvent()恰恰是新一批蜱虫到来的保证!

但这是否意味着可以保证你能处理所有的OnBookEvent事件？

实时的提基 - 页 4