错误、漏洞、问题 - 页 2270

新评论
 

有什么区别

SetIndexBuffer(1,ValuePainting,INDICATOR_COLOR_INDEX)。

и

PlotIndexSetInteger(0,PLOT_LINE_COLOR,1,clrBlue)。

?

我在扭动代码，不知道如何给毛翼 上色。

如果一种颜色在增长，另一种颜色在下降。

谁能给我举个例子？

 
Vladimir Pastushak:

我在旋转代码，但我不知道如何给毛翼上色。

如果一种颜色上升，如果另一种颜色下降。

谁能给我举个例子？

我只是在学习MQL5，但它应该看起来像这样。

//+------------------------------------------------------------------+
//|                                                         myMA.mq5 |
//|                                                            IgorM |
//|                              https://www.mql5.com/ru/users/igorm |
//+------------------------------------------------------------------+
#property copyright "IgorM"
#property link      "https://www.mql5.com/ru/users/igorm"
#property version   "1.00"
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot Red
#property indicator_label1  "Red"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrRed
#property indicator_style1  STYLE_SOLID
#property indicator_width1  2
//--- plot Blue
#property indicator_label2  "Blue"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrBlue
#property indicator_style2  STYLE_SOLID
#property indicator_width2  2
//--- input parameters
input int      PeriodMA=10;
//--- indicator buffers
double         RedBuffer[];
double         BlueBuffer[];
int handleMA;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   ArraySetAsSeries(RedBuffer,true);
   ArraySetAsSeries(BlueBuffer,true);
   SetIndexBuffer(0,RedBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,BlueBuffer,INDICATOR_DATA);
   handleMA=iMA(NULL,0,PeriodMA,0,MODE_SMA,PRICE_CLOSE);

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const int begin,
                const double &price[])
  {
//---
   int i,limit;
   double ma[];
   if(prev_calculated==0) limit=rates_total-2; else limit=rates_total-prev_calculated;
   for(i=limit;i>=0;i--)
     {
      CopyBuffer(handleMA,0,i,2,ma);
      if(ma[0]<ma[1])
        {
         RedBuffer[i]=ma[0]; BlueBuffer[i]=EMPTY_VALUE;
        }
      else
        {
         BlueBuffer[i]=ma[0];RedBuffer[i]=EMPTY_VALUE;
        }
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
 
一个编译错误。
template<typename T>
void f( T& ) {}
void g1() { class A {} a; f( a ); } //(1)//нормально 
void g2() { class A {} a; f( a ); } //(2)//Error: '&' - parameter conversion not allowed

1）和（2）之间的根本区别是什么？为什么一种情况下有错误，另一种情况下有正常的错误？

 
A100:

而（1）和（2）之间的根本区别是什么？为什么一种情况下有错误，而另一种情况下正常？

因此，函数中的类可以有相同的名称，但内容不同。在第二个变体中，签名f并不明确。

在第一种情况下，它被定义为。而在第二次之后，它不会以相同的名字重新定义。

 
Vladimir Pastushak:

有什么区别

SetIndexBuffer(1,ValuePainting,INDICATOR_COLOR_INDEX)。

и

PlotIndexSetInteger(0,PLOT_LINE_COLOR,1,clrBlue)。

?

我在扭动代码，不知道如何给毛翼上色。

如果一种颜色在增长，另一种颜色在下降。

谁能给我举个例子？

//+------------------------------------------------------------------+
//|                                                      ColorMA.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                             https://mql5.com/ru/users/artmedia70 |
//+------------------------------------------------------------------+
#property copyright "Copyright 2018, MetaQuotes Software Corp."
#property link      "https://mql5.com/ru/users/artmedia70"
#property version   "1.00"
#property description "Colored Moving Average"
#property indicator_chart_window
#property indicator_buffers 2    // Всего буферов 2 - рисуемый буфер и буфер цвета
#property indicator_plots   1    // Один рисуемый буфер
//--- plot ClrMA
#property indicator_label1  "Colored MA"
#property indicator_type1   DRAW_COLOR_LINE
#property indicator_color1  clrBlue,clrRed,clrDarkGray
#property indicator_style1  STYLE_SOLID
#property indicator_width1  2
//--- input parameters
input uint                 InpPeriod         =  14;            // Период расчёта
input ENUM_MA_METHOD       InpMethod         =  MODE_SMA;      // Метод расчёта
input ENUM_APPLIED_PRICE   InpAppliedPrice   =  PRICE_CLOSE;   // Цена расчёта
//--- indicator buffers
double         BufferMA[];       // Рисуемый буфер
double         BufferColors[];   // Буфер цвета
//--- global variables
int            period;
int            handle_ma;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- set global variables
   period=int(InpPeriod<1 ? 1 : InpPeriod);
//--- indicator buffers mapping
   SetIndexBuffer(0,BufferMA,INDICATOR_DATA);            // Рисуемый буфер
   SetIndexBuffer(1,BufferColors,INDICATOR_COLOR_INDEX); // Буфер цвета
//--- setting indicator parameters
   IndicatorSetString(INDICATOR_SHORTNAME,"Colored MA");
   IndicatorSetInteger(INDICATOR_DIGITS,Digits());
//--- setting buffer arrays as timeseries
   ArraySetAsSeries(BufferMA,true);
   ArraySetAsSeries(BufferColors,true);
//--- create MA's handles
   ResetLastError();
   handle_ma=iMA(NULL,PERIOD_CURRENT,period,0,InpMethod,InpAppliedPrice);
   if(handle_ma==INVALID_HANDLE)
     {
      Print("Не удалось создать хэндл iMA(",(string)period,") ",EnumToString(InpAppliedPrice),". Ошибка: ",GetLastError());
      return INIT_FAILED;
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- Проверка и расчёт количества просчитываемых баров
   if(rates_total<fmax(period,4)) return 0;  // три бара и меньше в расчёт не берём
//--- Проверка и расчёт количества просчитываемых баров
   int limit=rates_total-prev_calculated;
   if(limit>1)
     {
      /*
      Почему больше 1. Например, загрузилась история, и разница будет больше одного.
      Если все нормально, то разница rates_total-prev_calculated равна или 0, или 1
      0 - пришел новый тик, новый бар формироваться не начал.
      1 - пришел новый тик и начал формироваться новый бар
      */
      limit=rates_total-2; // rates_total - это Bars для текущего символа и периода
                           // Если не требуется проверять в цикле расчёта i+число, то limit=rates_total-1 (чтобы не вылететь за пределы массива), 
                           // иначе, если требуется проверять, например, i+period, то limit=rates_total-period-1
      ArrayInitialize(BufferMA,EMPTY_VALUE);
      ArrayInitialize(BufferColors,2);
     }
//--- Подготовка данных - в данном случае это и есть расчёт МА - копирование в буфер её значений из хэндла
   int count=(limit>1 ? rates_total : 1);       // если новый бар, то копируем всю доступную историю, иначе - только один текущий
   int copied=CopyBuffer(handle_ma,0,0,count,BufferMA);
   if(copied!=count) return 0;   // Если скопировать не удалось - выходим до следующего тика

//--- Установка цвета линии
   for(int i=limit; i>=0 && !IsStopped(); i--)
     {
      // Тут всё просто: 
      // У нас задано три цвета: #property indicator_color1  clrBlue,clrRed,clrDarkGray
      // 1. если МА на текущем баре выше чем МА на прошлом, то цвет под номером 0
      // 2. если МА на текущем баре ниже чем МА на прошлом, то цвет под номером 1
      // 3. иначе - цвет под номером 2 (в блоке инициализации в строке 86 задаётся этот цвет начальным для отображения линии, что, впрочем делать там не обязательно)
      BufferColors[i]=(BufferMA[i]>BufferMA[i+1] ? 0 : BufferMA[i]<BufferMA[i+1] ? 1 : 2);
     }
   
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+

我给你发了一个略显笨拙的例子（我还没有纠正Copy-Paste的错误）。

 
fxsaber:

因此，函数中的类可以有相同的名称，但内容不同。在第二个变体中，签名f并不明确。

在这里，一切都是一样的...而且很有效

#define  CLASS \
class A { \
public: \
        void f( int i ) { Print( i ); } \
        int a; \
}
void g1() { CLASS a; a.f( 1 ); }
void g2() { CLASS a; a.f( 2 ); }
void OnStart()
{
        g1();
        g2();
}

前面的C++的例子是可以的...所以签名是以某种方式被整理出来的。

 
一个编译错误。
void OnStart()
{
        struct A1 { int i; }; //(1)
        struct B1 : A1 {};    //(2)
        class  A2 { int i; }; //(3)
        class  B2 : A2 {};    //(4)//Error: 'B2' - struct undefined
}

1）（2）和（3）（4）之间的根本区别是什么？

 
雪茄服务中存在一个错误。当你改变杠杆率时，它显示的是相反的情况。例如，如果你把它从1:500改为1:100，它显示杠杆从1:100改为1:500。我必须做点什么......。)
 
A100:

这里都是一样的......而它的作用。

所以这里的情况完全不同--没有模板。

前面的例子在C++中是可行的...因此，签名在某种程度上是被照顾到的。

C++在这里给出了什么？

template<typename T>
void f( T& ) { Print(__FUNCSIG__); }
void g1() { class A { int i; } a; f( a ); }
void g2() { class A { double d; } a; f( a ); }

为了使它在MQL5中工作，输出应该包含两个不同的字符串，而不是同一个字符串。但在这种情况下，签名的生成机制将必须相当不同。如果C++在打印时产生同样的结果，__FUNCSIG__值将会急剧下降。

 

以下行为可能与什么有关

编译指标工作正常，再次编译指标不能正常工作。它在测试器中是否正常工作？

1...226322642265226622672268226922702271227222732274227522762277...3184
新评论
原因: