MetaEditor build 1490

Andrey Dik 2016.12.04 20:50 #21

fxsaber:
没有办法定义它。SL和TP完全是MT服务器的本质。

最可靠的方式（除非经纪人改变评论格式，这是不可能的事情）。

Viktor Mossekhin 2016.12.04 22:26 #22

这就是它的作用。

void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
   if(trans.type==TRADE_TRANSACTION_DEAL_ADD)
     {
      datetime end=TimeCurrent();
      datetime start=end-end%PeriodSeconds(PERIOD_D1);
      ResetLastError();
      if(!HistorySelect(start,end))
        {
         Print("Getting deals history failed. Error ",GetLastError());
         return;
        }
      ulong ticket=HistoryDealGetTicket(HistoryDealsTotal()-1);
      if(ticket==trans.deal)
        {
         if(HistoryDealGetInteger(ticket,DEAL_ENTRY)==DEAL_ENTRY_OUT &&
            (StringFind(HistoryDealGetString(ticket,DEAL_COMMENT),"tp")!=-1
            || StringFind(HistoryDealGetString(ticket,DEAL_COMMENT),"sl")!=-1))
           {
            Print(HistoryDealGetString(ticket,DEAL_SYMBOL),"  Profit= ",HistoryDealGetDouble(ticket,DEAL_PROFIT),"  ticket=",ticket);
           }
        }
     }
  }

MetaEditor build 1490 初学者的问题 MQL5 MT5 MetaTrader 贸易交易时

fxsaber 2016.12.05 00:31 #23

现实生活中的工作选项（不是为测试者）。

void OnTradeTransaction ( const MqlTradeTransaction &Trans, const MqlTradeRequest &Request, const MqlTradeResult &Result )
{
  if ((Trans.type == TRADE_TRANSACTION_ORDER_ADD) &&
       PositionSelectByTicket(Trans.position) && OrderSelect(Trans.order) &&
       (PositionGetInteger(POSITION_TYPE) == 1 - OrderGetInteger(ORDER_TYPE)))
  {
    const double Price = OrderGetDouble(ORDER_PRICE_OPEN);

    if (Price == PositionGetDouble(POSITION_TP))
      Print("Position #" + (string)Trans.position + " - triggered TP.");
    else if (Price == PositionGetDouble(POSITION_SL))
      Print("Position #" + (string)Trans.position + " - triggered SL.");
  }
}

mql5语言的特点、微妙之处以及技巧错误、漏洞、问题 MetaEditor build 1490

Andrey Dik 2016.12.05 04:04 #24

fxsaber:
真正的工作变体（不是为测试者）。

void OnTradeTransaction ( const MqlTradeTransaction &Trans, const MqlTradeRequest &Request, const MqlTradeResult &Result )
{
  if ((Trans.type == TRADE_TRANSACTION_ORDER_ADD) &&
       PositionSelectByTicket(Trans.position) && OrderSelect(Trans.order) &&
       (PositionGetInteger(POSITION_TYPE) == 1 - OrderGetInteger(ORDER_TYPE)))
  {
    const double Price = OrderGetDouble(ORDER_PRICE_OPEN);

    if (Price == PositionGetDouble(POSITION_TP))
      Print("Position #" + (string)Trans.position + " - triggered TP.");
    else if (Price == PositionGetDouble(POSITION_SL))
      Print("Position #" + (string)Trans.position + " - triggered SL.");
  }
}

我在测试器中进行了检查--它不起作用，我想它在现实中也不起作用，因为它所检查的位置已经不存在了。

fxsaber 2016.12.05 05:24 #25

Andrey Dik:
我在测试器中进行了检查--它不起作用，而且我认为它在现实中也不起作用，因为测试的位置已经不存在了。

这是测试器中的一个人为错误（以便完全不减慢它的速度）。仅仅从逻辑上看，一切都很正确。

Andrey Dik 2016.12.05 06:35 #26

void OnTick ()
{
  string s = DoubleToString(PosTotalCommissSwap (Symbol (), true, true), 4);

  Comment (s);
}
//+------------------------------------------------------------------+

// Подсчет комиссий и свопов указанной позиции по символу
double PosTotalCommissSwap (string symb, bool commiss, bool swap)
{
  int posTotal = PositionsTotal (); //всего открытых позиций
  Print (posTotal);

  //пройдем по всем открытым позициям
  for(int i = posTotal - 1; i >=0; i--)
  {
    string posSymb = PositionGetSymbol (i);
    Print (posSymb);

    //если найдена позиция по указанному символу
    if(symb == posSymb)
    {
      Print ("Позиция найдена");
      long posID  = PositionGetInteger (POSITION_IDENTIFIER);

      //выберем историю сделок, относящуюся к выбранной позиции
      if(HistorySelectByPosition (posID))
      {
        int dealsTotal = HistoryDealsTotal ();  //всего сделок в истории позиции
        Print ("Всего сделок в позиции: " + dealsTotal);
        double fees = 0.0; //все комиссии и свопы

        //пройдем по всем сделкам позиции
        for(int k = 0; k < dealsTotal; k++)
        {
          ulong dealTicket = HistoryDealGetTicket (k); //тикет сделки

          if(commiss)
            fees += HistoryDealGetDouble (dealTicket, DEAL_COMMISSION);

          if(swap)
            fees += HistoryDealGetDouble (dealTicket, DEAL_SWAP);
        }

        return (fees);
      }
      else
        Print ("Историю сделок выбрать не удалось");
    }
  }

  return (0.0);
}

似乎打破了按职位ID选择交易历史的做法。

有时打印（有时不打印）写

2016.12.05 11:26:11.767 获取当前位置（GBPUSD,M5）的佣金 1

2016.12.05 11:26:11.767 获取当前位置（GBPUSD,M5）的佣金 GBPUSD

2016.12.05 11:26:11.767 获取当前佣金的位置(GBPUSD,M5) 发现位置

2016.12.05 11:26:11.767 获取当前仓位（GBPUSD,M5）的佣金仓位中的总交易量：0

厚颜无耻的谎言，位置还在那里!

MetaEditor build 1490 初学者的问题 MQL5 MT5 MetaTrader 错误、漏洞、问题

fxsaber 2016.12.05 07:00 #27

Andrey Dik:

看起来，按职位ID选择交易历史的做法已经失效。

如果它发生在OrderSend之后，那就可以了。

Andrey Dik 2016.12.05 07:06 #28

fxsaber:
如果它发生在OrderSend之后，那是正常的。

不，这在任何方面都是不正常的。在任何情况下，都有一个职位，因此有参与其 "生活 "的交易。但奇怪的是，即使EA已经入仓，代码也看不到交易，我们在日志中看到了这一点，仓位数量被定义，符号的位置被选择，但其中没有交易......

fxsaber 2016.12.05 07:11 #29

Andrey Dik:
不，这在任何方面都是不正常的。在任何情况下，都有一个职位，因此也有参与其 "生活 "的交易。更奇怪的是，即使专家顾问已经有了头寸，代码也看不到交易...

雷纳特说这是正常的，不要争论!下面是关于OrderSend的解决方案

关于交易、自动交易系统和策略测试的论坛

如何在MT5中正确使用OrderSend？

fxsaber, 2016.11.19 23:59

从库中翻出OrderSendSync，在此。

uint OrderSend_MaxPause = 1000000; // максимальное время на синхронизацию в мкс.

const bool IsTester = (::MQLInfoInteger(MQL_TESTER) || ::MQLInfoInteger(MQL_OPTIMIZATION) ||
                       ::MQLInfoInteger(MQL_VISUAL_MODE) || ::MQLInfoInteger(MQL_FRAME_MODE));



bool Waiting( const bool FlagInit = false )
{
  static ulong StartTime = 0;

  if (FlagInit)
    StartTime = ::GetMicrosecondCount();

  const bool Res = (::GetMicrosecondCount() - StartTime < OrderSend_MaxPause);

  if (Res)
    ::Sleep(0);

  return(Res);
}

bool EqualPrices( const double Price1, const double Price2, const int digits)
{
  return(::NormalizeDouble(Price1 - Price2, digits) == 0);
}

#define WHILE(A) while (!(Res = (A)) && Waiting())

bool OrderSendSync( const MqlTradeRequest &Request, MqlTradeResult &Result )
{
  bool Res = ::OrderSend(Request, Result);

  if (Res && !IsTester && (Result.retcode < TRADE_RETCODE_ERROR) && (OrderSend_MaxPause > 0))
  {
    Res = (Result.retcode == TRADE_RETCODE_DONE);
    Waiting(true);

    if (Request.action == TRADE_ACTION_DEAL)
    {
      WHILE(::HistoryOrderSelect(Result.order))
        ;

      Res = Res && (((ENUM_ORDER_STATE)::HistoryOrderGetInteger(Result.order, ORDER_STATE) == ORDER_STATE_FILLED) ||
                    ((ENUM_ORDER_STATE)::HistoryOrderGetInteger(Result.order, ORDER_STATE) == ORDER_STATE_PARTIAL));

      if (Res)
        WHILE(::HistoryDealSelect(Result.deal))
          ;
    }
    else if (Request.action == TRADE_ACTION_PENDING)
    {
      if (Res)
        WHILE(::OrderSelect(Result.order))
          ;
      else
      {
        WHILE(::HistoryOrderSelect(Result.order))
          ;

        Res = false;
      }
    }
    else if (Request.action == TRADE_ACTION_SLTP)
    {
      if (Res)
      {
        bool EqualSL = false;
        bool EqualTP = false;

        const int digits = (int)::SymbolInfoInteger(Request.symbol, SYMBOL_DIGITS);

        if ((Request.position == 0) ? ::PositionSelect(Request.symbol) : ::PositionSelectByTicket(Request.position))
        {
          EqualSL = EqualPrices(::PositionGetDouble(POSITION_SL), Request.sl, digits);
          EqualTP = EqualPrices(::PositionGetDouble(POSITION_TP), Request.tp, digits);
        }

        WHILE((EqualSL && EqualTP))
          if ((Request.position == 0) ? ::PositionSelect(Request.symbol) : ::PositionSelectByTicket(Request.position))
          {
            EqualSL = EqualPrices(::PositionGetDouble(POSITION_SL), Request.sl, digits);
            EqualTP = EqualPrices(::PositionGetDouble(POSITION_TP), Request.tp, digits);
          }
      }
    }
    else if (Request.action == TRADE_ACTION_MODIFY)
    {
      if (Res)
      {
        bool EqualSL = false;
        bool EqualTP = false;

        const int digits = (int)::SymbolInfoInteger(Request.symbol, SYMBOL_DIGITS);

        if (::OrderSelect(Result.order))
        {
          EqualSL = EqualPrices(::OrderGetDouble(ORDER_SL), Request.sl, digits);
          EqualTP = EqualPrices(::OrderGetDouble(ORDER_TP), Request.tp, digits);
        }

        WHILE((EqualSL && EqualTP))
          if (::OrderSelect(Result.order))
          {
            EqualSL = EqualPrices(::OrderGetDouble(ORDER_SL), Request.sl, digits);
            EqualTP = EqualPrices(::OrderGetDouble(ORDER_TP), Request.tp, digits);
          }
      }
    }
    else if (Request.action == TRADE_ACTION_REMOVE)
      if (Res)
        WHILE(::HistoryOrderSelect(Result.order))
          ;
  }

  return(Res);
}

#undef WHILE

代码的想法应该是明确的。我可能忽略了一些东西。我没有注意到操作中的任何错误。

如果你使用这个OrderSend，你就不会有这样的问题。

要么等待OnTradeTransaction中的适当信息。

如何在MT5中正确使用OrderSend？ mql5语言的特点、微妙之处以及技巧 How to work correctly

Andrey Dik 2016.12.05 07:20 #30

fxsaber:
雷纳特说这是正常的，不要争论!下面是关于OrderSend的解决方案

如果你使用这个OrderSend，将不会有这样的问题。

或者等待OnTradeTransaction中的适当信息。

不，这是不正常的。

有一个位置。我们将专家顾问发送至图表。我们没有所选职位的交易历史。这里的正常情况是什么？）

MetaEditor build 1490 - 页 3